Çoklu video dosyalarını oynatma

Çoklu videolar oynatmak ve oynatılırken videolar arasında geçiş yapmak için FLVPlayback bileşeninin tek bir örneğinde birden çok video oynatıcı açabilirsiniz.

FLVPlayback bileşenini Sahne Alanı'na sürüklediğinizde başlangıç video oynatıcısını oluşturursunuz. Bileşen otomatik olarak başlangıç video oynatıcısına 0 numarasını atar ve bunu varsayılan oynatıcı yapar. Ek bir video oynatıcı oluşturmak için activeVideoPlayerIndex özelliğini yeni bir numaraya ayarlayın. activeVideoPlayerIndex özelliği ayarlandığında belirtilen video oynatıcı etkin video oynatıcı olur ve FLVPlayback sınıfının özellikleri ve yöntemleri tarafından etkilenir. Ancak activeVideoPlayerIndex özelliği ayarlandığında video oynatıcı görünür olmaz. Video oynatıcıyı görünür hale getirmek için visibleVideoPlayerIndex özelliğini video oynatıcısının numarasına ayarlayın. Bu özelliklerin FLVPlayback sınıfının yöntemleri ve özellikleri ile nasıl etkileşimde oldukları hakkında daha fazla bilgi için, Adobe® Flash® Professional CS5 için ActionScript® 3.0 Başvurusu bölümündeki FLVPlayback.activeVideoPlayerIndex ve FLVPlayback.visibleVideoPlayerIndex özelliklerine bakın .

Şu ActionScript kodu, varsayılan video oynatıcıda video dosyasını oynatmak ve bu video dosyasına bir işaret noktası eklemek için source özelliğini yükler. ready olayı gerçekleştiğinde, olay işleyici activeVideoPlayerIndex özelliğini 1 numarasına ayarlayarak ikinci bir video oynatıcı açar. İkinci video oynatıcı için bir FLV dosyası ve işaret noktası belirtir ve sonra varsayılan oynatıcıyı (0) tekrar etkin video oynatıcı haline getirir.

/** 
    Requires: 
- FLVPlayback component on the Stage with an instance name of my_FLVPlybk 
*/ 
// add a cue point to the default player 
import fl.video.*; 
my_FLVPlybk.source = "http://www.helpexamples.com/flash/video/clouds.flv"; 
my_FLVPlybk.addASCuePoint(3, "1st_switch"); 
my_FLVPlybk.addEventListener(VideoEvent.READY, ready_listener); 
function ready_listener(eventObject:VideoEvent):void { 
    // add a second video player and create a cue point for it 
    my_FLVPlybk.activeVideoPlayerIndex = 1; 
    my_FLVPlybk.source = "http://www.helpexamples.com/flash/video/water.flv"; 
    my_FLVPlybk.addASCuePoint(3, "2nd_switch"); 
    my_FLVPlybk.activeVideoPlayerIndex = 0; 
};

Bir FLV dosyası oynatılırken başka bir FLV dosyasına geçiş yapmak için ActionScript kodunuzda geçiş yapmanız gerekir. İşaret noktaları, bir cuePoint olayı kullanarak FLV dosyasında belirli noktalarda müdahale etmenize olanak sağlar. Şu kod, cuePoint olayı için bir dinleyici oluşturur ve etkin video oynatıcısını (0) duraklatan bir işleyici işlevi çağırır, ikinci oynatıcıya (1) geçiş yapar ve ikinci oynatıcının FLV dosyasını oynatır:

import fl.video.*; 
// add listener for a cuePoint event 
my_FLVPlybk.addEventListener(MetadataEvent.CUE_POINT, cp_listener); 
// add the handler function for the cuePoint event 
function cp_listener(eventObject:MetadataEvent):void { 
        // display the no. of the video player causing the event 
        trace("Hit cuePoint event for player: " + eventObject.vp); 
        // test for the video player and switch FLV files accordingly 
        if (eventObject.vp == 0) { 
            my_FLVPlybk.pause();     //pause the first FLV file 
            my_FLVPlybk.activeVideoPlayerIndex = 1; // make the 2nd player active 
            my_FLVPlybk.visibleVideoPlayerIndex = 1; // make the 2nd player visible 
            my_FLVPlybk.play(); // begin playing the new player/FLV 
        } else if (eventObject.vp == 1) { 
            my_FLVPlybk.pause(); // pause the 2nd FLV 
            my_FLVPlybk.activeVideoPlayerIndex = 0; // make the 1st player active 
            my_FLVPlybk.visibleVideoPlayerIndex = 0; // make the 1st player visible 
            my_FLVPlybk.play(); // begin playing the 1st player 
        } 
} 
my_FLVPlybk.addEventListener(VideoEvent.COMPLETE, complete_listener); 
function complete_listener(eventObject:VideoEvent):void { 
        trace("Hit complete event for player: " + eventObject.vp); 
        if (eventObject.vp == 0) { 
            my_FLVPlybk.activeVideoPlayerIndex = 1; 
            my_FLVPlybk.visibleVideoPlayerIndex = 1; 
            my_FLVPlybk.play(); 
        } else { 
            my_FLVPlybk.closeVideoPlayer(1); 
        } 
};

Yeni bir video oynatıcı oluşturduğunuzda, FLVPlayback örneği, özelliklerini varsayılan video oynatıcının source , totalTime, ve isLive özellikleri dışındaki değerine ayarlar, FLVPlayback örneği bu istisna özellikleri her zaman şu varsayılan değerlere ayarlar: sırayla boş dize, 0 ve false . Varsayılan video oynatıcı için true olan autoPlay özelliğini false değerine ayarlar. cuePoints özelliğinin, varsayılan video oynatıcısına yapılan sonraki yüklemeler de dahil herhangi bir etkisi yoktur.

Ses düzeyini, konumlandırmayı, boyutları, görünürlüğü ve kullanıcı arabirimi denetimlerini denetleyen yöntemler ve özellikler her zaman geneldir ve bunların davranışı activeVideoPlayerIndex özelliğinin ayarlanmasıyla etkilenmez. Bu yöntemler ve özellikler ve activeVideoPlayerIndex özelliğini ayarlamanın etkisi hakkında daha fazla bilgi için, Adobe® Flash® Professional CS5 için ActionScript® 3.0 Başvurusu bölümündeki FLVPlayback.activeVideoPlayerIndex özelliğine bakın. Kalan özellikler ve yöntemler, activeVideoPlayerIndex özelliğinin değeriyle tanımlanan video oynatıcısını hedefler.

Ancak boyutları denetleyen özellikler ve yöntemler visibleVideoPlayerIndex özelliğiyle etkileşim kurar . Daha fazla bilgi için, Adobe® Flash® Professional CS5 için ActionScript® 3.0 Başvurusu bölümündeki FLVPlayback.addASCuePoint() yöntemine bakın.