Normal ifade örneği: Wiki ayrıştırıcısı

WikiParser sınıfı, Wiki girdi metnini eşdeğer HTML çıktısına dönüştüren yöntemleri içerir. Bu çok güçlü bir Wiki dönüştürme uygulaması değildir ancak desen eşleştirme ve dize dönüştürmesi için normal ifadelerin bazı kullanımlarını gösterir.

setWikiData() yöntemiyle birlikte yapıcı işlevi yalnızca aşağıdaki gibi Wiki girdi metninin örnek bir dizesini başlatır:

public function WikiParser() 
{ 
    wikiData = setWikiData(); 
}

Kullanıcı örnek uygulamada Test Et düğmesini tıklattığında, uygulama, WikiParser nesnesinin parseWikiString() yöntemini çağırır. Bu yöntem, başka birçok yöntemi çağırır ve bu yöntemler de daha sonra sonuçta elde edilen HTML dizesini oluşturur.

public function parseWikiString(wikiString:String):String 
{ 
    var result:String = parseBold(wikiString); 
    result = parseItalic(result); 
    result = linesToParagraphs(result); 
    result = parseBullets(result); 
    return result; 
}

Çağrılan yöntemlerin her biri (parseBold(), parseItalic(), linesToParagraphs() ve parseBullets()), girdi Wiki metnini HTML olarak formatlanmış metne dönüştürmek üzere bir normal ifade tarafından tanımlandığı şekilde, eşleşen desenleri değiştirmek için dizenin replace() yöntemini kullanır.

private function parseBold(input:String):String 
{ 
    var pattern:RegExp = /'''(.*?)'''/g; 
    return input.replace(pattern, "<b>$1</b>"); 
}

private function parseItalic(input:String):String 
{ 
    var pattern:RegExp = /''(.*?)''/g; 
    return input.replace(pattern, "<i>$1</i>"); 
}

private function parseBullets(input:String):String 
{ 
    var pattern:RegExp = /^\*(.*)/gm; 
    return input.replace(pattern, "<li>$1</li>"); 
}

var pattern:RegExp = /^$/gm; 
var result:String = input.replace(pattern, "");

Kullanıcı, urlToATag onay kutusunu seçmişse, örnek uygulamada Test Et düğmesini tıklattığında, uygulama, URL dizelerini girdi Wiki dizesinden HTML <a> etiketlerine dönüştürmek için URLParser.urlToATag() statik yöntemini çağırır

var protocol:String = "((?:http|ftp)://)"; 
var urlPart:String = "([a-z0-9_-]+\.[a-z0-9_-]+)"; 
var optionalUrlPart:String = "(\.[a-z0-9_-]*)"; 
var urlPattern:RegExp = new RegExp(protocol + urlPart + optionalUrlPart, "ig"); 
var result:String = input.replace(urlPattern, "<a href='$1$2$3'><u>$1$2$3</u></a>");

RegExp() yapıcı işlevi, çok sayıda bileşenden tek bir normal ifade (urlPattern) oluşturmak için kullanılır. Bu bileşenlerin her biri, normal ifade deseninin parçasını tanımlayan dizelerdir.

protocol dizesi tarafından tanımlanan normal ifade deseninin birinci bölümü, http:// veya ftp:// olmak üzere bir URL protokolünü tanımlar. Parantezler, ? sembolüyle belirtilen, yakalama yapmayan bir grubu tanımlar. Başka bir deyişle, parantezler yalnızca | değiştirme desenine yönelik bir grubu tanımlamak için kullanılır; bu grup, replace() yönteminin yerini alan dizesinde geribaşvuru kodlarıyla ($1, $2, $3) eşleşmez.

Normal ifadeyi oluşturan diğer bileşenlerin her biri, daha sonra replace() yönteminin yerini alan dizesindeki geribaşvuru kodlarında ($1, $2, $3) kullanılan yakalama gruplarını (desende parantezlerle belirtilir) kullanır.

