Şifrelemeyi SQL veritabanlarıyla kullanma

Şifreleme, veritabanında saklanan bilgiye erişimi sınırlamak istediğinizde kullanışlı bir yoldur. Adobe AIR'in veritabanı şifreleme işlevleri farklı amaçlar için kullanılabilir. Şifreli bir veritabanı kullanmak isteyebileceğiniz durumlara ilişkin örnekler aşağıdadır:

• Bir sunucudan indirilen özel uygulama verilerinin salt okunur önbelleği

• Bir sunucuyla senkronize edilen özel veriler için yerel bir uygulama deposu (sunucuya veri gönderilir ve sunucudan veri yüklenir)

• Uygulama tarafından oluşturulan ve düzenlenen belgeler için dosya formatı olarak kullanılan şifreli dosyalar. Dosyalar bir kullanıcıya özgü olabilir veya uygulamanın tüm kullanıcıları tarafından paylaşılmak üzere tasarlanmış olabilir.

• Yerel SQL veritabanları için kullanımlar bölümünde açıklananlar gibi bilgisayara veya veritabanı dosyalarına erişimi olan insanlardan saklı tutulması gereken diğer yerel veri deposu kullanımları.

Şifreli bir veritabanı kullanmak istemenizin nedenini anlamak, uygulamanızı nasıl yapılandıracağınıza karar vermenize yardımcı olur. Özellikle, uygulamanızın veritabanı için şifreleme anahtarını nasıl oluşturacağını, alacağını veya depolayacağını etkileyebilir. Dikkate alınması gereken bu konular hakkında daha fazla bilgi için bkz. Şifrelemeyi veritabanıyla kullanmak için dikkate alınması gerekenler .

Şifreli veritabanı dışında, kritik verilerin gizli kalmasını sağlamada kullanılan alternatif bir mekanizma, şifrelenmiş yerel depo .'dur. Şifrelenmiş yerel depoyla, String anahtarı kullanarak ByteArray değeri saklarsınız. Yalnızca değeri saklayan AIR uygulaması buna erişebilir ve yalnızca değerin saklandığı bilgisayarda erişebilir. Şifreli yerel depoyla, kendi şifreleme anahtarınızı oluşturmanız gerekmez. Bu nedenle, şifreli yerel depo bir ByteArray içinde kolayca kodlanabilen tek bir değer veya değerler kümesini kolayca saklamak için en uygun yoldur. Şifreli veritabanı, yapılandırılmış veri depolama ve sorgulamanın amaçlandığı daha büyük veri kümeleri için daha uygundur. Şifreli yerel depo kullanımı hakkında daha fazla bilgi için, bkz. Şifrelenmiş yerel depolama .

Şifreli bir veritabanı kullanmak için, veritabanı dosyası oluşturulduğu sırada şifrelenmelidir. Veritabanı bir kez şifrelenmemiş olarak oluşturulduğunda, sonradan şifrelenemez. Benzer şekilde, şifreli bir veritabanının daha sonra şifresi kaldırılamaz. Ayrıca, şifreli bir veritabanının şifreleme anahtarını değiştirebilirsiniz. Ayrıntılar için bkz. Veritabanının şifreleme anahtarını değiştirme . Şifrelenmemiş bir veritabanınız varsa ve veritabanı şifrelemeyi kullanmak istiyorsanız, yeni ve şifreli bir veritabanı oluşturabilir ve var olan tablo yapısını ve verileri yeni veritabanına kopyalayabilirsiniz.

Şifreli bir veritabanı oluşturmak, Veritabanı oluşturma bölümünde anlatıldığı gibi, şifrelenmemiş bir veritabanı oluşturmakla hemen hemen aynıdır. Önce veritabanına bağlantıyı temsil eden bir SQLConnection örneği oluşturuyorsunuz. Henüz var olmayan bir dosya için veritabanı konumunu belirterek, SQLConnection nesnesinin open() yöntemini veya openAsync() yöntemini çağırma yoluyla veritabanını oluşturabilirsiniz. Şifreli veritabanı oluşturmanın tek farkı, encryptionKey parametresi için ( open() yönteminin beşinci parametresi ve openAsync() yönteminin altıncı parametresi) bir değer sağlamanız gerekmesidir.

Geçerli bir encryptionKey parametre değeri, tam olarak 16 bayt içeren bir ByteArray nesnesidir.

Aşağıdaki örneklerde şifrelenmiş veritabanı oluşturma gösterilmiştir. Basitleştirmek için, bu örnekte şifreleme anahtarı uygulama kodunda sabit olarak kodlanmıştır. Ancak, bu teknik güvenli olmadığı için kesinlikle önerilmez.

