Veri türleri

Proje boyutu arttıkça, olabildiğince erkenden tür hatalarının yakalanmasının önemi artıp veri türü esnekliğinin önemi azaldığından, derleme zamanı tür denetlemesi genellikle daha büyük projelerde kullanışlıdır. Bu nedenle de Flash Professional ve Flash Builder uygulamalarında ActionScript derleyicisi varsayılan olarak sıkı modda çalışacak şekilde ayarlanmıştır.

Derleme zamanı tür denetlemesi sağlamak için, derleyicinin kodunuzdaki değişkenlerin veya ifadelerin veri türü bilgilerini bilmesi gerekir. Bir değişkenin veri türünü açıkça bildirmek için, değişken adına son ek olarak iki nokta operatörünü ( : ) ve ardından veri türünü ekleyin. Veri türünü bir parametreyle ilişkilendirmek için, iki nokta operatörünü ve ardından da veri türünü kullanın. Örneğin, aşağıdaki kod, xParam parametresine veri türü bilgilerini ekler ve açık bir veri türüyle bir değişkeni myParam olarak bildirir:

function runtimeTest(xParam:String) 
{ 
    trace(xParam); 
} 
var myParam:String = "hello"; 
runtimeTest(myParam);

ActionScript derleyicisi, katı modda tür uyuşmazlıklarını derleyici hataları olarak bildirir. Örneğin, aşağıdaki kod, Object türünde bir işlev parametresini xParam olarak bildirir, ancak daha sonra bu parametreye String ve Number türünde değerler atamayı dener. Bu da katı modda bir derleyici hatası oluşturur.

function dynamicTest(xParam:Object) 
{ 
    if (xParam is String) 
    { 
        var myStr:String = xParam; // compiler error in strict mode 
        trace("String: " + myStr); 
    } 
    else if (xParam is Number) 
    { 
        var myNum:Number = xParam; // compiler error in strict mode 
        trace("Number: " + myNum); 
    } 
}

Ancak katı modda da, atama deyiminin sağ tarafını türlenmemiş şekilde bırakarak derleme zamanı tür denetlemesini seçerek devre dışı bırakabilirsiniz. Bir tür ek açıklamasını çıkararak veya özel yıldız ( * ) tür ek açıklamasını kullanarak bir değişkeni ya da ifadeyi türlenmemiş olarak işaretleyebilirsiniz. Örneğin, önceki örnekte yer alan xParam parametresi, artık tür ek açıklaması içermeyecek şekilde değiştirilirse, kod sıkı modda derlenir:

function dynamicTest(xParam) 
{ 
    if (xParam is String) 
    { 
        var myStr:String = xParam; 
        trace("String: " + myStr); 
    } 
    else if (xParam is Number) 
    { 
        var myNum:Number = xParam; 
        trace("Number: " + myNum); 
    } 
} 
dynamicTest(100) 
dynamicTest("one hundred");

Katı modda da, standart modda da derleme yapsanız, ActionScript 3.0'da, çalışma zamanı tür denetlemesi gerçekleşir. Bir dizi bekleyen bir işleve argüman olarak 3 değerinin iletildiği bir durumu göz önünde bulundurun. 3 değeri, Array veri türüyle uyumlu olmadığından, katı modda derleyici bir hata oluşturur. Sıkı modu devre dışı bırakıp standart modda çalışırsanız, derleyici tür uyuşmazlığından şikayetçi olmaz ancak çalışma zamanı tür denetlemesi bir çalışma zamanı hatası verir.

Aşağıdaki örnek, bir Array argümanı bekleyen ancak kendisine 3 değeri iletilen typeTest() adındaki bir işlevi gösterir. 3 değeri, parametrenin bildirilen veri türünün (Array) bir üyesi olmadığından bu, standart modda bir çalışma zamanı hatasına yol açar.

function typeTest(xParam:Array) 
{ 
    trace(xParam); 
} 
var myNum:Number = 3; 
typeTest(myNum);  
// run-time error in ActionScript 3.0 standard mode

