RadioButton bileşenini kullanma

RadioButton bileşeni kullanıcıyı seçenekler kümesinde tek bir tercih yapmaya zorlamanıza imkan tanır. Bu bileşen, en az iki RadioButton örneğinin bulunduğu bir grupta kullanılmalıdır. Herhangi bir belirli zamanda yalnızca bir grup üyesi seçilebilir. Grupta bir radyo düğmesi seçildiğinde, grupta geçerli olarak seçilen radyo düğmesinin seçimini kaldırılır. groupName parametresini, bir radyo düğmesinin ait olduğu grubu belirtecek şekilde ayarlarsınız.

Radyo düğmesi, web'deki çoğu form uygulamasının temel bölümünü oluşturur. Kullanıcının seçenekler grubunda tek bir tercih yapmasını istediğiniz her yerde radyo düğmelerini kullanabilirsiniz. Örneğin, müşterinin hangi kredi kartını kullanmak istediğini sormak için formda radyo düğmelerini kullanabilirsiniz.

RadioButton bileşeniyle kullanıcı etkileşimi

Radyo düğmesi etkinleştirilebilir veya devre dışı bırakılabilir. Devre dışı bırakılmış bir radyo düğmesi, fare veya klavye girdisini kabul etmez. Kullanıcı, bir RadioButton bileşen grubunu tıklattığında veya sekme ile geçtiğinde, yalnızca seçili radyo düğmesi odağı alır. Daha sonra kullanıcı odağı denetlemek için şu tuşları kullanabilir:

Anahtar

Açıklama

Yukarı Ok/Sol Ok

Seçim radyo düğmesi grubu içinde önceki radyo düğmesine taşınır.

Aşağı Ok/Sağ Ok

Seçim radyo düğmesi grubu içinde sonraki radyo düğmesine taşınır.

Sekme

Odağı radyo düğmesi grubundan sonraki bileşene taşır.

Odağı kontrol etmeyle ilgili daha fazla bilgi için, Adobe® Flash® Professional CS5 için ActionScript® 3.0 Başvurusu ve FocusManager ile çalışma bölümündeki IFocusManager arabirimine ve FocusManager sınıfına bakın.

Sahne Alanı'nda her bir RadioButton örneğinin canlı önizlemesi, geliştirme sırasında Özellik denetçisinde veya Bileşen denetçisinde parametrelere yapılan değişiklikleri yansıtır. Ancak seçimin birbirini dışlaması canlı önizlemede görüntülenmez. Aynı gruptaki iki radyo düğmesi için seçili parametreyi true değerine ayarlarsanız, çalışma zamanında yalnızca oluşturulan son örnek seçilmiş olarak görüntülense de, her iki örnek birden seçilmiş olarak görüntülenir. Daha fazla bilgi için bkz. RadioButton bileşeni parametreleri .

Bir uygulamaya RadioButton bileşenini eklediğinizde, aşağıdaki kod satırlarını ekleyerek bu bileşeni bir ekran okuyucusu için erişilebilir duruma getirebilirsiniz: 

import fl.accessibility.RadioButtonAccImpl; 
RadioButtonAccImpl.enableAccessibility();

Bileşenin kaç tane örneğine sahip olduğunuza bakılmaksızın, bir bileşenin erişilebilirliğini yalnızca bir defa etkinleştirirsiniz. Daha fazla bilgi için bkz. Bölüm 18, “Erişilebilir İçerik Oluşturma,” Flash Uygulamasını Kullanma .

RadioButton bileşeni parametreleri

Her RadioButton bileşeni örneği için Özellik denetçisinde veya Bileşen denetçisinde şu geliştirme parametrelerini ayarlayabilirsiniz: groupName, label,LabelPlacement, selected ve value . Bu parametrelerin her biri, aynı adda, karşılık gelen ActionScript özelliğine sahiptir. Bu parametrelerin olası değerleriyle ilgili bilgi için, Adobe® Flash® Professional CS5 için ActionScript® 3.0 Başvurusu bölümündeki RadioButton sınıfına bakın.

RadioButton sınıfının yöntemlerini, özelliklerini ve olaylarını kullanarak RadioButton öğesi için ek seçenekler ayarlamak üzere ActionScript yazabilirsiniz.

RadioButton bileşeniyle uygulama oluşturma

