Initiera XML-variabler

Du kan tilldela en XML-litteral till ett XML-objekt enligt följande:

var myXML:XML =  
    <order> 
        <item id='1'> 
            <menuName>burger</menuName> 
            <price>3.95</price> 
        </item> 
        <item id='2'> 
            <menuName>fries</menuName> 
            <price>1.45</price> 
        </item> 
    </order>

Som framgår av nästa kodutdrag kan du använda konstruktorn new för att skapa en instans av ett XML-objekt från en sträng som innehåller XML-data:

var str:String = "<order><item id='1'><menuName>burger</menuName>" 
                            + "<price>3.95</price></item></order>"; 
var myXML:XML = new XML(str);

Du kommer att få ett körningsfel om de XML-data som finns i strängen inte är väl utformade (t.ex. om en sluttagg saknas).

Du kan också skicka data som referens (från andra variabler) till ett XML-objekt. Detta visas i följande exempel:

var tagname:String = "item";  
var attributename:String = "id";  
var attributevalue:String = "5";  
var content:String = "Chicken";  
var x:XML = <{tagname} {attributename}={attributevalue}>{content}</{tagname}>;  
trace(x.toXMLString()) 
    // Output: <item id="5">Chicken</item>

Om du vill läsa in XML-data från en webbadress använder du klassen URLLoader som i följande exempel:

import flash.events.Event; 
import flash.net.URLLoader; 
import flash.net.URLRequest; 
 
var externalXML:XML; 
var loader:URLLoader = new URLLoader(); 
var request:URLRequest = new URLRequest("xmlFile.xml"); 
loader.load(request); 
loader.addEventListener(Event.COMPLETE, onComplete); 
 
function onComplete(event:Event):void 
{ 
    var loader:URLLoader = event.target as URLLoader; 
    if (loader != null) 
    { 
        externalXML = new XML(loader.data); 
        trace(externalXML.toXMLString()); 
    } 
    else 
    { 
        trace("loader is not a URLLoader!"); 
    } 
}

Du använder klassen XMLSocket när du vill läsa in XML-data från en socketanslutning. Mer information finns i XMLSocket class i Referenshandbok för ActionScript 3.0 i Adobe Flash-plattformen.