XML nesnelerini birleştirme ve dönüştürme

Flash Player 9 ve üstü, Adobe AIR 1.0 ve üstü

XML nesnesinin özellikler listesinin başına veya sonuna bir özellik eklemek için, aşağıdaki örnekte gösterildiği gibi, prependChild() yöntemini veya appendChild() yöntemini kullanın:

var x1:XML = <p>Line 1</p>  
var x2:XML = <p>Line 2</p>  
var x:XML = <body></body> 
x = x.appendChild(x1); 
x = x.appendChild(x2); 
x = x.prependChild(<p>Line 0</p>); 
    // x == <body><p>Line 0</p><p>Line 1</p><p>Line 2</p></body>

Belirtilen bir özellikten önce veya sonra bir özellik eklemek için, aşağıda gösterildiği gibi, insertChildBefore() yöntemini ya da insertChildAfter() yöntemini kullanın:

var x:XML =  
    <body> 
        <p>Paragraph 1</p>  
        <p>Paragraph 2</p> 
    </body> 
var newNode:XML = <p>Paragraph 1.5</p>  
x = x.insertChildAfter(x.p[0], newNode) 
x = x.insertChildBefore(x.p[2], <p>Paragraph 1.75</p>)

Aşağıdaki örnekte gösterildiği gibi, XML nesneleri oluştururken başvuruya göre (diğer değişkenlerden) veri iletmek için küme ayracı operatörlerini de ( { ve } ) kullanabilirsiniz:

var ids:Array = [121, 122, 123];  
var names:Array = [["Murphy","Pat"], ["Thibaut","Jean"], ["Smith","Vijay"]] 
var x:XML = new XML("<employeeList></employeeList>"); 
 
for (var i:int = 0; i < 3; i++) 
{ 
    var newnode:XML = new XML();  
    newnode = 
        <employee id={ids[i]}> 
            <last>{names[i][0]}</last> 
            <first>{names[i][1]}</first> 
        </employee>; 
 
    x = x.appendChild(newnode) 
}

Aşağıdaki gibi, = operatörünü kullanarak bir XML nesnesine özellikler ve nitelikler atayabilirsiniz:

var x:XML =  
    <employee> 
        <lastname>Smith</lastname> 
    </employee> 
x.firstname = "Jean"; 
x.@id = "239";

Böylece x XML nesnesi şunlara ayarlanır:

<employee id="239"> 
    <lastname>Smith</lastname> 
    <firstname>Jean</firstname> 
</employee>

XMLList nesnelerini bitiştirmek için + ve += operatörlerini kullanabilirsiniz:

var x1:XML = <a>test1</a>  
var x2:XML = <b>test2</b>  
var xList:XMLList = x1 + x2; 
xList += <c>test3</c>

Böylece xList XMLList nesnesi şunlara ayarlanır:

<a>test1</a> 
<b>test2</b> 
<c>test3</c>