Harici verileri yükleme

Harici veri yükleyen çoğu API, gerekli ağ talebinin özelliklerini tanımlamak için URLRequest sınıfını kullanır.

URLLoader sınıfı, bir sunucuya talep göndermenize ve verilen bilgilere ulaşmanıza izin verir. URLLoader sınıfını yerel dosya erişimine izin verilen bağlamlardaki (Flash Player dosya sistemiyle yerel sanal alanı ve AIR uygulaması sanal alanı gibi) yerel dosya sistemi üzerinde bulunan dosyalara erişmek için de kullanabilirsiniz. URLLoader sınıfı bir URL'den metin, ikili veri veya URL olarak kodlanmış değişkenler olarak veri indirir. URLLoader sınıfı complete , httpStatus , ioError , open , progress ve securityError gibi olaylar gönderir.

ActionScript 3.0 olay işleme modeli, LoadVars.onData , LoadVars.onHTTPStatus ve LoadVars.onLoad olay işleyicilerini kullanan ActionScript 2.0 modelinden büyük ölçüde farklıdır. ActionScript 3.0’da olayları işleme hakkında daha fazla bilgi edinmek için bkz. Olayları işleme

İndirilen veriler, indirme işlemi tamamlanana kadar kullanılamaz. progress olayının gönderilmesini dinleyerek indirmenin ilerlemesini (yüklenen baytlar ve toplam bayt) denetleyebilirsiniz. Ancak, bir dosya yeterince hızlı yüklenirse progress olayı gönderilmeyebilir. Bir dosya başarıyla yüklendiğinde complete olayı gönderilir. URLLoader dataFormat özelliğini ayarlayarak, verileri metin, ham ikili veri veya bir URLVariables nesnesi olarak alabilirsiniz.

URLLoader.load() yöntemi (ve isteğe bağlı olarak URLLoader sınıfının yapıcısı), URLRequest nesnesi olan tek bir parametre ( request ) alır. URLRequest nesnesi, hedef URL, istek yöntemi ( GET veya POST ), ek başlık bilgileri ve MIME türü gibi tek bir HTTP isteğinin tüm bilgilerini içerir.

Örneğin, sunucu tarafı komut dosyasına bir XML paketi yüklemek için aşağıdaki kodu kullanabilirsiniz:

var secondsUTC:Number = new Date().time; 
var dataXML:XML =  
    <clock> 
        <time>{secondsUTC}</time> 
    </clock>; 
var request:URLRequest = new URLRequest("http://www.yourdomain.com/time.cfm"); 
request.contentType = "text/xml"; 
request.data = dataXML.toXMLString(); 
request.method = URLRequestMethod.POST; 
var loader:URLLoader = new URLLoader(); 
loader.load(request); 

Önceki kod parçası, sunucuya gönderilecek XML paketini içeren dataXML adında bir XML örneği oluşturur. Örnek, URLRequest contentType özelliğini "text/xml" olarak ayarlar ve XML belgesini URLRequest data özelliğine atar. Son olarak, örnek bir URLLoader nesnesi oluşturup load() yöntemini kullanarak uzak komut dosyasına talebi gönderir.

URLStream sınıfı indirme verileri geldiğinde bu verilere erişim sağlar. URLStream sınıfı ayrıca, indirmeyi tamamlamadan önce bir akışı kapatmanıza olanak verir. İndirilen veri, ham ikili veri olarak mevcuttur.

Bir URLStream nesnesinden veri okurken, okumadan önce yeterli verinin olup olmadığını belirlemek için bytesAvailable özelliğini kullanın. Mevcut olandan daha fazla veri okumaya çalışırsanız, EOFError istisnası atılır.

Dinamik uygulamalar oluşturduğunuzda, harici dosyalardan veya sunucu tarafı komut dosyalarından veri yüklemek faydalı olabilir. Bu, uygulamanızı düzenlemeniz veya yeniden derlemeniz gerekmeden dinamik uygulamalar oluşturmanıza olanak sağlar. Örneğin, bir “günün ipucu” uygulaması oluşturuyorsanız, bir veritabanından rastgele bir ipucunu alıp her gün bir metin dosyasına kaydeden sunucu tarafı komut dosyası yazabilirsiniz. Daha sonra uygulamanız, her seferinde veritabanını sorgulamak yerine statik metin dosyasının içeriklerini yükleyebilir.