Katı modda çalıştığınız halde çalışma zamanı tür hatası aldığınız durumlar da olabilir. Katı modu kullanırken türlenmemiş bir değişken kullanarak derleme zamanı tür denetlemesini devre dışı bırakırsanız bu mümkün olur. Türlenmemiş bir değişken kullandığınızda, tür denetlemesini ortadan kaldırmış olmazsınız yalnızca çalışma zamanına ertelemiş olursunuz. Örneğin, önceki örnekte yer alan myNum değişkeninin bildirilmiş bir veri türü yoksa, derleyici tür uyuşmazlığını algılayamaz; ancak kod, atama deyiminin sonucu olarak 3 değerine ayarlanan myNum çalışma zamanı değerini Array veri türüne ayarlanmış xParam türüyle karşılaştırdığından, bir çalışma zamanı hatası oluşturur.

function typeTest(xParam:Array) 
{ 
    trace(xParam); 
} 
var myNum = 3; 
typeTest(myNum);  
// run-time error in ActionScript 3.0

Çalışma zamanı tür denetlemesi ayrıca derleme zamanı tür denetlemesine göre mirasın daha esnek kullanılmasını sağlar. Standart mod, tür denetlemesini çalışma zamanına erteleyerek, yukarı çevrim de yapsanız bir alt sınıfın özelliklerine başvurmanıza olanak sağlar. Bir sınıf örneğinin türünü belirtmek için bir temel sınıf kullanıp bu sınıf türü örneğini başlatmak için bir alt sınıf kullandığınızda yukarı çevrim gerçekleşir. Örneğin, genişletilebilen ClassBase adında bir sınıf oluşturabilirsiniz ( final niteliğine sahip sınıflar genişletilemez):

class ClassBase 
{ 
}

Daha sonra aşağıdaki gibi, ClassExtender adında olan ve someString adında bir özellik içeren, ClassBase sınıfının bir alt sınıfını oluşturabilirsiniz:

class ClassExtender extends ClassBase 
{ 
    var someString:String; 
}

Her iki sınıfı da kullanıp ClassBase veri türü kullanılarak bildirilen ancak ClassExtender yapıcısı kullanılarak başlatılan bir sınıf örneği oluşturabilirsiniz. Temel sınıf, alt sınıfta bulunmayan özellikleri veya yöntemleri içermediğinden, yukarı çevrim güvenli bir işlem olarak değerlendirilir.

var myClass:ClassBase = new ClassExtender();

Ancak bir alt sınıf, temel sınıfının içermediği özellikleri veya yöntemleri içermez. Örneğin, ClassExtender sınıfı, ClassBase sınıfında varolmayan someString özelliğini içerir. ActionScript 3.0 standart modunda, aşağıdaki örnekte gösterildiği gibi, bir derleme zamanı hatası oluşturmadan myClass örneğini kullanarak bu özelliğe başvurabilirsiniz:

var myClass:ClassBase = new ClassExtender(); 
myClass.someString = "hello"; 
// no error in ActionScript 3.0 standard mode

is operatörü, bir değişkenin veya ifadenin belirli bir veri türünün üyesi olup olmadığını test etmenize olanak tanır. Önceki ActionScript sürümlerinde, instanceof operatörü bu işlevselliği sağlamıştır ancak ActionScript 3.0'da instanceof operatörü, veri türü üyeliğini test etmek için kullanılmamalıdır. x instanceof y ifadesi yalnızca y varlığı için x prototip zincirini denetlediğinden, elle tür denetleme için instanceof operatörü yerine is operatörü kullanılmalıdır. (Ayrıca ActionScript 3.0'da prototip zinciri, miras hiyerarşisinin tam resmini sağlamaz.)

is operatörü uygun miras hiyerarşisini inceler ve yalnızca bir nesnenin belirli bir sınıfın örneği olup olmadığını denetlemek için değil, bir nesnenin belirli bir arabirimi uygulayan bir sınıf örneği olup olmadığını denetlemek için de kullanılabilir. Aşağıdaki örnek, mySprite adında bir Sprite sınıfı örneği oluşturur ve mySprite öğesinin Sprite ve DisplayObject sınıflarının bir örneği olup olmadığını ve IEventDispatcher arabirimini uygulayıp uygulamadığını test etmek için is operatörünü kullanır:

