Pano veri biçimleri

Bir nesne, özel veri biçimi kullanılarak panoya yazıldığında, nesne verisi, bir başvuru olarak veya orijinal nesnenin serileştirilmiş bir kopyası olarak okunabilir. Nesnelerin başvuru olarak mı serileştirilmiş kopyalar olarak mı aktarılacağını belirleyen dört aktarım modu vardır.

Bir nesneyi panoya yazarken, format parametresi için air: veya flash:ayrılmış önekleriyle başlamayan herhangi bir dize kullanabilirsiniz. Nesneyi okumak için biçim olarak aynı dizeyi kullanın. Aşağıdaki örnek nesnelerin panoya nasıl okunacağını ve yazılacağını gösterir:

public function createClipboardObject(object:Object):Clipboard{ 
    var transfer:Clipboard = Clipboard.generalClipboard; 
    transfer.setData("object", object, true); 
} 

Pano nesnesinden serileştirilmiş bir nesneyi ayıklamak için (bırakma veya yapıştırma işleminden sonra), aynı biçim adını ve CLONE_ONLY veya CLONE_PREFFERED aktarım modlarını kullanın.

var transfer:Object = clipboard.getData("object", ClipboardTransferMode.CLONE_ONLY); 

Başvuru her zaman Clipboard nesnesine eklenir. Pano nesnesinden başvuruyu ayıklamak için (bırakma veya yapıştırma işleminden sonra), serileştirilmiş kopya yerine ORIGINAL_ONLY veya ORIGINAL_PREFFERED aktarım modlarını kullanın:

var transferredObject:Object =  
    clipboard.getData("object", ClipboardTransferMode.ORIGINAL_ONLY); 

Başvurular yalnızca Clipboard nesnesi geçerli uygulaması kaynaklıysa geçerlidir. Başvuru varsa başvuruya erişmek için ORIGINAL_PREFFERED aktarım modunu, başvuru yoksa serileştirilmiş klonu kullanın.

Aşağıdaki örnek gecikmeli oluşturma işlevinin nasıl uygulanacağını gösterir.

Kullanıcı Kopyala düğmesine bastığında, uygulama önceki pano işlemlerinden veri kalmamasını sağlamak için sistem panosunu temizler. Daha sonra setDataHandler() yöntemi, pano oluşturucusu olarak renderData() işlevini ayarlar.

Kullanıcı, hedef metin alanının bağlam menüsünden Yapıştır komutunu seçtiğinde, uygulama panoya erişir ve hedef metni ayarlar. Panodaki metin verisi biçimi, dize yerine bir işlevle ayarlanmış olduğundan, pano renderData() işlevini çağırır. renderData() işlevi metni kaynak metinde döndürür, ardından bu metin hedef metne atanır.

Kaynak metni Yapıştır düğmesine basmadan önce düzenlerseniz, düzenleme kopyala düğmesine basıldıktan sonra gerçekleşmiş bile olsa, düzenlemenin yapıştırılan metne yansıtılacağını göz önünde bulundurun. Bunun nedeni, yapıştır düğmesine basılana kadar oluşturma işlevinin kaynak metni kopyalamamasıdır. (Gecikmeli oluşturmayı gerçek bir uygulamada kullanırken, bu sorunun önüne geçmek için kaynak verileri bir şekilde saklamak veya korumak isteyebilirsiniz.)

 package {  
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
    import flash.desktop.ClipboardTransferMode; 
    import flash.display.Sprite; 
    import flash.text.TextField; 
    import flash.text.TextFormat; 
    import flash.text.TextFieldType; 
    import flash.events.MouseEvent; 
    import flash.events.Event; 
    public class DeferredRenderingExample extends Sprite  
    {  
         private var sourceTextField:TextField; 
        private var destination:TextField; 
        private var copyText:TextField; 
        public function DeferredRenderingExample():void 
        { 
            sourceTextField = createTextField(10, 10, 380, 90); 
            sourceTextField.text = "Neque porro quisquam est qui dolorem " 
                + "ipsum quia dolor sit amet, consectetur, adipisci velit."; 
                 
            copyText = createTextField(10, 110, 35, 20); 
            copyText.htmlText = "<a href='#'>Copy</a>"; 
            copyText.addEventListener(MouseEvent.CLICK, onCopy); 
 
            destination = createTextField(10, 145, 380, 90); 
            destination.addEventListener(Event.PASTE, onPaste); 
        } 
        private function createTextField(x:Number, y:Number, width:Number, 
                        height:Number):TextField 
        { 
            var newTxt:TextField = new TextField(); 
            newTxt.x = x; 
            newTxt.y = y; 
            newTxt.height = height; 
            newTxt.width = width; 
            newTxt.border = true; 
            newTxt.multiline = true; 
            newTxt.wordWrap = true; 
            newTxt.type = TextFieldType.INPUT; 
            addChild(newTxt); 
            return newTxt; 
        } 
        public function onCopy(event:MouseEvent):void 
        { 
            Clipboard.generalClipboard.clear(); 
            Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, 
                            renderData); 
        } 
        public function onPaste(event:Event):void 
        { 
            sourceTextField.text = 
            Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
        } 
        public function renderData():String 
        { 
            trace("Rendering data"); 
            var sourceStr:String = sourceTextField.text; 
            if (sourceTextField.selectionEndIndex > 
                     sourceTextField.selectionBeginIndex) 
            { 
                return sourceStr.substring(sourceTextField.selectionBeginIndex, 
                                    sourceTextField.selectionEndIndex); 
            } 
            else 
            { 
                return sourceStr; 
            } 
        } 
    } 
}

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="326" height="330" applicationComplete="init()"> 
    <mx:Script> 
    <![CDATA[ 
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
     
    public function init():void 
    { 
        destination.addEventListener("paste", doPaste); 
    } 
 
    public function doCopy():void 
    { 
        Clipboard.generalClipboard.clear(); 
        Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, renderData); 
    } 
    public function doPaste(event:Event):void 
    { 
        destination.text = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
    } 
     
    public function renderData():String{ 
        trace("Rendering data"); 
        return source.text; 
    } 
    ]]> 
    </mx:Script> 
    <mx:Label x="10" y="10" text="Source"/> 
    <mx:TextArea id="source" x="10" y="36" width="300" height="100"> 
        <mx:text>Neque porro quisquam est qui dolorem ipsum quia dolor sit amet, consectetur, adipisci velit.</mx:text> 
    </mx:TextArea> 
    <mx:Label x="10" y="181" text="Destination"/> 
    <mx:TextArea id="destination"  x="12" y="207" width="300" height="100"/> 
    <mx:Button click="doCopy();" x="91" y="156" label="Copy"/> 
</mx:Application>