Button bileşenini kullanma

Button bileşeni, kullanıcının uygulamada bir eylem başlatmak için fare veya boşluk çubuğu ile basabileceği yeniden boyutlandırılabilir, dikdörtgen bir düğmedir. Button öğesine özel bir simge ekleyebilirsiniz. Button öğesinin davranışını basma yerine aç/kapa olarak değiştirebilirsiniz. Aç/kapa Button öğesi, tıklatıldığında basılı kalır ve tekrar tıklatıldığında basılmamış durumuna geri döner.

Button, birçok form ve web uygulamasının temel parçasını oluşturur. Kullanıcının bir olay başlatmasını istediğiniz her yerde düğmeleri kullanabilirsiniz. Örneğin, çoğu formda bir Gönder düğmesi bulunur. Ayrıca bir sunuma Geri ve İleri düğmeleri de ekleyebilirsiniz.

Button bileşeniyle kullanıcı etkileşimi

Bir uygulamada herhangi bir düğmeyi etkinleştirebilir veya devre dışı bırakabilirsiniz. Bir düğme devre dışı durumunda fare veya klavye girdisi almaz. Etkinleştirilmiş bir düğme üzerini tıklattığınızda veya bastığınızda odağı alır. Bir Button örneği odağa sahip olduğunda, odağı denetlemek için şu tuşları kullanabilirsiniz:

Anahtar

Açıklama

Üst Karakter+Sekme

Odağı bir önceki nesneye taşır.

Boşluk çubuğu

Düğmeye basar veya düğmeyi serbest bırakır ve click olayını tetikler.

Sekme

Odağı bir sonraki nesneye taşır.

Enter/Return

Bir düğme FocusManager’ın varsayılan Button öğesi olarak ayarlanmışsa odağı bir sonraki nesneye taşır.

Odağı kontrol etmeyle ilgili daha fazla bilgi için, Adobe® Flash® Professional CS5 için ActionScript® 3.0 Başvurusu ve FocusManager ile çalışma bölümündeki IFocusManager arabirimine ve FocusManager sınıfına bakın.

Her bir Button örneğinin canlı önizlemesi, geliştirme sırasında Özellik denetçisinde veya Bileşen denetçisinde parametrelere yapılan değişiklikleri yansıtır.

Not: Bir simge düğmeden büyükse, düğmenin kenarlıklarını aşar.

Bir düğmeyi bir uygulamada varsayılan basma düğmesi olarak atamak için (kullanıcı Enter düğmesine bastığında click olayını alan düğme), FocusManager.defaultButton öğesini ayarlayın. Örneğin, aşağıdaki kod varsayılan düğmeyi submitButton adında bir Button örneği olacak şekilde ayarlar. 

FocusManager.defaultButton = submitButton;

Bir uygulamaya Button bileşenini eklediğinizde, aşağıdaki ActionScript kodu satırlarını ekleyerek bu bileşeni bir ekran okuyucusu için erişilebilir duruma getirebilirsiniz: 

import fl.accessibility.ButtonAccImpl; 
 
ButtonAccImpl.enableAccessibility();

Kaç tane örnek oluşturduğunuza bakılmaksızın, bir bileşenin erişilebilirliğini yalnızca bir defa etkinleştirebilirsiniz.

Button bileşeni parametreleri

Her Button örneği için Özellik denetçisinde (Pencere > Özellikler > Özellikler) ya da Bileşen denetçisinde (Pencere > Bileşen Denetçisi) şu geliştirme parametrelerini ayarlayabilirsiniz: emphasized , label , labelPlacement , selected ve toggle . Bu parametrelerin her biri, aynı adda, karşılık gelen ActionScript özelliğine sahiptir. Bu parametrelere bir değer atadığınızda, uygulamada özelliğin başlangıç durumunu ayarlarsınız. Özellik ActionScript'te ayarlandığında, parametrede ayarladığınız değer geçersiz kalır. Bu parametrelerin olası değerleriyle ilgili bilgi için Adobe® Flash® Professional CS5 için ActionScript® 3.0 Başvurusu bölümündeki Button sınıfına bakın.

Button bileşeniyle uygulama oluşturma

