SQL ifadeleriyle çalışma

SQLStatement örneği oluşturur.

SQLStatement nesnesi, uygulamanızdaki SQL ifadesini temsil eder.

var selectData:SQLStatement = new SQLStatement(); 

Veritabanının hangi sorguya karşı çalıştığını belirtin.

Bunu yapmak için, SQLStatement nesnesinin sqlConnection özelliğini istenen veritabanıyla bağlantısı olan SQLConnection örneğine ayarlayın.

// A SQLConnection named "conn" has been created previously 
selectData.sqlConnection = conn;

Geçerli SQL ifadesini belirtin.

İfade metnini bir Dize olarak oluşturun ve SQLStatement örneğinin text özelliğine atayın.

selectData.text = "SELECT col1, col2 FROM my_table WHERE col1 = :param1";

Yürütme işleminin sonucunu işlemek için işlevleri tanımlayın (yalnızca senkronize olmayan yürütme modu).

İşlevleri SQLStatement örneğinin result ve error olayları olarak kaydetmek için addEventListener() yöntemini kullanın.

// using listener methods and addEventListener() 
     
selectData.addEventListener(SQLEvent.RESULT, resultHandler); 
selectData.addEventListener(SQLErrorEvent.ERROR, errorHandler); 
     
function resultHandler(event:SQLEvent):void 
{ 
    // do something after the statement execution succeeds 
} 
     
function errorHandler(event:SQLErrorEvent):void 
{ 
    // do something after the statement execution fails 
} 

Alternatif olarak, Responder nesnesi kullanarak dinleyici yöntemleri belirleyebilirsiniz. Bu durumda Responder örneğini oluşturur ve dinleyici yöntemlerini bu örneğe bağlarsınız.

// using a Responder (flash.net.Responder) 
     
var selectResponder = new Responder(onResult, onError); 
     
function onResult(result:SQLResult):void 
{ 
    // do something after the statement execution succeeds 
} 
     
function onError(error:SQLError):void 
{ 
    // do something after the statement execution fails 
} 

İfade metni parametre tanımları içeriyorsa, bu parametreler için değer atayın.

Parametre değerleri atamak için, SQLStatement örneğinin parameters ilişkilendirici dizi özelliğini kullanın.

selectData.parameters[":param1"] = 25;

SQL ifadesini yürütün.

SQLStatement örneğinin execute() yöntemini çağırın.

// using synchronous execution mode 
// or listener methods in asynchronous execution mode 
selectData.execute();

Ayrıca, senkronize olmayan yürütme modunda olay dinleyicileri yerine Responder kullanıyorsanız, Responder örneğini execute() yöntemine iletin.

// using a Responder in asynchronous execution mode 
selectData.execute(-1, selectResponder);

Bu adımları gösteren belirli örnekler için şu başlıklara bakın:

Bir veritabanından veri alma

Veri ekleme

Verileri değiştirme veya silme