Film klibi örneği: RuntimeAssetsExplorer

Gezginin düzgün şekilde SWF kütüphanesiyle etkileşim kurması için, çalışma zamanı varlığı kütüphanelerinin yapısının biçimlendirilmesi gerekir. Beklenen bir yapıyı ayıran yöntemlerin şeması olması yönüyle bir sınıfa benzeyen ancak sınıftan farklı olarak herhangi bir yöntem gövdesi içermeyen bir arabirim oluşturarak bunu gerçekleştireceğiz. Arabirim, hem çalışma zamanı kütüphanesinin hem de gezginin birbiriyle iletişim kurması için bir yol sağlar. Tarayıcımıza yüklenen çalışma zamanı varlıklarının her SWF dosyası bu arabirimi uygular. Arabirimler ve arabirimlerin nasıl kullanışlı olabileceği hakkında daha fazla bilgi için, ActionScript 3.0'ı Öğrenme 'deki Arabirimler'e bakın.

RuntimeLibrary arabirimi çok basit olacaktır—yalnızca içe aktarılacak olan ve çalışma zamanı kütüphanesinde kullanılabilir olan sembollerin sınıf yollarının bir dizisini gezgine sağlayabilecek bir işlev gerektirmekteyiz. Bu amaçla, arabirim tek bir yönteme sahiptir: getAssets() .

package com.example.programmingas3.runtimeassetexplorer 
{ 
    public interface RuntimeLibrary 
    { 
        function getAssets():Array; 
    } 
}

RuntimeLibrary arabirimi tanımlanarak, SWF dosyalarının başka bir SWF dosyasına yüklenebileceği birden çok varlık kütüphanesi oluşturulması mümkündür. Tek tek varlıkların SWF kütüphanesinin oluşturulması dört görev içerir:

• Varlık kütüphanesi SWF dosyası için bir sınıf oluşturma

• Kütüphanede bulunan tek tek varlıklar için sınıflar oluşturma

• Gerçek grafik varlıkları oluşturma

• Grafik öğelerini sınıflarla ilişkilendirme ve kütüphane SWF dosyasını yayınlama

package 
{ 
    import flash.display.Sprite; 
    import com.example.programmingas3.runtimeassetexplorer.RuntimeLibrary; 
     
    public class GeometricAssets extends Sprite implements RuntimeLibrary  
    { 
        public function GeometricAssets() { 
             
        } 
        public function getAssets():Array { 
            return [ "com.example.programmingas3.runtimeassetexplorer.AnimatingBox", 
                     "com.example.programmingas3.runtimeassetexplorer.AnimatingStar" ];     
        } 
    } 
}

package com.example.programmingas3.runtimeassetexplorer 
{ 
    import flash.display.MovieClip; 
     
    public class AnimatingStar extends MovieClip 
    { 
        public function AnimatingStar() { 
        } 
    } 
}

Uygulanacak son işlev, varlık gezgininin kullanıcı arabirimidir. Bu örnekte, çalışma zamanı kütüphanesinin yolu ASSETS_PATH adında bir değişken olarak kodlanmıştır. Alternatif olarak, örneğin, sabit sürücünüzde belirli bir SWF dosyasına gözatan bir arabirim oluşturmak için, FileReference sınıfını oluşturabilirsiniz.

Çalışma zamanı kütüphanesi başarıyla yüklendiğinde, Flash Player runtimeAssetsLoadComplete() yöntemini çağırır:

private function runtimeAssetsLoadComplete(event:Event):void 
{ 
    var rl:* = event.target.content; 
    var assetList:Array = rl.getAssets(); 
    populateDropdown(assetList); 
    stage.frameRate = 60; 
}

Bu yöntemde, rl değişkeni yüklenen SWF dosyasını temsil eder. Kod, yüklenen SWF dosyasının getAssets() yöntemini çağırarak kullanılabilir olan varlıkların listesini alır ve populateDropDown() yöntemini çağırarak bir ComboBox bileşenini kullanılabilir varlıkların bir listesiyle doldurmak için bunları kullanır. Daha sonra da bu yöntem her varlığın tam sınıf yolunu saklar. Kullanıcı arabiriminde Ekle düğmesi tıklatıldığında addAsset() yöntemi tetiklenir:

private function addAsset():void 
{ 
    var className:String = assetNameCbo.selectedItem.data; 
    var AssetClass:Class = getDefinitionByName(className) as Class; 
    var mc:MovieClip = new AssetClass(); 
    ... 
}

bu yöntem, ComboBox öğesinde geçerli olarak seçilmiş varlığın sınıf yolunu ( assetNameCbo.selectedItem.data ) alır ve o varlığın yeni bir örneğini oluşturmak üzere varlığın sınıfına gerçek bir başvuruyu almak için getDefinitionByName() işlevini (flash.utils paketinden) kullanır.