Dizinlenmiş diziler

Array örneği veya Vector örneği oluşturmak için birçok teknik kullanabilirsiniz. Ancak, her dizi oluşturma tekniği birbirinden farklılık gösterir.

Dizinlenmiş diziye bir öğe eklemenin en temel yolu, dizi erişimi ( [] ) operatörünün kullanılmasıdır. Dizinlenmiş dizi öğesinin değerini ayarlamak için, Array veya Vector nesne adını ve atama deyiminin sol tarafındaki dizin sayısını kullanın:

songTitles[5] = "Happy Birthday";

Array veya Vector öğesi, o dizinde bir öğe içermiyorsa, dizin oluşturulur ve değer orada saklanır. O dizinde değer varsa, yeni değer varolan değerin yerini alır.

Array nesnesi, herhangi bir dizinde öğe oluşturmanıza olanak sağlar. Ancak bir Vector nesnesiyle yalnızca varolan bir dizine veya sonraki mevcut dizine değer atayabilirsiniz. Sonraki mevcut dizin, Vector nesnesinin length özelliğine karşılık gelir. Vector nesnesine yeni bir öğe eklemenin en güvenli yolu, bu listeye benzer bir kod kullanılmasıdır:

myVector[myVector.length] = valueToAdd;

Array ve Vector sınıfı yöntemlerinin üçü ( push() , unshift() ve splice() ) bir dizinlenmiş diziye öğeler eklemenize olanak sağlar. push() yöntemi bir dizinin sonuna bir veya daha fazla öğe ekler. Başka bir deyişle, push() yöntemi kullanılarak bir diziye eklenen son öğe, en yüksek dizin numarasına sahip olacaktır. unshift() yöntemi bir dizinin başına, her zaman 0 dizin numaralı olan bir veya birden fazla öğe ekler. splice() yöntemi dizideki belirli bir dizine istenen sayıda öğe ekler.

Aşağıdaki örnek, bu yöntemlerin üçünü de göstermektedir. Gezegenlerin güneşe yakınlık sıralarına göre gezegenlerin adlarını saklamak için planets adlı bir dizi oluşturulur. Önce, ilk öğe olan Mars öğesini eklemek için push() yöntemi çağrılır. Ardından dizinin önüne ait olan Mercury öğesini eklemek için unshift() yöntemi çağrılır. Son olarak Venus ve Earth öğelerini, Mercury öğesinin arkasına Mars öğesinin önüne eklemek için splice() yöntemi çağrılır. splice() öğesine gönderilen ilk argüman olan 1 tam sayısı, eklemenin dizin 1'den başlaması komutunu verir. splice() öğesine gönderilen ikinci argüman olan 0 tam sayısı, herhangi bir öğenin silinmeyeceğini belirtir. Son olarak, splice() öğesine gönderilen üçüncü ve dördüncü argümanlar olan Venus ve Earth eklenir.

var planets:Array = new Array(); 
planets.push("Mars"); // array contents: Mars 
planets.unshift("Mercury"); // array contents: Mercury,Mars 
planets.splice(1, 0, "Venus", "Earth"); 
trace(planets); // array contents: Mercury,Venus,Earth,Mars

push() ve unshift() yöntemleri, değiştirilen dizinin uzunluğunu temsil eden işaretsiz bir tam sayı döndürür. splice() yöntemi öğe eklemek için kullanıldığında boş bir dizi döndürür; bu her ne kadar garip gelse de splice() yönteminin çok yönlülüğü göz önüne alındığında daha kolay anlaşılabilir. splice() yöntemini yalnızca bir diziye öğe eklemek için değil ayrıca bir diziden öğe kaldırmak için de kullanabilirsiniz. splice() yöntemi öğeleri kaldırmak için kullanıldığında, kaldırılan öğeleri içeren bir dizi döndürür.

Dizinlenmiş diziden bir öğenin değerini almanın en basit yolu, dizi erişimi ( [] ) operatörünün kullanılmasıdır. Dizinlenmiş dizi öğesinin değerini almak için, Array veya Vector nesne adını ve atama deyiminin sağ tarafındaki dizin sayısını kullanın:

var myFavoriteSong:String = songTitles[3];

Herhangi bir öğenin bulunmadığı bir dizin kullanılarak Array veya Vector öğesinden değer almaya çalışılması mümkündür. Bu durumda, Array nesnesi undefined değerini döndürür ve Vector öğesi bir RangeError istisnası atar.

Array ve Vector sınıfının üç yöntemi ( pop() , shift() ve splice() ) öğeleri kaldırmanıza olanak sağlar. pop() yöntemi, dizinin sonundaki öğeyi kaldırır. Başka bir deyişle, en yüksek dizin numarasına sahip öğeyi kaldırır. shift() yöntemi, dizinin başındaki öğeyi, başka bir deyişle, her zaman 0 dizin numarasına sahip olan öğeyi kaldırır. Öğe eklemek için de kullanılabilen splice() yöntemi, yönteme gönderilen ilk argüman tarafından belirtilen dizin numarasından başlayarak rastgele sayıda öğeyi kaldırır.