Desenin, urlPart dizesi tarafından tanımlanan bölümü, şu karakterlerden en az biriyle eşleşir: a-z, 0-9, _ veya -. + nicelik belirteci, en az bir karakterin eşleştiğini belirtir. Şu \. öğesi, zorunlu bir nokta (.) karakterini belirtir. Ve geri kalan kısım da bu karakterlerden en az birini içeren bir dizeyle eşleşir: a-z, 0-9, _ veya -.

Desenin, optionalUrlPart dizesiyle tanımlanan bölümü, şunlardan hiçbiriyle veya bir ya da birkaç tanesiyle eşleşir: nokta (.) karakteri ve onu takip eden herhangi bir sayıda alfasayısal karakter (_ ve - dahil). * nicelik belirteci, bu karakterlerden hiçbirinin eşleşmediğini veya bir ya da birkaçının eşleştiğini belirtir.

replace() yöntemine yapılan çağrı, normal ifadeyi kullanır ve geribaşvuruları kullanarak, yerini alan HTML dizesini oluşturur.

Daha sonra urlToATag() yöntemi, e-posta desenlerini, HTML <a> köprü dizeleriyle değiştirme tekniğine benzer teknikler kullanan emailToATag() yöntemini çağırır. Bu örnek dosyada HTTP, FTP ve e-posta URL'leriyle eşleşme yapmak için kullanılan normal ifadeler, örneklendirme amacıyla nispeten basit tutulmuştur; bu URL'lerin daha doğru şekilde eşleştirilmesi için daha karmaşık normal ifadeler vardır.

Kullanıcı dollarToEuro onay kutusunu seçmişse, örnek uygulamadaki Test Et düğmesini tıklattığında, aşağıdaki gibi uygulama, ABD doları dizelerini (örn. "$9.95") euro dizelerine (örn. "8.24 €") dönüştürmek için, CurrencyConverter.usdToEuro() statik yöntemini çağırır:

var usdPrice:RegExp = /\$([\d,]+.\d+)+/g; 
return input.replace(usdPrice, usdStrToEuroStr); 

Birinci satır, ABD doları dizelerinin eşleşmesi için basit bir deseni tanımlar. $ karakterinin önüne ters eğik çizgi (\) kaçış karakterinin getirildiğine dikkat edin.

replace() yöntemi, desen eşleştirici olarak normal ifadeyi kullanır ve yerini alacak dizeyi (euro cinsinden bir değer) belirlemek için usdStrToEuroStr() işlevini çağırır.

replace() yönteminin ikinci parametresi olarak bir işlev adı kullanıldığında, çağrılan işleve parametre olarak şunlar iletilir:

• Dizenin eşleşen bölümü.

• Herhangi bir yakalanmış parantez grubu eşleşmesi. Bu şekilde iletilen argüman sayısı, yakalanan parantez grubu eşleşmelerinin sayısına bağlı olarak değişiklik gösterir. İşlev kodu içinde arguments.length - 3 öğesini kontrol ederek, yakalanmış parantez grubu eşleşmelerinin sayısını belirleyebilirsiniz.

• Eşlemenin başladığı dize içindeki dizin konumu.

• Tam dize.

usdStrToEuroStr() yöntemi şu şekilde ABD doları dize desenlerini euro dizelerine dönüştürür:

private function usdToEuro(...args):String 
{ 
    var usd:String = args[1]; 
    usd = usd.replace(",", ""); 
    var exchangeRate:Number = 0.828017; 
    var euro:Number = Number(usd) * exchangeRate; 
    trace(usd, Number(usd), euro); 
    const euroSymbol:String = String.fromCharCode(8364); // € 
    return euro.toFixed(2) + " " + euroSymbol;  
}

args[1] öğesinin, usdPrice normal ifadesinin eşleştiği yakalanmış parantez grubunu temsil ettiğini unutmayın. Bu, ABD doları dizesinin sayısal bölümüdür: başka bir deyişle, $ işareti olmadan dolar miktarıdır. Bu yöntem, döviz kuru dönüştürmesi uygular ve bir sonuç dizesi (başında $ sembolü yerine, sonunda € sembolü bulunan) döndürür.