Aşağıdaki prosedür, geliştirme sırasında bir uygulamaya nasıl Button bileşeni ekleneceğini açıklamaktadır. Bu örnekte, Button öğesi tıklatıldığında, ColorPicker bileşeninin durumunu değiştirir.

  1. Yeni bir Flash (ActionScript 3.0) belgesi oluşturun.

  2. Bir Button bileşenini Bileşenler panelinden Sahne Alanı'na sürükleyin ve Button bileşeni için Özellik denetçisinde şu değerleri girin:

    • aButton örnek adını girin.

    • label parametresi için Show girin.

  3. ColorPicker bileşenini Sahne Alanı'na ekleyin ve bu bileşene aCp örnek adını verin.

  4. Eylemler panelini açın, ana Zaman Çizelgesi'nde Kare 1'i seçin ve şu ActionScript kodunu girin: 

    aCp.visible = false; 
 
aButton.addEventListener(MouseEvent.CLICK, clickHandler); 
 
function clickHandler(event:MouseEvent):void { 
     
    switch(event.currentTarget.label) { 
        case "Show": 
            aCp.visible = true; 
            aButton.label = "Disable"; 
            break; 
        case "Disable": 
            aCp.enabled = false; 
            aButton.label = "Enable"; 
            break; 
        case "Enable": 
            aCp.enabled = true; 
            aButton.label = "Hide"; 
            break; 
        case "Hide": 
            aCp.visible = false; 
            aButton.label = "Show"; 
            break; 
    } 
}

    Kodun ikinci satırı clickHandler() işlevini MouseEvent.CLICK olayı için olay işleme işlevi olarak kaydeder. Kullanıcı Button öğesini tıklattığında olay gerçekleşir ve Button öğesinin değerine bağlı olarak clickHandler() işlevinin şu eylemlerden birini gerçekleştirmesine neden olur:

    • Göster seçeneği, ColorPicker öğesini görünür hale getirir ve Button öğesinin etiketini Devre Dışı Bırak olarak değiştirir.

    • Devre Dışı Bırak seçeneği, ColorPicker öğesini devre dışı bırakır ve Button öğesinin etiketini Etkinleştir olarak değiştirir.

    • Etkinleştir seçeneği, ColorPicker öğesini etkinleştirir ve Button öğesinin etiketini Gizle olarak değiştirir.

    • Gizle seçeneği, ColorPicker öğesini görünmez hale getirir ve Button öğesinin etiketini Göster olarak değiştirir.

  5. Uygulamayı çalıştırmak için Kontrol Et > Filmi Test Et'i seçin.

Button bileşeniyle uygulama oluşturma

Aşağıdaki yordam, ActionScript kullanarak bir aç/kapa Button öğesi oluşturur ve Button öğesini tıklattığınızda Çıktı panelinde olay türünü görüntüler. Örnek, sınıfın yapıcısına başvurarak Button örneğini oluşturur ve onu addChild() yöntemini çağırarak Sahne Alanı'na ekler.

  1. Yeni bir Flash (ActionScript 3.0) belgesi oluşturun.

  2. Button bileşenini Bileşenler panelinden geçerli belgenin Kütüphane paneline sürükleyin.

    Bu işlem sonucunda bileşen kütüphaneye eklenir ancak uygulamada görünür duruma getirilmez.

  3. Eylemler panelini açın, ana Zaman Çizelgesi'nde Kare 1'i seçin ve bir Button örneği oluşturmak için şu kodu girin: 

    import fl.controls.Button; 
 
var aButton:Button = new Button(); 
addChild(aButton); 
aButton.label = "Click me"; 
aButton.toggle =true;  
aButton.move(50, 50);

    move() yöntemi, düğmeyi Sahne Alanı'nda 50 (x koordinatı), 50 (y koordinatı) konumuna yerleştirir.

  4. Şimdi bir olay dinleyicisi ve olay işleyici işlevi oluşturmak için şu ActionScript'i ekleyin: 

    aButton.addEventListener(MouseEvent.CLICK, clickHandler); 
 
function clickHandler(event:MouseEvent):void { 
    trace("Event type: " + event.type); 
}

  5. Kontrol Et > Filmi Test Et'i seçin.

    Düğmeyi tıklattığınızda, Flash uygulaması Çıktı panelinde “Olay türü: click” mesajını görüntüler.