Aşağıdaki örnek, bir Array örneğinden öğe kaldırmaya yönelik üç yöntemi de kullanır. Geniş su kütlelerinin adlarını saklamak için oceans adında bir Array öğesi oluşturulur. Array öğesindeki adların bazıları okyanus olmayıp göl olduğundan, bu adların kaldırılması gerekir.

İlk olarak Aral ve Superior öğelerini kaldırmak ve Atlantic ve Indian öğelerini eklemek için splice() yöntemi kullanılır. splice() öğesine gönderilen ilk argüman olan 2 tam sayısı, işlemin dizin 2'deki listede bulunan üçüncü öğeden başlaması gerektiğini belirtir. İkinci argüman olan 2, iki öğenin kaldırılması gerektiğini belirtir. Kalan argümanlar olan Atlantic ve Indian , dizin 2 konumuna eklenecek değerlerdir.

İkinci olarak, dizideki son öğe olan Huron öğesini kaldırmak için pop() yöntemi kullanılır. Üçüncü olarak da, dizideki ilk öğe olan Victoria öğesini kaldırmak için shift() yöntemi kullanılır.

var oceans:Array = ["Victoria", "Pacific", "Aral", "Superior", "Indian", "Huron"]; 
oceans.splice(2, 2, "Arctic", "Atlantic"); // replaces Aral and Superior 
oceans.pop(); // removes Huron 
oceans.shift(); // removes Victoria 
trace(oceans);// output: Pacific,Arctic,Atlantic,Indian

pop() ve shift() yöntemleri, kaldırılan öğeyi döndürür. Bir Array örneği için, diziler herhangi bir veri türünün değerlerini bulundurabildiğinden, döndürülen değerin veri türü Object olur. Vector örneği için, döndürülen değerin veri türü, Vector öğesinin taban türüdür. splice() yöntemi, kaldırılan değerleri içeren bir Array veya Vector öğesini döndürür. Aşağıdaki örnekte gösterildiği gibi, splice() öğesine yapılan bir çağrı, döndürülen Array öğesini yeni bir Array değişkenine atayacak şekilde oceans Array örneğini değiştirebilirsiniz:

var lakes:Array = oceans.splice(2, 2, "Arctic", "Atlantic"); 
trace(lakes); // output: Aral,Superior

Bir Array nesnesi öğesinde delete operatörünü kullanan bir kodla karşılaşabilirsiniz. delete operatörü, bir Array öğesinin değerini undefined olarak ayarlar ancak öğeyi Array öğesinden kaldırmaz. Örneğin, şu kod oceans Array içindeki üçüncü öğede delete operatörünü kullanır, ancak Array öğesinin uzunluğu 5 olarak kalır:

var oceans:Array = ["Arctic", "Pacific", "Victoria", "Indian", "Atlantic"]; 
delete oceans[2]; 
trace(oceans);// output: Arctic,Pacific,,Indian,Atlantic 
trace(oceans[2]); // output: undefined 
trace(oceans.length); // output: 5

Bir dizinin length özelliğini kullanarak Array veya Vector öğesini kırpabilirsiniz. Dizinlenmiş dizinin length özelliğini geçerli dizi uzunluğundan düşük bir uzunluğa ayarlarsanız, yeni length eksi 1 değerinden yüksek dizin sayılarında saklanan öğeler kaldırılarak dizi kırpılır. Örneğin, oceans dizisi, tüm geçerli girişler dizinin başında olacak şekilde sıralansaydı, şu kodda gösterildiği gibi, dizinin sonundaki girişleri kaldırmak için length özelliğini kullanabilirdiniz:

var oceans:Array = ["Arctic", "Pacific", "Victoria", "Aral", "Superior"]; 
oceans.length = 2; 
trace(oceans); // output: Arctic,Pacific

Sıralamayı düzenleyerek veya ters çevirerek dizinlenmiş dizinin sıralamasını değiştirmenize olanak sağlayan üç yöntem vardır: reverse() , sort() ve sortOn() Bu yöntemlerin tümü, varolan diziyi değiştirir. Aşağıdaki tabloda, bu yöntemler ve bu yöntemlerin Array ve Vector nesnelerine yönelik davranışı özetlenmektedir:

var oceans:Array = ["Arctic", "Atlantic", "Indian", "Pacific"]; 
oceans.reverse(); 
trace(oceans); // output: Pacific,Indian,Atlantic,Arctic

var poets:Array = ["Blake", "cummings", "Angelou", "Dante"]; 
poets.sort(); // default sort 
trace(poets); // output: Angelou,Blake,Dante,cummings 
 
poets.sort(Array.CASEINSENSITIVE); 
trace(poets); // output: Angelou,Blake,cummings,Dante 
 
poets.sort(Array.DESCENDING); 
trace(poets); // output: cummings,Dante,Blake,Angelou 
 
poets.sort(Array.DESCENDING | Array.CASEINSENSITIVE); // use two options 
trace(poets); // output: Dante,cummings,Blake,Angelou