Aşağıdaki kod parçası, params.txt adında harici bir metin dosyasının içeriklerini yükleyen bir URLRequest ve URLLoader nesnesi oluşturur:

var request:URLRequest = new URLRequest("params.txt"); 
var loader:URLLoader = new URLLoader(); 
loader.load(request);

var request:URLRequest = new URLRequest("sendfeedback.cfm"); 
request.method = URLRequestMethod.POST;

Çalışma zamanında yüklenen params.txt harici belgesi aşağıdaki verileri içerir:

monthNames=January,February,March,April,May,June,July,August,September,October,November,December&dayNames=Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday

Dosya iki parametre içerir, monthNames ve dayNames . Her parametre, virgülle ayrılmış dizeler halinde ayrıştırılmış bir liste içerir. String.split() yöntemini kullanarak bu listeyi bir diziye ayrıştırabilirsiniz.

Harici veri dosyalarında değişken adı olarak ayrılmış sözcükleri veya dil yapılarını kullanmayın, aksi takdirde bu, kodunuzun okunmasını ve hatalarının ayıklanmasını daha güçleştirir.

function completeHandler(event) 
{ 
    var loader2 = event.target; 
    air.trace(loader2.data); 
}

Uzak belge ad-değer çiftleri içeriyorsa, yüklenen dosyanın içeriğini aşağıdaki gibi ileterek URLVariables sınıfı aracılığıyla verileri ayrıştırabilirsiniz:

private function completeHandler(event:Event):void 
{ 
    var loader2:URLLoader = URLLoader(event.target); 
    var variables:URLVariables = new URLVariables(loader2.data); 
    trace(variables.dayNames); 
}

Harici dosyadan her ad-değer çifti URLVariables nesnesinde bir özellik olarak oluşturulmuştur. Önceki kod örneğinde yer alan değişkenler nesnesindeki her özellik, bir dize olarak değerlendirilir. Ad-değer çiftinin değeri bir öğeler listesiyse, dizeyi aşağıdaki gibi String.split() yöntemini çağırarak bir diziye dönüştürebilirsiniz:

var dayNameArray:Array = variables.dayNames.split(",");

Harici metin dosyalarından sayısal veriler yüklüyorsanız, int() , uint() veya Number() gibi bir üst düzey işlev kullanarak değerleri sayısal değerlere dönüştürün.

Uzak dosyanın içeriklerini bir dize olarak yükleyip yeni bir URLVariables nesnesi oluşturmak yerine, URLLoader.dataFormat özelliğini URLLoaderDataFormat sınıfında bulunan statik özelliklerden birine ayarlayabilirsiniz. URLLoader.dataFormat özelliği için üç olası değer şunlardır:

• URLLoaderDataFormat.BINARY — URLLoader.data özelliği, bir ByteArray nesnesinde saklanan ikili verileri içerir.

• URLLoaderDataFormat.TEXT — URLLoader.data özelliği, bir String nesnesinde metin içerir.

• URLLoaderDataFormat.VARIABLES — URLLoader.data özelliği, bir URLVariables nesnesinde saklanan URL olarak kodlanmış değişkenleri içerir.

Aşağıdaki kod, URLLoader.dataFormat özelliğinin URLLoaderDataFormat.VARIABLES olarak ayarlanmasının, yüklenen verileri nasıl otomatik olarak bir URLVariables nesnesine ayrıştırmanıza olanak sağladığını gösterir:

package 
{ 
    import flash.display.Sprite; 
    import flash.events.*; 
    import flash.net.URLLoader; 
    import flash.net.URLLoaderDataFormat; 
    import flash.net.URLRequest; 
 
    public class URLLoaderDataFormatExample extends Sprite 
    { 
        public function URLLoaderDataFormatExample() 
        { 
            var request:URLRequest = new URLRequest("http://www.[yourdomain].com/params.txt"); 
            var variables:URLLoader = new URLLoader(); 
            variables.dataFormat = URLLoaderDataFormat.VARIABLES; 
            variables.addEventListener(Event.COMPLETE, completeHandler); 
            try 
            { 
                variables.load(request); 
            }  
            catch (error:Error) 
            { 
                trace("Unable to load URL: " + error); 
            } 
        } 
        private function completeHandler(event:Event):void 
        { 
        var loader:URLLoader = URLLoader(event.target); 
        trace(loader.data.dayNames); 
        } 
    } 
}