var mySprite:Sprite = new Sprite(); 
trace(mySprite is Sprite); // true 
trace(mySprite is DisplayObject);// true 
trace(mySprite is IEventDispatcher); // true

is operatörü, miras hiyerarşisini denetler ve mySprite örneğinin Sprite ve DisplayObject sınıflarıyla uyumlu olduğunu düzgün şekilde bildirir. (Sprite sınıfı, DisplayObject sınıfının bir alt sınıfıdır.) is operatörü ayrıca mySprite öğesinin IEventDispatcher arabirimini uygulayan herhangi bir sınıftan miras alıp almadığını da denetler. Sprite sınıfı, IEventDispatcher arabirimini uygulayan IEventDispatcher sınıfından miras aldığından, is operatörü, mySprite öğesinin aynı arabirimini uyguladığını doğru şekilde bildirir.

Aşağıdaki örnek, is operatörü yerine instanceof operatörünü kullanarak önceki örnekteki testlerin aynısını gösterir. instanceof operatörü, mySprite öğesinin Sprite veya DisplayObject öğesinin bir örneği olduğunu doğru şekilde tanımlar ancak mySprite öğesinin IEventDispatcher arabirimini uygulayıp uygulamadığını test etmek için kullanıldığında false değerini döndürür.

trace(mySprite instanceof Sprite); // true 
trace(mySprite instanceof DisplayObject);// true 
trace(mySprite instanceof IEventDispatcher); // false

as operatörü, bir ifadenin belirli bir veri türünün üyesi olup olmadığını denetlemenize olanak tanır. Ancak is operatöründen farklı olarak as operatörü bir Boolean değeri döndürmez. as operatörü, true yerine ifadenin değerini ve false yerine de null değerini döndürür. Aşağıdaki örnek, Sprite örneğinin DisplayObject, IEventDispatcher ve Number veri türlerinden hangisinin üyesi olduğunu denetleme gibi basit bir durumda is operatörü yerine as operatörü kullanılmasının sonuçlarını gösterir.

var mySprite:Sprite = new Sprite(); 
trace(mySprite as Sprite);                 // [object Sprite] 
trace(mySprite as DisplayObject);                 // [object Sprite] 
trace(mySprite as IEventDispatcher);                 // [object Sprite] 
trace(mySprite as Number);                                       // null

as operatörünü kullandığınızda, sağdaki işlenenin bir veri türü olması gerekir. Sağdaki işlenen olarak veri türü dışında bir ifade kullanma girişimi hataya yol açar.

Boolean veri türü iki değer içerir: true ve false . Boolean türündeki değişkenler için diğer değerler geçerli değildir. Bildirilmiş ancak başlatılmamış bir Boolean değişkeninin varsayılan değeri false olur.

int veri türü, dahili olarak 32 bit tam sayı şeklinde saklanır ve

-2.147.483.648 (-2 ³¹ ) ile 2.147.483.647 (2 ³¹ - 1) (dahil) arasındaki tam sayılar kümesini kapsar. Önceki ActionScript sürümleri yalnızca hem tam sayı hem de kayan nokta sayıları için kullanılan Number veri türünü sunardı. ActionScript 3.0'da şimdi 32-bit işaretli ve işaretsiz tam sayılar için düşük düzeyli makine türlerine erişiminiz vardır. Değişkeninizin kayan nokta sayılarını kullanmasına gerek yoksa, Number veri türü yerine int veri türünün kullanılması hem daha hızlı hem de daha etkili olur.

Minimum ve maksimum int değerleri aralığı dışında kalan tam sayı değerleri için, pozitif ve negatif 9.007.199.254.740.992 arasındaki değerleri (53-bit tam sayı değerleri) işleyebilen Number veri türünü kullanın. int veri türündeki değişkenler için varsayılan değer 0'dır.

