ActionScript'te XML örneği: internetten RSS verilerini yükleme

RSSParser sınıfı, rssXML değişkeninde saklanan girdi RSS verilerini HTML olarak biçimlendirilmiş çıktı (rssOutput) içeren bir dizeye dönüştüren xmlLoaded() yöntemini içerir.

Kaynak RSS verileri varsayılan bir ad alanı içeriyorsa, kod, yöntemin başına yakın konumda varsayılan XML ad alanını ayarlar:

if (rssXML.namespace("") != undefined) 
{ 
    default xml namespace = rssXML.namespace(""); 
}

Sonraki satırlar, kaynak XML verisinin içerikleri üzerinde döngü gerçekleştirerek item adındaki alt öğe özelliklerinin her birini inceler:

for each (var item:XML in rssXML..item) 
{ 
    var itemTitle:String = item.title.toString(); 
    var itemDescription:String = item.description.toString(); 
    var itemLink:String = item.link.toString(); 
    outXML += buildItemHTML(itemTitle,  
                            itemDescription, 
                            itemLink); 
}

İlk üç satır, dize değişkenlerini, XML verisinin item özelliğinin başlık, açıklama ve bağlantı özelliklerini temsil edecek şekilde ayarlar. Sonraki satır, parametre olarak üç yeni dize değişkeni kullanarak, HTML verilerini bir XMLList nesnesi biçiminde almak için buildItemHTML() yöntemini çağırır.

HTML verileri (bir XMLList nesnesi) şu biçimde olabilir:

<b>itemTitle</b> 
<p> 
    itemDescription 
    <br /> 
    <a href="link"> 
        <font color="#008000">More...</font> 
    </a> 
</p>

Yöntemin birinci satırları, varsayılan xml ad alanını temizler:

default xml namespace = new Namespace();

default xml namespace direktifi, blok düzeyinde kapsam işlevine sahiptir. Başka bir deyişle, bu bildirimin kapsamı buildItemHTML() yöntemidir.

Bunu izleyen satırlar, işleve iletilen dize argümanlarını esas alarak XMLList öğesini oluşturur:

var body:XMLList = new XMLList(); 
body += new XML("<b>" + itemTitle + "</b>"); 
var p:XML = new XML("<p>" + itemDescription + "</p>"); 
 
var link:XML = <a></a>; 
link.@href = itemLink; // <link href="itemLinkString"></link> 
link.font.@color = "#008000";  
        // <font color="#008000"></font></a> 
        // 0x008000 = green 
link.font = "More..."; 
 
p.appendChild(<br/>);  
p.appendChild(link);  
body += p;

Bu XMLList nesnesi, ActionScript HTML metin alanı için uygun olan dize verisini temsil eder.

xmlLoaded() yöntemi, buildItemHTML() yönteminin döndürme değerini kullanır ve bunu bir dizeye dönüştürür:

XML.prettyPrinting = false; 
rssOutput = outXML.toXMLString();    

xmlLoaded() yöntemi, kaynak RSS XML verisindeki bilgileri esas alarak bir rssTitle dize değişkeni ayarlar:

rssTitle = rssXML.channel.title.toString();

Son olarak, xmlLoaded() yöntemi, verilerin ayrıştırıldığını ve kullanılabilir olduğunu uygulamaya bildiren bir olay oluşturur:

            dataWritten = new Event("dataWritten", true);