Dizelerdeki alt dizeleri ve desenleri bulma

Eşleşen alt dizeleri bulma

search() yöntemi, bu örnekte gösterildiği gibi, belirli bir desenle eşleşen birinci alt dizenin dizin konumunu döndürür:

var str:String = "The more the merrier."; 
// (This search is case-sensitive.) 
trace(str.search("the")); // output: 9 

Bu örnekte gösterildiği gibi, eşleşen deseni tanımlamak için normal ifadeleri kullanabilirsiniz:

var pattern:RegExp = /the/i; 
var str:String = "The more the merrier."; 
trace(str.search(pattern)); // 0

Dizedeki birinci karakter 0 dizin konumunda olduğundan, trace() yönteminin çıktısı 0'dır. i bayrağı normal ifadede ayarlanır, bu nedenle arama büyük/küçük harf duyarlı değildir.

Normal ifadede g (genel) bayrağı ayarlanmış olsa da, search() yöntemi yalnızca bir eşleşme bulur ve bunun başlangıç dizin konumunu döndürür.

Aşağıdaki örnek, tırnak işareti içindeki bir dizeyle eşleşen, daha karmaşık bir normal ifadeyi gösterir:

var pattern:RegExp = /"[^"]*"/; 
var str:String = "The \"more\" the merrier."; 
trace(str.search(pattern)); // output: 4 
 
str = "The \"more the merrier."; 
trace(str.search(pattern)); // output: -1  
// (Indicates no match, since there is no closing double quotation mark.)

match() yöntemi benzer şekilde çalışır. Eşleşen bir alt dizeyi arar. Ancak, aşağıdaki örnekte olduğu gibi, normal ifade deseninde genel bayrağını kullandığınızda, match() yöntemi, eşleşen alt dizelerin bir dizisini döndürür:

var str:String = "bob@example.com, omar@example.org"; 
var pattern:RegExp = /\w*@\w*\.[org|com]+/g; 
var results:Array = str.match(pattern);

results dizisi şu şekilde ayarlanır:

["bob@example.com","omar@example.org"]

Normal ifadeler hakkında daha fazla bilgi için, bkz. Normal ifadeler kullanma .

Eşleşen alt dizeleri değiştirme

Bir dizedeki belirtilen bir deseni aramak ve eşleşmeleri, belirtilen yerini alan dizeyle değiştirmek için, aşağıdaki örnekte gösterildiği gibi, replace() yöntemini kullanabilirsiniz:

var str:String = "She sells seashells by the seashore."; 
var pattern:RegExp = /sh/gi; 
trace(str.replace(pattern, "sch")); //sche sells seaschells by the seaschore. 

Normal ifadede i ( ignoreCase ) bayrağı ayarlanmış olduğundan, eşleşen dizelerin büyük/küçük harf duyarlı olmadığını ve g ( global ) bayrağı ayarlanmış olduğundan, birden çok eşleşmenin değiştirildiğini unutmayın. Daha fazla bilgi için bkz. Normal ifadeler kullanma .

Yerini alan dizeye şu $ yerini alma kodlarınıdahil edebilirsiniz. Aşağıdaki tabloda gösterilen yerini alan metin, $ yerini alma kodunun yerine eklenir:

Örneğin, aşağıda, eşleşen birinci ve ikinci yakalama grubunu temsil eden $2 ve $1 yerini alma kodlarının kullanımını göstermektedir:

var str:String = "flip-flop"; 
var pattern:RegExp = /(\w+)-(\w+)/g; 
trace(str.replace(pattern, "$2-$1")); // flop-flip

Bir işlevi replace() yönteminin ikinci parametresi olarak da kullanabilirsiniz. Eşleşen metin, işlevin döndürülen değeriyle değiştirilir.

var str:String = "Now only $9.95!"; 
var price:RegExp = /\$([\d,]+.\d+)+/i; 
trace(str.replace(price, usdToEuro)); 
 
function usdToEuro(matchedSubstring:String,                                  capturedMatch1:String,                                  index:int,                                  str:String):String 
{ 
    var usd:String = capturedMatch1; 
    usd = usd.replace(",", ""); 
    var exchangeRate:Number = 0.853690; 
    var euro:Number = parseFloat(usd) * exchangeRate; 
    const euroSymbol:String = String.fromCharCode(8364); 
    return euro.toFixed(2) + " " + euroSymbol; 
}

Bir işlevi, replace() yönteminin ikinci parametresi olarak kullandığınızda, şu argümanlar işleve iletilir:

• Dizenin eşleşen bölümü.

• Herhangi bir yakalama parantez grubu eşleşmesi. Bu şekilde iletilen argüman sayısı, parantez eşleşmelerinin sayısına bağlı olarak değişiklik gösterir. İşlev kodu içinde arguments.length - 3 öğesini kontrol ederek, parantez eşleşmelerinin sayısını belirleyebilirsiniz.

• Eşlemenin başladığı dize içindeki dizin konumu.

• Tam dize.