var conn:SQLConnection = new SQLConnection(); 
     
var encryptionKey:ByteArray = new ByteArray(); 
encryptionKey.writeUTFBytes("Some16ByteString"); // This technique is not secure! 
     
// Create an encrypted database in asynchronous mode 
conn.openAsync(dbFile, SQLMode.CREATE, null, false, 1024, encryptionKey); 
     
// Create an encrypted database in synchronous mode 
conn.open(dbFile, SQLMode.CREATE, false, 1024, encryptionKey);

Şifreleme anahtarı oluşturmak için önerilen bir yolu gösteren örnek için bkz. Örnek: Şifreleme anahtarı oluşturma ve kullanma .

Şifreli veritabanı oluşturma gibi, şifreli bir veritabanına bağlantı açma yordamı da şifrelenmemiş bir veritabanına bağlanmaya benzer. Bu yordam, Veritabanına bağlanma bölümünde daha ayrıntılı biçimde açıklanmıştır. Senkronize yürütme modunda bir bağlantı açmak için open() yöntemini veya senkronize olmayan yürütme modunda bağlantı açmak için openAsync() yöntemini kullanın. Aradaki tek fark, şifreli bir veritabanını açmak için encryptionKey parametresine ilişkin ( open() yönteminin beşinci parametresi ve openAsync() yönteminin altıncı parametresi) doğru değeri belirtmeniz gerekiyor olmasıdır.

Sağlanan şifreleme anahtarı doğru değilse, bir hata oluşur. open() yöntemi için, SQLError istisnası verilir. SQLConnection nesnesi, openAsync() yöntemi için, error özelliği bir SQLError nesnesi içeren bir SQLErrorEvent gönderir. Her durumda, istisna tarafından oluşturulan SQLError nesnesi errorID özellik değeri 3138'e sahiptir. Bu hata kimliği, “Açılan dosya bir veritabanı dosyası değil” hata mesajına karşılık gelir.

Aşağıdaki örnek, senkronize olmayan yürütme modunda şifreli veritabanı açmayı gösterir. Basitleştirmek için, bu örnekte şifreleme anahtarı uygulama kodunda sabit olarak kodlanmıştır. Ancak, bu teknik güvenli olmadığı için kesinlikle önerilmez.

import flash.data.SQLConnection; 
import flash.data.SQLMode; 
import flash.events.SQLErrorEvent; 
import flash.events.SQLEvent; 
import flash.filesystem.File; 
     
var conn:SQLConnection = new SQLConnection(); 
conn.addEventListener(SQLEvent.OPEN, openHandler); 
conn.addEventListener(SQLErrorEvent.ERROR, errorHandler); 
var dbFile:File = File.applicationStorageDirectory.resolvePath("DBSample.db"); 
     
var encryptionKey:ByteArray = new ByteArray(); 
encryptionKey.writeUTFBytes("Some16ByteString"); // This technique is not secure! 
     
conn.openAsync(dbFile, SQLMode.UPDATE, null, false, 1024, encryptionKey); 
     
function openHandler(event:SQLEvent):void 
{ 
    trace("the database opened successfully"); 
} 
     
function errorHandler(event:SQLErrorEvent):void 
{ 
    if (event.error.errorID == 3138) 
    { 
        trace("Incorrect encryption key"); 
    } 
    else 
    { 
        trace("Error message:", event.error.message); 
        trace("Details:", event.error.details); 
    } 
} 

Aşağıdaki örnek, senkronize yürütme modunda şifreli veritabanı açmayı gösterir. Basitleştirmek için, bu örnekte şifreleme anahtarı uygulama kodunda sabit olarak kodlanmıştır. Ancak, bu teknik güvenli olmadığı için kesinlikle önerilmez.

import flash.data.SQLConnection; 
import flash.data.SQLMode; 
import flash.filesystem.File; 
     
var conn:SQLConnection = new SQLConnection(); 
var dbFile:File = File.applicationStorageDirectory.resolvePath("DBSample.db"); 
     
var encryptionKey:ByteArray = new ByteArray(); 
encryptionKey.writeUTFBytes("Some16ByteString"); // This technique is not secure! 
     
try 
{ 
    conn.open(dbFile, SQLMode.UPDATE, false, 1024, encryptionKey); 
    trace("the database was created successfully"); 
} 
catch (error:SQLError) 
{ 
    if (error.errorID == 3138) 
    { 
        trace("Incorrect encryption key"); 
    } 
    else 
    { 
        trace("Error message:", error.message); 
        trace("Details:", error.details); 
    } 
} 