Null veri türü yalnızca bir değer içerir, null . Bu, String veri türü için ve Object sınıfı da dahil olmak üzere karmaşık veri türlerini tanımlayan tüm sınıflar için varsayılan değerdir. Boolean, Number, int ve uint gibi diğer ilkel veri türlerinin hiçbiri null değerini içermez. Çalışma zamanında, null değeri, Boolean, Number, int, veya uint gibi değişken türlerine null atamaya çalışırsanız uygun varsayılan değere dönüştürülür. Bu veri türünü tür ek açıklaması olarak kullanamazsınız.

ActionScript 3.0'da Number veri türü, tam sayıları, işaretsiz tam sayıları ve kayan nokta sayılarını temsil edebilir. Ancak, performansı en üst düzeye çıkarmak için, Number veri türünü yalnızca 32-bit int ve uint türlerinin saklayamayacağı kadar büyük tam sayı değerleri için ve kayan nokta sayıları için kullanmanız gerekir. Bir kayan nokta sayısını saklamak için, sayıya bir ondalık işareti dahil edin. Ondalık işaretini çıkarırsanız, sayı bir tam sayı olarak saklanır.

Number veri türü, İkili Kayan Nokta Aritmetiği için IEEE Standardı (IEEE-754) tarafından belirtilen 64-bit çift kesinlikli biçimi kullanır. Bu standart, kayan nokta sayılarının mevcut 64 bit kullanılarak nasıl saklanacağını dikte eder Sayının pozitif veya negatif olduğunu belirlemek için tek bir bit kullanılır. Üst için taban 2 olarak saklanan 11 bit kullanılır. Geriye kalan 52 bit, significand ( ayrıca mantissa olarak da adlandırılır) öğesini (üst tarafından belirtilen güce yükseltilen rakamdır) saklamak için kullanılır.

Number veri türü, bir üssü saklamak için bit'lerinden bir kısmını kullanarak, significand için tüm bit'leri kullandığında saklayabildiğinden çok daha büyük kayan nokta sayılarını saklayabilir. Örneğin, Number veri türü, significand öğesini saklamak için tüm 64 bit'i de kullansaydı, 2 ⁶⁵ - 1 büyüklüğünde bir sayıyı saklayabilirdi. Number veri türü bir üssü saklamak için 11 bit kullanarak, significand öğesini 2 ¹⁰²³ kuvvetine yükseltebilir.

Number türünün temsil edebildiği maksimum ve minimum değerler, Number sınıfının Number.MAX_VALUE ve Number.MIN_VALUE adındaki statik özelliklerinde saklanır.

Number.MAX_VALUE == 1.79769313486231e+308 
Number.MIN_VALUE == 4.940656458412467e-324

Bu sayı aralığı büyük olsa da, bu geniş aralık kesinlik düzeyini azaltır. Number veri türü, significand öğesini saklamak için 52 bit kullanır ve bu da, kesin şekilde temsil edilecek 52 bit'ten fazlasını gerektiren sayıların (örn. 1/3 kesiri) yalnızca yaklaşık değerler olmasına neden olur. Uygulamanız için ondalık sayılarda mutlak kesinlik gerekiyorsa, ikili kayan nokta aritmetiğinin tersine ondalık kayan nokta aritmetiğini uygulayan bir yazılım kullanmanız gerekir.

Number veri türünde tam sayı değerlerini sakladığınızda, significand öğesinin yalnızca 52 bit'i kullanılır. Number veri türü, -9.007.199.254.740.992 (-2 ⁵³ ) ile 9.007.199.254.740.992 (2 ⁵³ ) arasındaki tam sayıları temsil etmek için bu 52 bit'i ve özel gizlenmiş bit'i kullanır.

NaN değeri yalnızca Number türündeki değişkenler için varsayılan değer olarak değil, aynı zamanda bir sayı döndürmesi gerektiği halde sayı döndürmeyen herhangi bir işlemin sonucu olarak da kullanır. Örneğin, negatif bir sayının kare kökünü hesaplamayı denerseniz, sonuç NaN olur. Diğer özel Number değerleri arasında pozitif sonsuzluk ve negatif sonsuzluk yer alır.

