Çizim API'si ile içerik oluşturmanın bir avantajı, içeriğinizi yalnızca bir defa konumlandırma sınırınızın olmamasıdır. Çizim yapmak için kullandığınız değişkenler korunarak veya değiştirilerek, çizdikleriniz değiştirilebilir. Değişkenleri değiştirip yeniden çizim yaparak, kareler dizisi üzerinden veya bir zamanlayıcı ile animasyon yürütebilirsiniz.
Örneğin, aşağıdaki kod, geçerli derece sayısını artırarak her ilerleyen kareyle görüntüyü değiştirir (
Event.ENTER_FRAME
olayını dinleyip) ve grafik nesnelerine silinmesini ve güncellenmiş konumla yeniden çizilmesini bildirir.
stage.frameRate = 31;
var currentDegrees:Number = 0;
var radius:Number = 40;
var satelliteRadius:Number = 6;
var container:Sprite = new Sprite();
container.x = stage.stageWidth / 2;
container.y = stage.stageHeight / 2;
addChild(container);
var satellite:Shape = new Shape();
container.addChild(satellite);
addEventListener(Event.ENTER_FRAME, doEveryFrame);
function doEveryFrame(event:Event):void
{
currentDegrees += 4;
var radians:Number = getRadians(currentDegrees);
var posX:Number = Math.sin(radians) * radius;
var posY:Number = Math.cos(radians) * radius;
satellite.graphics.clear();
satellite.graphics.beginFill(0);
satellite.graphics.drawCircle(posX, posY, satelliteRadius);
}
function getRadians(degrees:Number):Number
{
return degrees * Math.PI / 180;
}
Çok farklı bir sonuç üretmek için, kodun başındaki başlangıç tohum değişkenlerini (
currentDegrees
,
radius
ve
satelliteRadius
) değiştirerek deneme yapabilirsiniz. Örneğin, yarıçap değişkenini daraltmayı ve/veya totalSatellites değişkenini artırmayı deneyin. Bu, çizim API'sinin nasıl karmaşıklığı nedeniyle oluşturma basitliği gizlenen bir görüntü oluşturabildiğini gösteren örneklerden yalnızca biridir.