Aşağıdaki örneğin gösterdiği gibi, harici bir dosyadan XML yüklemek, URLVariables yüklemekle aynıdır. Bir URLRequest örneği ile bir URLLoader örneği oluşturabilir ve bunları uzak bir XML belgesini indirmek için kullanabilirsiniz. Dosya tamamen indirildiğinde, Event.COMPLETE olayı gönderilir ve harici dosyanın içerikleri, XML yöntemlerini ve özelliklerini kullanarak ayrıştırabileceğiniz bir XML örneğine dönüştürülür.

package 
{ 
    import flash.display.Sprite; 
    import flash.errors.*; 
    import flash.events.*; 
    import flash.net.URLLoader; 
    import flash.net.URLRequest; 
 
    public class ExternalDocs extends Sprite 
    { 
        public function ExternalDocs() 
        { 
            var request:URLRequest = new URLRequest("http://www.[yourdomain].com/data.xml"); 
            var loader:URLLoader = new URLLoader(); 
            loader.addEventListener(Event.COMPLETE, completeHandler); 
            try 
            { 
                loader.load(request); 
            } 
            catch (error:ArgumentError) 
            { 
                trace("An ArgumentError has occurred."); 
            } 
            catch (error:SecurityError) 
            { 
                trace("A SecurityError has occurred."); 
            } 
        } 
        private function completeHandler(event:Event):void 
        { 
            var dataXML:XML = XML(event.target.data); 
            trace(dataXML.toXMLString()); 
        } 
    } 
}

Harici veri dosyaları yüklemenin yanı sıra, sunucu tarafı komut dosyasına değişkenler gönderip sunucunun yanıtını işlemek için de URLVariables sınıfını kullanabilirsiniz. Bu örneğin, bir oyun programlıyor ve kullanıcının puanını yüksek puanlar listesine eklenip eklenmeyeceğinin hesaplanması için sunucuya göndermek ve hatta kullanıcının oturum açma bilgilerini doğrulama için sunucuya göndermek istiyorsanız, kullanışlı bir özelliktir. Sunucu tarafı komut dosyası kullanıcı adı ve parolayı işleyebilir, veritabanına karşı doğrulayabilir ve kullanıcının girdiği kimlik bilgilerinin geçerli olup olmadığına ilişkin teyit döndürebilir.

Aşağıdaki kod parçası, name adında yeni bir değişken oluşturan variables adında bir URLVariables nesnesi oluşturur. Daha sonra, değişkenlerin gönderileceği sunucu tarafı komut dosyasının URL'sini belirten bir URLRequest nesnesi oluşturulur. Daha sonra, değişkenleri bir HTTP POST isteği olarak göndermek üzere URLRequest nesnesinin method özelliğini ayarlarsınız. URLVariables nesnesini URL isteğine eklemek için, URLRequest nesnesinin data özelliğini önceden oluşturulan URLVariables nesnesine ayarlarsınız. Son olarak, URLLoader örneği oluşturulur ve isteği başlatan URLLoader.load() yöntemi çağrılır.

var variables:URLVariables = new URLVariables("name=Franklin"); 
var request:URLRequest = new URLRequest(); 
request.url = "http://www.[yourdomain].com/greeting.cfm"; 
request.method = URLRequestMethod.POST; 
request.data = variables; 
var loader:URLLoader = new URLLoader(); 
loader.dataFormat = URLLoaderDataFormat.VARIABLES; 
loader.addEventListener(Event.COMPLETE, completeHandler); 
try 
{ 
    loader.load(request); 
} 
catch (error:Error) 
{ 
    trace("Unable to load URL"); 
} 
 
function completeHandler(event:Event):void 
{ 
    trace(event.target.data.welcomeMessage); 
}

Aşağıdaki kod, önceki örnekte kullanılan Adobe ColdFusion® greeting.cfm belgesinin içeriklerini barındırır:

<cfif NOT IsDefined("Form.name") OR Len(Trim(Form.Name)) EQ 0> 
    <cfset Form.Name = "Stranger" /> 
</cfif> 
<cfoutput>welcomeMessage=#UrlEncodedFormat("Welcome, " & Form.name)# 
</cfoutput>