Şifreleme anahtarı oluşturmak için önerilen bir yolu gösteren örnek için bkz. Örnek: Şifreleme anahtarı oluşturma ve kullanma .

Veritabanı şifrelendiğinde, veritabanına ilişkin şifreleme anahtarını sonradan değiştirebilirsiniz. Veritabanının şifreleme anahtarını değiştirmek için önce bir SQLConnection örneği oluşturarak ve bunun open() veya openAsync() yöntemini çağırarak veritabanına bağlantı açın. Veritabanına bağlanıldığında, argüman olarak yeni şifreleme anahtarını ileterek reencrypt() yöntemini çağırın.

Çoğu veritabanı işlemi gibi, reencrypt() yönteminin davranışı, veritabanı bağlantısının senkronize veya senkronize olmayan yürütme modunu kullanıyor olmasına göre değişir. Veritabanına bağlanmak için open() yöntemini kullanırsanız reencrypt() işlemi senkronize olarak çalışır. İşlem tamamlandığında, yürütme sonraki kod satırıyla devam eder:

var newKey:ByteArray = new ByteArray(); 
// ... generate the new key and store it in newKey 
conn.reencrypt(newKey);

Diğer yandan, veritabanı bağlantısı openAsync() yöntemi kullanılarak açıldıysa, reencrypt() işlemi senkronize olmayan modda çalışır. reencrypt() yönteminin çağrılması, yeniden şifreleme işlemini başlatır. İşlem tamamlandığında, SQLConnection nesnesi bir reencrypt olayı gönderir. Yeniden şifrelemenin tamamlandığını belirlemek için bir olay dinleyicisi kullanabilirsiniz:

var newKey:ByteArray = new ByteArray(); 
// ... generate the new key and store it in newKey 
     
conn.addEventListener(SQLEvent.REENCRYPT, reencryptHandler); 
     
conn.reencrypt(newKey); 
     
function reencryptHandler(event:SQLEvent):void 
{ 
    // save the fact that the key changed 
}

reencrypt() işlemi, kendi işlemi içinde çalışır. İşlem kesintiye uğradığında veya başarısız olduğunda (örneğin, uygulama işlem tamamlanmadan kapatıldığında) işlem geri alınır. Bu durumda, ilk şifreleme anahtarı veritabanının şifreleme anahtarı olarak kalır.

reencrypt() yöntemi, veritabanından şifrelemeyi kaldırmak için kullanılamaz. reencrypt() yöntemine null değerinin veya 16 bayt olmayan bir ByteArray değerinin iletilmesi hatayla sonuçlanır.

Yerel SQL veritabanları için kullanımlar bölümü, şifreli veritabanı kullanmak isteyebileceğiniz çeşitli durumları gösterir. Farklı uygulamaların kullanım senaryolarının (bunlar ve diğer senaryolar dahil) farklı gizlilik gereksinimleri olduğu açıktır. Uygulamanızda şifreleme kullanımını yapılandırma biçiminiz, bir veritabanındaki verilerin ne kadar özel olduğunu denetlemenizin önemli bir parçasıdır. Örneğin, şifreli veritabanını kişisel verilerinizi aynı bilgisayarı kullanan diğer kullanıcılardan bile saklı tutmak için kullanıyorsanız, her kullanıcının veritabanı kendi şifreleme anahtarını gerektirir. En yüksek düzeyde güvenlik için, uygulamanız kullanıcı tarafından girilen paroladan anahtar oluşturabilir. Şifreleme anahtarını parolaya dayandırmak, başka bir kişi kullanıcının bilgisayardaki hesabına erişmeyi başarsa bile, verilere erişememesini sağlar. Güvenlik spektrumunun diğer ucunda, bir veritabanı dosyasının uygulamanızın tüm kullanıcıları için okunabilir olmasını, ancak diğer uygulamaların bu dosyaya erişememesini istiyorsunuz. Bu durumda, uygulamanın yüklenmiş her kopyasının, paylaşımlı bir şifreleme anahtarına erişimi olması gerekir.

Uygulamanızı ve özellikle şifreleme anahtarının oluşturulduğu tekniği uygulama verileriniz için kullanmak istediğiniz gizlilik düzeyine göre tasarlayabilirsiniz. Aşağıdaki liste, farklı veri gizliliği düzeyleri için tasarım önerileri sunar:

