XML değişkenlerini başlatma

Flash Player 9 ve üstü, Adobe AIR 1.0 ve üstü

Aşağıdaki gibi, XML nesnesine bir XML değişmezi atayabilirsiniz: 

var myXML:XML =  
    <order> 
        <item id='1'> 
            <menuName>burger</menuName> 
            <price>3.95</price> 
        </item> 
        <item id='2'> 
            <menuName>fries</menuName> 
            <price>1.45</price> 
        </item> 
    </order>

Aşağıdaki kod parçasında gösterildiği gibi, XML verisi içeren bir dizeden bir XML nesnesi örneği oluşturmak için, new yapıcısını da kullanabilirsiniz: 

var str:String = "<order><item id='1'><menuName>burger</menuName>" 
                            + "<price>3.95</price></item></order>"; 
var myXML:XML = new XML(str);

Dizedeki XML verileri düzgün biçimlendirilmemişse (örneğin, bir kapatma etiketi eksikse), çalışma zamanı hatasıyla karşılaşırsınız.

Ayrıca aşağıdaki örnekte gösterildiği gibi, verileri başvuruya göre (diğer değişkenlerden) bir XML nesnesine iletebilirsiniz: 

var tagname:String = "item";  
var attributename:String = "id";  
var attributevalue:String = "5";  
var content:String = "Chicken";  
var x:XML = <{tagname} {attributename}={attributevalue}>{content}</{tagname}>;  
trace(x.toXMLString()) 
    // Output: <item id="5">Chicken</item>

Bir URL'den XML verileri yüklemek için, aşağıdaki örnekte gösterildiği gibi, URLLoader sınıfını kullanın: 

import flash.events.Event; 
import flash.net.URLLoader; 
import flash.net.URLRequest; 
 
var externalXML:XML; 
var loader:URLLoader = new URLLoader(); 
var request:URLRequest = new URLRequest("xmlFile.xml"); 
loader.load(request); 
loader.addEventListener(Event.COMPLETE, onComplete); 
 
function onComplete(event:Event):void 
{ 
    var loader:URLLoader = event.target as URLLoader; 
    if (loader != null) 
    { 
        externalXML = new XML(loader.data); 
        trace(externalXML.toXMLString()); 
    } 
    else 
    { 
        trace("loader is not a URLLoader!"); 
    } 
}

Bir soket bağlantısından XML verilerini okumak için, XMLSocket sınıfını kullanın. Daha fazla bilgi için Adobe Flash Platformu için ActionScript 3.0 Başvurusu 'ndaki XMLSocket sınıfına bakın.