İlişkilendirilebilir diziler

ActionScript 3.0'da ilişkilendirilebilir dizi oluşturmanın iki yolu vardır. Birinci yol, Object örneği kullanılmasıdır. Object örneği kullanarak, bir nesne değişmeziyle dizinizi başlatabilirsiniz. Object sınıfının genel nesne olarak da adlandırılan bir örneği, ilişkilendirilebilir bir diziyle aynı işleve sahiptir. Genel nesnenin özellik adlarının her biri, saklanan değere erişilmesini sağlayan bir anahtar görevi görür.

Aşağıdaki örnek iki anahtar ve değer çiftiyle diziyi başlatmak için bir nesne değişmezi kullanan monitorInfo adında ilişkilendirilebilir bir dizi oluşturur:

var monitorInfo:Object = {type:"Flat Panel", resolution:"1600 x 1200"}; 
trace(monitorInfo["type"], monitorInfo["resolution"]);  
// output: Flat Panel 1600 x 1200

Bildirim zamanında diziyi başlatmanız gerekmiyorsa, diziyi oluşturmak için Object yapıcısını şu şekilde kullanabilirsiniz:

var monitorInfo:Object = new Object();

Bir nesne değişmezi veya Object sınıfı yapıcısı kullanılarak dizi oluşturulduktan sonra, dizi erişimi ([]) operatörünü veya nokta operatörünü (.) kullanarak diziye yeni değerler ekleyebilirsiniz. Aşağıdaki örnek monitorArray öğesine iki yeni değer ekler:

monitorInfo["aspect ratio"] = "16:10"; // bad form, do not use spaces 
monitorInfo.colors = "16.7 million"; 
trace(monitorInfo["aspect ratio"], monitorInfo.colors); 
// output: 16:10 16.7 million

aspect ratio adındaki anahtarın bir boşluk karakteri içerdiğini unutmayın. Bu, dizi erişimi ([]) operatörüyle mümkün olsa da, nokta operatörüyle denendiğinde hataya yol açar. Anahtar adlarınızda boşluk kullanılması önerilmez.

İlişkilendirilebilir bir dizi oluşturmanın ikinci yolu, Array yapıcısı (veya herhangi bir dinamik sınıf yapıcısı) kullanıldıktan sonra diziye anahtar ve değer çiftleri eklemek için dizi erişimi ([]) operatörünün veya nokta operatörünün (.) kullanılmasıdır. İlişkilendirilebilir dizinizin Array türünde olmasını bildirirseniz, diziyi başlatmak için bir nesne değişmezi kullanamazsınız. Aşağıdaki örnek, Array yapıcısını kullanarak monitorInfo adında ilişkilendirilebilir bir dizi oluşturur ve type adında bir anahtar ile resolution adında bir anahtarı değerleriyle birlikte ekler:

var monitorInfo:Array = new Array(); 
monitorInfo["type"] = "Flat Panel"; 
monitorInfo["resolution"] = "1600 x 1200"; 
trace(monitorInfo["type"], monitorInfo["resolution"]);  
// output: Flat Panel 1600 x 1200

İlişkilendirilebilir bir dizi oluşturmak için Array yapıcısının kullanılması herhangi bir avantaj sağlamaz. Array yapıcısını veya Array veri türünü kullanıyor olsanız da, ilişkilendirilebilir dizilerle Array.length özelliğini veya Array sınıfı yöntemlerinden herhangi birini kullanamazsınız. Dizinlenmiş diziler oluşturmanın en iyi yolu Array yapıcısının kullanılmasıdır.

Anahtarlar için dize yerine nesne kullanan ilişkilendirilebilir bir dizi oluşturmak üzere Dictionary sınıfını kullanabilirsiniz. Bu diziler bazen sözlük, karma veya eşleme olarak adlandırılır. Örneğin, belirli bir konteynerle ilişkisini esas alarak bir Sprite nesnesinin konumunu belirleyen bir uygulamayı göz önünde bulundurun. Sprite nesnelerinin her birini bir konteynere eşlemek için Dictionary nesnesini kullanabilirsiniz.

Aşağıdaki kod, Dictionary nesnesi için anahtar görevi gören üç Sprite sınıfı örneği oluşturur. Her anahtara GroupA veya GroupB değeri atanır. Değerler herhangi bir veri türünde olabilir ancak bu örnekte hem GroupA hem de GroupB Object sınıfının örnekleridir. Daha sonra, aşağıdaki kodda gösterildiği gibi, dizi erişimi ([]) operatörü ile anahtarların her biriyle ilişkilendirilmiş değere erişebilirsiniz:

import flash.display.Sprite; 
import flash.utils.Dictionary; 
 
var groupMap:Dictionary = new Dictionary(); 
 
// objects to use as keys 
var spr1:Sprite = new Sprite(); 
var spr2:Sprite = new Sprite(); 
var spr3:Sprite = new Sprite(); 
 
// objects to use as values 
var groupA:Object = new Object(); 
var groupB:Object = new Object(); 
 
// Create new key-value pairs in dictionary. 
groupMap[spr1] = groupA; 
groupMap[spr2] = groupB; 
groupMap[spr3] = groupB; 
 
if (groupMap[spr1] == groupA) 
{ 
    trace("spr1 is in groupA");  
} 
if (groupMap[spr2] == groupB) 
{ 
    trace("spr2 is in groupB");  
} 
if (groupMap[spr3] == groupB) 
{ 
    trace("spr3 is in groupB");  
}

for (var key:Object in groupMap) 
{ 
    trace(key, groupMap[key]); 
} 
/* output: 
[object Sprite] [object Object] 
[object Sprite] [object Object] 
[object Sprite] [object Object] 
*/

for each (var item:Object in groupMap) 
{ 
    trace(item); 
} 
/* output: 
[object Object] 
[object Object] 
[object Object] 
*/

var myObject:Object = new Object();

import flash.utils.Dictionary; 
 
var myObject:Object = new Object(); 
var myMap:Dictionary = new Dictionary(); 
myMap[myObject] = "foo";

myObject = null; 
delete myMap[myObject];

import flash.utils.Dictionary; 
 
var myObject:Object = new Object(); 
var myMap:Dictionary = new Dictionary(true); 
myMap[myObject] = "foo"; 
myObject = null; // Make object eligible for garbage collection.