var names:Array = new Array("John Q. Smith", "Jane Doe", "Mike Jones"); 
function orderLastName(a, b):int 
{ 
    var lastName:RegExp = /\b\S+$/; 
    var name1 = a.match(lastName); 
    var name2 = b.match(lastName); 
    if (name1 < name2) 
    { 
        return -1; 
    } 
    else if (name1 > name2) 
    { 
        return 1; 
    } 
    else 
    { 
        return 0; 
    } 
} 
trace(names); // output: John Q. Smith,Jane Doe,Mike Jones 
names.sort(orderLastName); 
trace(names); // output: Jane Doe,Mike Jones,John Q. Smith

var poets:Array = new Array(); 
poets.push({name:"Angelou", born:"1928"}); 
poets.push({name:"Blake", born:"1757"}); 
poets.push({name:"cummings", born:"1894"}); 
poets.push({name:"Dante", born:"1265"}); 
poets.push({name:"Wang", born:"701"});

poets.sortOn("born", Array.NUMERIC); 
for (var i:int = 0; i < poets.length; ++i) 
{ 
    trace(poets[i].name, poets[i].born); 
} 
/* output: 
Wang 701 
Dante 1265 
Blake 1757 
cummings 1894 
Angelou 1928 
*/

var indices:Array; 
indices = poets.sortOn("born", Array.NUMERIC | Array.RETURNINDEXEDARRAY); 
for (var i:int = 0; i < indices.length; ++i) 
{ 
    var index:int = indices[i]; 
    trace(poets[index].name, poets[index].born); 
} 
/* output: 
Wang 701 
Dante 1265 
Blake 1757 
cummings 1894 
Angelou 1928 
*/

Array ve Vector sınıfının dört yönteminin tümü ( concat() , join() , slice() ve toString() ) bilgi için diziyi sorgular ancak diziyi değiştirmez. concat() ve slice() yöntemleri yeni diziler döndürürken, join() ve toString() yöntemleri de dize döndürür. concat() yöntemi, argüman olarak yeni bir diziyi veya öğeler listesini alır ve yeni bir dizi oluşturmak için bunları varolan diziyle birleştirir. slice() yöntemi, startIndex ve endIndex adında iki parametre içerir ve varolan diziden "dilimli" öğelerin bir kopyasını içeren yeni bir dizi döndürür. Dilim, startIndex parametresindeki öğeyle başlar ve endIndex parametresinden hemen önceki öğeyle sona erer. Şunu yinelemekte fayda var: endIndex parametresindeki öğe döndürme değerine dahil edilmez.

Aşağıdaki örnek, diğer dizilerin öğelerini kullanarak yeni diziler oluşturmak için concat() ve slice() öğelerini kullanır:

var array1:Array = ["alpha", "beta"]; 
var array2:Array = array1.concat("gamma", "delta"); 
trace(array2); // output: alpha,beta,gamma,delta 
 
var array3:Array = array1.concat(array2); 
trace(array3); // output: alpha,beta,alpha,beta,gamma,delta 
 
var array4:Array = array3.slice(2,5); 
trace(array4); // output: alpha,beta,gamma

Diziyi sorgulayıp dizinin içeriklerini dize olarak döndürmek için join() ve toString() yöntemlerini kullanabilirsiniz. join() yöntemi için herhangi bir parametre kullanılmıyorsa, iki yöntem de aynı şekilde hareket ederek dizideki tüm öğelerin virgül sınırlı listesini içeren bir dize döndürür. join() yöntemi, toString() yönteminden farklı olarak, döndürülen dizedeki her öğe arasında ayırıcı olarak kullanılacak sembolü seçmenizi sağlayan delimiter adında bir parametreyi kabul eder.

Aşağıdaki örnek, rivers adında bir Array öğesi oluşturur ve Array öğesindeki değerleri dize olarak döndürmek için hem join() hem de toString() öğelerini çağırır. toString() yöntemi virgül sınırlı değerler ( riverCSV ) döndürmek için kullanılırken, join() yöntemi + karakteriyle ayrılmış değerler döndürmek için kullanılır.

var rivers:Array = ["Nile", "Amazon", "Yangtze", "Mississippi"]; 
var riverCSV:String = rivers.toString(); 
trace(riverCSV); // output: Nile,Amazon,Yangtze,Mississippi 
var riverPSV:String = rivers.join("+"); 
trace(riverPSV); // output: Nile+Amazon+Yangtze+Mississippi

join() yöntemiyle ilgili bilinmesi gereken bir nokta, aşağıdaki örnekte gösterildiği gibi, ana dizi öğeleri için hangi ayırıcıyı belirttiğinize bakılmaksızın, yuvalanmış Array veya Vector örneklerinin her zaman virgülle ayrılmış değerlerle döndürülmesidir:

var nested:Array = ["b","c","d"]; 
var letters:Array = ["a",nested,"e"];  
var joined:String = letters.join("+"); 
trace(joined); // output: a+b,c,d+e