Degrade ışıma filtresi

Flash Player 9 ve üstü, Adobe AIR 1.0 ve üstü

GradientBevelFilter sınıfı görüntüleme nesnelerine veya BitmapData nesnelerine gelişmiş bir ışıma efekti uygulamanıza olanak verir. Bu efekt, ışıma üzerinde daha fazla denetim elde etmenizi sağlar ve sonuç olarak daha gerçekçi bir ışıma efekti oluşturur. Ayrıca, degrade ışıma filtresi, bir nesnenin iç, dış veya üst kenarlarına bir degrade ışıma uygulamanıza olanak sağlar.

Aşağıdaki örnek, Sahne Alanı'na bir daire çizer ve buna bir degrade ışıma filtresi uygular. Fareyi sağa ve aşağı doğru hareket ettirdikçe, bulanıklaştırma miktarı sırayla yatay ve dikey yönlerde artar. Ayrıca, Sahne Alanı'nı her tıklattığınızda, bulanıklaştırmanın gücü de artar.

import flash.events.MouseEvent; 
import flash.filters.BitmapFilterQuality; 
import flash.filters.BitmapFilterType; 
import flash.filters.GradientGlowFilter; 
 
// Create a new Shape instance. 
var shape:Shape = new Shape(); 
 
// Draw the shape. 
shape.graphics.beginFill(0xFF0000, 100); 
shape.graphics.moveTo(0, 0); 
shape.graphics.lineTo(100, 0); 
shape.graphics.lineTo(100, 100); 
shape.graphics.lineTo(0, 100); 
shape.graphics.lineTo(0, 0); 
shape.graphics.endFill(); 
 
// Position the shape on the Stage. 
addChild(shape); 
shape.x = 100; 
shape.y = 100; 
 
// Define a gradient glow. 
var gradientGlow:GradientGlowFilter = new GradientGlowFilter(); 
gradientGlow.distance = 0; 
gradientGlow.angle = 45; 
gradientGlow.colors = [0x000000, 0xFF0000]; 
gradientGlow.alphas = [0, 1]; 
gradientGlow.ratios = [0, 255]; 
gradientGlow.blurX = 10; 
gradientGlow.blurY = 10; 
gradientGlow.strength = 2; 
gradientGlow.quality = BitmapFilterQuality.HIGH; 
gradientGlow.type = BitmapFilterType.OUTER; 
 
// Define functions to listen for two events. 
function onClick(event:MouseEvent):void 
{ 
    gradientGlow.strength++; 
    shape.filters = [gradientGlow]; 
} 
 
function onMouseMove(event:MouseEvent):void 
{ 
    gradientGlow.blurX = (stage.mouseX / stage.stageWidth) * 255; 
    gradientGlow.blurY = (stage.mouseY / stage.stageHeight) * 255; 
    shape.filters = [gradientGlow]; 
} 
stage.addEventListener(MouseEvent.CLICK, onClick); 
stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);