Worker (işçi) öğeleri oluşturma ve yönetme

Worker (işçi) swf'sini ana swf'nin içine ByteArray olarak gömmek için [Embed] meta etiketini kullanın:

[Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")] 
private static var BgWorker_ByteClass:Class; 
private function createWorker():void 
{ 
    var workerBytes:ByteArray = new BgWorker_ByteClass(); 
    var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes); 
     
    // ... set up worker communication and start the worker 
}

Worker (işçi) swf'si ana swf'nin içine BgWorker_ByteClass adlı bir ByteArray alt sınıfı olarak derlenir. Bu sınıfın bir örneğinin oluşturulması size, worker (işçi) swf'sinin baytlarıyla önceden doldurulmuş bir ByteArray sağlar.

Harici bir swf dosyasını yüklemek için bir URLLoader nesnesi kullanın. Söz konusu swf dosyası, ana swf ile aynı internet etki alanından yüklenmiş veya bir AIR uygulama paketine dahil edilmiş bir swf dosyası gibi aynı güvenlik etki alanından gelmelidir.

var workerLoader:URLLoader = new URLLoader(); 
workerLoader.dataFormat = URLLoaderDataFormat.BINARY; 
workerLoader.addEventListener(Event.COMPLETE, loadComplete); 
workerLoader.load(new URLRequest("BgWorker.swf")); 
 
private function loadComplete(event:Event):void 
{ 
    // create the background worker 
    var workerBytes:ByteArray = event.target.data as ByteArray; 
    var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes); 
     
    // ... set up worker communication and start the worker 
}

URLLoader, swf dosyasını yüklemeyi tamamladığında, swf'nin baytları URLLoader nesnesinin data özelliğinde (örnekte event.target.data ) kullanılabilir hale gelir.

Tek bir swf'yi hem ana swf hem de worker (işçi) swf'si olarak kullanabilirsiniz. Ana görüntüleme sınıfının loaderInfo.bytes özelliğini, swf'nin baytlarına erişmek için kullanın.

// The primordial worker's main class constructor 
public function PrimordialWorkerClass() 
{ 
    init(); 
} 
 
private function init():void 
{ 
    var swfBytes:ByteArray = this.loaderInfo.bytes; 
     
    // Check to see if this is the primordial worker or the background worker 
    if (Worker.current.isPrimordial) 
    { 
        // create a background worker 
        var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes); 
         
        // ... set up worker communication and start the worker 
    } 
    else // entry point for the background worker 
    { 
        // set up communication between workers using getSharedProperty() 
        // ... (not shown) 
         
        // start the background work 
    } 
}

Bu tekniği kullanıyorsanız, ana sınıfın oluşturucusu veya çağırdığı bir yöntem içindeki swf dosya kodunu kollara ayırmak için bir if ifadesi kullanın. Kodun ana worker (işçi) öğesinde mi, yoksa arka plan worker (işçi) öğesinde mi çalıştığını belirlemek için, örnekte gösterildiği şekilde, geçerli Worker nesnesinin isPrimordial özelliğini denetleyin.