Aşağıdaki prosedür, geliştirme sırasında bir uygulamaya nasıl RadioButton bileşenleri ekleneceğini açıklamaktadır. Bu örnekte, evet veya hayır yanıtı vermek için RadioButton öğeleri kullanılır. RadioButton öğesindeki veriler TextArea üzerinde görüntülenir.

  1. Yeni bir Flash (ActionScript 3.0) belgesi oluşturun.

  2. İki RadioButton bileşenini Bileşenler panelinden Sahne Alanı'na sürükleyin.

  3. Birinci radyo düğmesini seçin. Özellik denetçisinde, bu radyo düğmesine yesRb örnek adını ve rbGroup grup adını verin.

  4. İkinci radyo düğmesini seçin. Özellik denetçisinde, bu radyo düğmesine noRb örnek adını ve rbGroup grup adını verin.

  5. TextArea bileşenini Bileşenler panelinden Sahne Alanı'na sürükleyin ve bu bileşene aTa örnek adını verin.

  6. Eylemler panelini açın, ana Zaman Çizelgesi'nde Kare 1'i seçin ve şu ActionScript kodunu girin: 

    yesRb.label = "Yes"; 
yesRb.value = "For"; 
noRb.label = "No"; 
noRb.value = "Against"; 
 
yesRb.move(50, 100); 
noRb.move(100, 100); 
aTa.move(50, 30); 
noRb.addEventListener(MouseEvent.CLICK, clickHandler); 
yesRb.addEventListener(MouseEvent.CLICK, clickHandler); 
 
function clickHandler(event:MouseEvent):void { 
    aTa.text = event.target.value; 
}

  7. Uygulamayı çalıştırmak için Kontrol Et > Filmi Test Et'i seçin.

ActionScript kullanarak RadioButton oluşturma

Bu örnek, kırmızı, mavi ve yeşil renkleri için üç RadioButtons öğesi oluşturmak üzere ActionScript kullanır ve gri bir kutu çizer. Her RadioButton öğesinin value özelliği, o düğmeyle ilişkilendirilmiş rengin onaltılık değerini belirtir. Kullanıcı RadioButton öğelerinden birini tıklattığında, clickHandler() işlevi drawBox() öğesini çağırarak kutuyu renklendirmek için RadioButton öğesinin value özelliğindeki rengi iletir.

  1. Yeni bir Flash (ActionScript 3.0) belgesi oluşturun.

  2. RadioButton bileşenini Kütüphane paneline sürükleyin.

  3. Eylemler panelini açın, ana Zaman Çizelgesi'nde Kare 1'i seçin ve şu ActionScript kodunu girin: 

    import fl.controls.RadioButton; 
import fl.controls.RadioButtonGroup; 
 
var redRb:RadioButton = new RadioButton(); 
var blueRb:RadioButton = new RadioButton(); 
var greenRb:RadioButton = new RadioButton(); 
var rbGrp:RadioButtonGroup = new RadioButtonGroup("colorGrp"); 
 
var aBox:MovieClip = new MovieClip(); 
drawBox(aBox, 0xCCCCCC); 
 
addChild(redRb); 
addChild(blueRb); 
addChild(greenRb); 
addChild(aBox); 
 
redRb.label = "Red"; 
redRb.value = 0xFF0000; 
blueRb.label = "Blue"; 
blueRb.value = 0x0000FF; 
greenRb.label = "Green"; 
greenRb.value = 0x00FF00; 
redRb.group = blueRb.group = greenRb.group = rbGrp; 
redRb.move(100, 260); 
blueRb.move(150, 260); 
greenRb.move(200, 260); 
 
rbGrp.addEventListener(MouseEvent.CLICK, clickHandler); 
 
function clickHandler(event:MouseEvent):void { 
    drawBox(aBox, event.target.selection.value); 
} 
 
function drawBox(box:MovieClip,color:uint):void { 
            box.graphics.beginFill(color, 1.0); 
            box.graphics.drawRect(125, 150, 100, 100); 
            box.graphics.endFill();         
}

  4. Uygulamayı çalıştırmak için Kontrol Et > Filmi Test Et'i seçin.

    Daha fazla bilgi için, Adobe® Flash® Professional CS5 için ActionScript® 3.0 Başvurusu bölümündeki RadioButton sınıfına bakın.