Exempel på filmklipp: RuntimeAssetsExplorer

För att utforskaren ska kunna samverka på rätt sätt med ett SWF-bibliotek, måste resursbiblioteken för körning struktureras. Vi gör det genom att skapa ett gränssnitt som liknar en klass så till vida att det är en kopia av metoder som avgränsar en förväntad struktur, men till skillnad från en klass så inkluderar den inget metodinnehåll. Med gränssnittet kan både körningsbiblioteket och utforskaren kommunicera med varandra. Varje SWF med körningsresurser som läses in i webbläsaren implementerar det här gränssnittet. Mer information om gränssnitt och hur de kan användas finns i avsnittet om gränssnitt i Learning ActionScript 3.0.

Gränssnittet RuntimeLibrary är enkelt; vi begär helt enkelt en funktion som kan förse utforskaren med en array av klassökvägar för symbolerna som ska exporteras och vara tillgängliga i körningsbiblioteket. Hittills har gränssnittet endast en metod: getAssets().

package com.example.programmingas3.runtimeassetexplorer 
{ 
    public interface RuntimeLibrary 
    { 
        function getAssets():Array; 
    } 
}

Genom att definiera gränssnittet RuntimeLibrary är det möjligt att skapa flera resursbiblioteks-SWF-filer som kan läsas in till en annan SWF-fil. Fyra uppgifter ingår när du skapar ett individuellt SWF-bibliotek med resurser:

• Skapa en klass för resursbiblioteks-SWF-fil

• Skapa klasser för individuella resurser i biblioteket

• Skapa de faktiska grafikresurserna

• Associera de grafiska elementen med klasser och publicera biblioteks-SWF-filen

package 
{ 
    import flash.display.Sprite; 
    import com.example.programmingas3.runtimeassetexplorer.RuntimeLibrary; 
     
    public class GeometricAssets extends Sprite implements RuntimeLibrary  
    { 
        public function GeometricAssets() { 
             
        } 
        public function getAssets():Array { 
            return [ "com.example.programmingas3.runtimeassetexplorer.AnimatingBox", 
                     "com.example.programmingas3.runtimeassetexplorer.AnimatingStar" ];     
        } 
    } 
}

package com.example.programmingas3.runtimeassetexplorer 
{ 
    import flash.display.MovieClip; 
     
    public class AnimatingStar extends MovieClip 
    { 
        public function AnimatingStar() { 
        } 
    } 
}

Den sista funktionsdelen utgörs av användargränssnittet för resursutforskaren. I det här exemplet är sökvägen till körningsbiblioteket hårdkodad som en variabel med namnet ASSETS_PATH. Alternativt kan du använda klassen FileReference t.ex. för att skapa ett gränssnitt som söker efter en särskild SWF-fil på hårddisken.

När körningsbiblioteket har lästs in, anropar Flash Player metoden runtimeAssetsLoadComplete():

private function runtimeAssetsLoadComplete(event:Event):void 
{ 
    var rl:* = event.target.content; 
    var assetList:Array = rl.getAssets(); 
    populateDropdown(assetList); 
    stage.frameRate = 60; 
}

I den här metoden representerar variabeln rl den inlästa SWF-filen. Koden anropar getAssets()-metoden för den inlästa SWF-filen, hämtar listan över resurser som är tillgängliga och använder dem för att fylla i en ComboBox-komponent med en lista över tillgängliga resurser genom att anropa populateDropDown()-metoden. Den metoden i sin tur lagrar den fullständiga klassökvägen för varje resurs. När du klickar på Lägg till i användargränssnittet aktiveras addAsset()-metoden:

private function addAsset():void 
{ 
    var className:String = assetNameCbo.selectedItem.data; 
    var AssetClass:Class = getDefinitionByName(className) as Class; 
    var mc:MovieClip = new AssetClass(); 
    ... 
}

Nu hämtas klassökvägen för den resurs som för närvarande har valts i ComboBox (assetNameCbo.selectedItem.data) och funktionen getDefinitionByName() (från flash.utils-paketet) används för att hämta en faktisk referens till resursens klass för att skapa en ny instans av resursen.