String veri türü, 16-bit karakterlerin bir sırasını temsil eder. Dizeler, UTF-16 biçimi kullanılarak dahili şekilde Unicode karakterleri olarak saklanır. Dizeler, Java programlama dilinde olduğu gibi, sabit değerlerdir. String değerindeki bir işlem, yeni bir dize örneği döndürür. String veri türüyle bildirilen bir değişkenin varsayılan değeri, null şeklindedir. null değeri boş dizeyle ( "" ) aynı değildir. null değeri değişkenin içinde bir değer saklamadığı anlamına gelirken, boş dize, değerin hiçbir karakter içermeyen bir String olan bir değer içerdiği anlamına gelir.

uint veri türü, dahili olarak 32-bit işaretsiz tam sayı şeklinde saklanır ve 0 ile 4.294.967.295 (2 ³² - 1) arasındaki tam sayıların kümesini kapsar. Negatif olmayan tam sayıları çağıran özel koşullar için uint veri türünü kullanın. Örneğin, int veri türü, renk değerlerinin işlenmesi için uygun olmayan dahili bir işaret bit'i içerdiğinden, piksel rengi değerlerini temsil etmek için uint veri türünü kullanmanız gerekir. Maksimum uint değerinden büyük tam sayı değerleri için, 53-bit tam sayı değerlerini işleyebilen Number veri türünü kullanın. uint veri türündeki değişkenler için varsayılan değer 0'dır.

Void veri türü yalnızca bir değer içerir: undefined . Önceki ActionScript sürümlerinde undefined , Object sınıfının örnekleri için varsayılan değerdi. ActionScript 3.0'da, Object örneklerinin varsayılan değeri null şeklindedir. Object sınıfının bir örneğine undefined değerini atamayı denerseniz, değer null değerine dönüştürülür. Türlenmemiş değişkenlere yalnızca undefined değerini atayabilirsiniz. Türlenmemiş değişkenler, tür ek açıklaması içermeyen veya tür ek açıklaması için yıldız ( * ) sembolünü kullanan değişkenlerdir. void öğesini yalnızca döndürme tür ek açıklaması olarak kullanabilirsiniz.

Object veri türü, Object sınıfı tarafından tanımlanır. Object sınıfı, ActionScript'teki tüm sınıf tanımlamaları için temel sınıf görevi görür. Object veri türünün ActionScript 3.0 sürümü, önceki sürümlerden üç şekilde farklılık gösterir. İlk olarak, Object veri türü artık tür ek açıklaması içermeyen değişkenlere atanan varsayılan veri türü değildir. İkinci olarak, Object veri türü, Object örneklerinin varsayılan değeri olarak kullanılan undefined değerini artık içermez. Üçüncü olarak, ActionScript 3.0'da, Object sınıfının örnekleri için varsayılan değer null şeklindedir.

Önceki ActionScript sürümlerinde, Object veri türüne tür ek açıklaması içermeyen bir değişken otomatik olarak atanırdı. Artık türlenmemiş değişken kavramını içeren ActionScript 3.0'da bu geçerli değildir. Tür ek açıklaması içermeyen değişkenler artık türlenmemiş olarak değerlendirilir. Kodunuzun okuyucularına, amacınızın bir değişkene tür vermemek olduğunu açıkça belirtmek isterseniz, tür ek açıklamasının çıkarılmasına eşdeğer şekilde, tür ek açıklaması için yıldız ( * ) sembolünü kullanabilirsiniz. Aşağıdaki örnekte, her ikisi de x türlenmemiş değişkenini bildiren iki eşdeğer deyim gösterilmektedir:

var x 
var x:*

Yalnızca türlenmemiş değişkenler undefined değerini barındırabilir. Bir veri türüne sahip değişkene undefined değerini atamaya çalışırsanız, çalışma zamanı, undefined değerini o veri türünün varsayılan değerine dönüştürür. Object veri türü örnekleri için, varsayılan değer null değeridir. Bu durum, undefined değerini bir Object örneğine atamaya çalışırsanız, değerin null değerine dönüştürüleceği anlamına gelir.