Diziler örneği: PlayList

PlayList sınıfı, Song nesnelerinin kümesini yönetir. Oynatma listesine şarkı ekleme (addSong() yöntemi) ve listedeki şarkıları sıralama (sortList() yöntemi) işlevleriyle genel yöntemler içerir. Ayrıca sınıf, oynatma listesindeki gerçek şarkı kümesine erişilmesini sağlayan salt okunur bir erişimci özelliği (songList) içerir. Dahili olarak, PlayList sınıfı özel bir Array değişkenini kullanarak şarkılarını izler:

public class PlayList 
{ 
    private var _songs:Array; 
    private var _currentSort:SortProperty = null; 
    private var _needToSort:Boolean = false; 
    ... 
}

PlayList sınıfı tarafından şarkı listesini izlemek üzere kullanılan _songs Array değişkenine ek olarak, başka iki özel değişken de listenin sıralanması gerekip gerekmediğini (_needToSort) ve şarkı listesinin belirli bir zamanda hangi özelliğe göre sıralandığını (_currentSort) izler.

Tüm nesnelerde olduğu gibi, Array örneğinin bildirilmesi, Array oluşturulması işleminin yalnızca yarısıdır. Bir Array örneğinin özelliklerine veya yöntemlerine erişilmeden önce, PlayList sınıfının yapıcısında Array örneğinin başlatılması gerekir.

    public function PlayList() 
    { 
        this._songs = new Array(); 
        // Set the initial sorting. 
        this.sortList(SortProperty.TITLE); 
    }

Yapıcının ilk satırı, kullanıma hazır olması için _songs değişkenini başlatır. Ayrıca, ilk sıralama özelliğini ayarlamak için sortList() yöntemi çağrılır.

Kullanıcı uygulamaya yeni bir şarkı girdiğinde, veri girişi formundaki kod, PlayList sınıfının addSong() yöntemini çağırır.

    /** 
     * Adds a song to the playlist. 
     */ 
    public function addSong(song:Song):void 
    { 
        this._songs.push(song); 
        this._needToSort = true; 
    }

addSong() içinde, _songs dizisinin push() yöntemi çağrılır ve böylece addSong() öğesine iletilen Song nesnesi o diziye yeni bir öğe olarak eklenir. push() yöntemiyle, önceden uygulanmış olabilecek herhangi bir sıralama dikkate alınmaksızın, yeni öğe dizinin sonuna eklenir. Başka bir deyişle, push() yöntemi çağrıldıktan sonra, şarkı listesi artık doğru şekilde sıralanmaz, bu nedenle _needToSort değişkeni true değerine ayarlanır. Teoride, sortList() yöntemi hemen çağrılabilir, böylece listenin belirli bir zamanda sıralanıp sıralanmadığını izleme gereği ortadan kalkar. Pratikteyse, alınmadan hemen önce şarkı listesinin sıralanması gerekmez. Sıralama işlemi ertelendiğinde, uygulama gereksiz olan sıralama işlemini (örneğin, alınmadan önce listeye birçok şarkı eklendiğinde) gerçekleştirmez.

Oynatma listesi tarafından yönetilen Song örnekleri karmaşık nesneler olduğundan, uygulama kullanıcıları, şarkı başlığı veya yayınlama yılı gibi farklı özelliklere göre oynatma listesini sıralamak isteyebilir. PlayList uygulamasında, şarkı listesini sıralama görevi üç bölüm içerir: listenin sıralanma ölçütü olan özelliği tanımlama, bu özelliğe göre sıralama yapılırken hangi sıralama seçeneklerinin kullanılması gerektiğini belirtme ve gerçek sıralama işlemini gerçekleştirme.

    public static const TITLE:SortProperty = new SortProperty("title"); 
    public static const ARTIST:SortProperty = new SortProperty("artist"); 
    public static const YEAR:SortProperty = new SortProperty("year");

        // Set the initial sorting. 
        this.sortList(SortProperty.TITLE);

    /** 
     * Sorts the list of songs according to the specified property. 
     */ 
    public function sortList(sortProperty:SortProperty):void 
    { 
        ... 
        var sortOptions:uint; 
        switch (sortProperty) 
        { 
            case SortProperty.TITLE: 
                sortOptions = Array.CASEINSENSITIVE; 
                break; 
            case SortProperty.ARTIST: 
                sortOptions = Array.CASEINSENSITIVE; 
                break; 
            case SortProperty.YEAR: 
                sortOptions = Array.NUMERIC; 
                break; 
        } 
         
        // Perform the actual sorting of the data. 
        this._songs.sortOn(sortProperty.propertyName, sortOptions); 
             
        // Save the current sort property. 
        this._currentSort = sortProperty; 
 
        // Record that the list is sorted. 
        this._needToSort = false; 
    }

Dizilerin, şarkı listesini PlayList sınıfında tutmak için kullanılmasına ek olarak, bu örnekte, belirli bir şarkının ait olduğu tür listesinin yönetilmesine yardımcı olmak için de Song sınıfında diziler kullanılır. Song sınıfının tanımındaki bu kod parçasını göz önünde bulundurun:

private var _genres:String; 
 
public function Song(title:String, artist:String, year:uint, filename:String, genres:Array) 
{ 
    ... 
    // Genres are passed in as an array 
    // but stored as a semicolon-separated string. 
    this._genres = genres.join(";"); 
}

Yeni bir Song örneği oluşturulurken, şarkının ait olduğu türü (veya türleri) belirtmek için kullanılan genres parametresi, bir Array örneği olarak tanımlanır. Böylece, birden çok türün yapıcıya iletilebilen tek bir değişken şeklinde gruplanması yararlı hale gelir. Ancak, dahili olarak Song sınıfı, özel _genres değişkenindeki türleri noktalı virgülle ayrılmış bir String örneği olarak tutar. Belirtilen sınırlayıcı olarak ";" değişmez dize değeriyle join() yöntemi çağrılarak, Array parametresi noktalı virgülle ayrılmış bir dizeye dönüştürülür.

Aynı işaretle, genres erişimcileri, türlerin Array olarak ayarlanmasına veya alınmasına olanak sağlar:

    public function get genres():Array 
    { 
        // Genres are stored as a semicolon-separated String, 
        // so they need to be transformed into an Array to pass them back out. 
        return this._genres.split(";"); 
    } 
    public function set genres(value:Array):void 
    { 
        // Genres are passed in as an array, 
        // but stored as a semicolon-separated string. 
        this._genres = value.join(";"); 
    }

genresset erişimcileri yapıcıyla tamamen aynı şekilde hareket eder; bir Array öğesini kabul eder ve bunu noktalı virgülle ayrılmış bir String öğesine dönüştürmek için join() yöntemini çağırır. get erişimcisi tam tersi işlemi gerçekleştirir: _genres değişkeninin split() yöntemi çağrılır, böylece String öğesi, belirtilen sınırlayıcı (daha önceki gibi ";" değişmez dize değeri) kullanılarak değerler dizesine ayrılır.