• Veritabanını herhangi bir bilgisayardaki uygulamaya erişimi olan tüm kullanıcılar için erişilebilir kılmak için uygulamanın tüm örnekleri tarafından kullanılabilen tek bir anahtar kullanın. Örneğin, uygulama ilk kez çalıştırıldığında, SSL gibi güvenli bir protokol kullanarak bir sunucudan paylaşımlı şifreleme anahtarını indirebilir. Anahtarı gelecekte kullanmak üzere şifreli yerel depoya kaydedebilir. Alternatif olarak, bilgisayardaki her kullanıcıya ilişkin verileri şifreleyin ve verileri taşınabilir kılmak için sunucu gibi uzak bir veri deposuyla senkronize edin.

• Veritabanını herhangi bir bilgisayardaki tek bir kullanıcı tarafından erişilebilir kılmak için, şifreleme anahtarını bir kullanıcı sırrından (parola gibi) oluşturun. Anahtarı oluşturmak için belirli bir bilgisayara bağlı olan herhangi bir değeri (şifreli yerel depoda saklanan bir değer gibi) kullanmayın. Alternatif olarak, bilgisayardaki her kullanıcıya ilişkin verileri şifreleyin ve verileri taşınabilir kılmak için sunucu gibi uzak bir veri deposuyla senkronize edin.

• Veritabanını tek bir bilgisayardaki tek bir kişi tarafından erişilebilir kılmak için, anahtarı bir paroladan ve oluşturulmuş bir salttan yaratın. Bu tekniğe ilişkin bir örnek için bkz. Örnek: Şifreleme anahtarı oluşturma ve kullanma .

Bir uygulamayı şifreli bir veritabanı kullanmak üzere tasarlarken göz önüne alınması gereken diğer güvenlik konuları şunlardır:

• Bir sistem her zaman en zayıf noktası kadar güvenlidir. Şifreleme anahtarı kullanmak için kullanıcı tarafından girilen bir parolayı kullanıyorsanız, parolalarda minimum uzunluk ve karmaşıklık sınırlamaları uygulamayı göz önünde bulundurun. Yalnızca temel karakterleri kullanan kısa bir parola, kolayca tahmin edilebilir.

• AIR uygulamasının kaynak kodu, kullanıcının bilgisayarında düz metinde (HTML içeriği için) veya derlemesi kolayca açılabilir bir ikili formatta (SWF içeriği için) saklanır. Kaynak kod erişilebilir olduğundan, hatırlanması gereken iki nokta şöyledir:

  • Şifreleme anahtarınızı kaynak kodunuzda asla sabit olarak kodlamayın

  • Şifreleme anahtarını oluşturmak için kullanılan tekniğin (rastgele karakter oluşturucu veya belirli bir karma algoritma) bir saldırgan tarafından kolayca çözülebileceğini her zaman göz önünde bulundurun

• AIR veritabanı şifreleme CBC-MAC (CCM) moduyla Counter içeren Gelişmiş Şifreleme Standardı'nı (AES) kullanır. Bu şifreleme, güvenli olmak için bir salt değeriyle birleştirilen kullanıcı tarafından girilmiş bir anahtarı gerektirir. Buna ilişkin bir örnek için bkz. Örnek: Şifreleme anahtarı oluşturma ve kullanma .

• Veritabanını şifrelemeyi seçtiğinizde, bu veritabanıyla bağlantılı olan veritabanı motoru tarafından kullanılan tüm disk dosyaları şifrelenir. Ancak, veritabanı motoru işlemlerdeki okuma ve yazma süresi performansını artırmak için bazı verileri geçici olarak bellek içi bir önbellekte tutar. Bellekte yerleşik veriler şifrelenmez. Saldırgan AIR uygulaması tarafından kullanılan belleğe erişmeyi örneğin hata ayıklayıcı kullanarak başarırsa, veritabanında açık ve şifrelenmemiş olan veriler kullanılabilir durumda olabilir.

Bu örnek uygulama, şifreleme anahtarı oluşturma için bir tekniği gösterir. Bu uygulama, kullanıcının verileri için en yüksek düzeyde gizlilik ve güvenlik sağlamak üzere tasarlanmıştır. Kişisel verileri korumanın önemli bir yönü, uygulamanın veritabanına her bağlanmasında kullanıcının parolayı girmesini gerektirmesidir. Sonuç olarak, bu örnekte gösterildiği gibi, bu gizlilik düzeyini gerektiren bir uygulama, veritabanı şifreleme anahtarını hiçbir zaman doğrudan saklamamalıdır.

Uygulama iki bölümden oluşur: Şifreleme anahtarını oluşturan ActionScript sınıfı (EncryptionKeyGenerator sınıfı) ve bu sınıfın nasıl kullanılacağını gösteren temel bir kullanıcı arabirimi. Tam kaynak kodu için bkz. Şifreleme anahtarı oluşturmak için tam örnek kod .