Grundläggande om nätverk och kommunikation

Du kan använda NetworkInfo-objektet för att identifiera de nätverksgränssnitt för hårdvara och mjukvara som finns tillgängliga för programmet. NetworkInfo-objektet är ett singleton -objekt, du behöver inte skapa något. Använd i stället den statiska klassegenskapen networkInfo om du vill komma åt det enskilda NetworkInfo-objektet. NetworkInfo-objektet skickar också en networkChange -händelse när något av de tillgängliga gränssnitten ändras.

Anropa metoden findInterfaces() för att hämta en lista med NetworkInterface-objekt. Varje NetworkInterface-objekt i listan beskriver ett av de tillgängliga gränssnitten. NetworkInterface-objektet tillhandahåller sådan information som IP-adress, maskinvaruadress, största överföringsenhet och om gränssnittet är aktivt eller inte.

I följande kodexempel spåras NetworkInterface-egenskaper för alla gränssnitt på klientdatorn:

package { 
import flash.display.Sprite; 
import flash.net.InterfaceAddress; 
import flash.net.NetworkInfo; 
import flash.net.NetworkInterface; 
 
public class NetworkInformationExample extends Sprite 
{ 
    public function NetworkInformationExample() 
    { 
        var networkInfo:NetworkInfo = NetworkInfo.networkInfo; 
        var interfaces:Vector.<NetworkInterface> = networkInfo.findInterfaces(); 
         
        if( interfaces != null ) 
        { 
            trace( "Interface count: " + interfaces.length ); 
            for each ( var interfaceObj:NetworkInterface in interfaces ) 
            { 
                trace( "\nname: "             + interfaceObj.name ); 
                trace( "display name: "     + interfaceObj.displayName ); 
                trace( "mtu: "                 + interfaceObj.mtu ); 
                trace( "active?: "             + interfaceObj.active ); 
                trace( "parent interface: " + interfaceObj.parent ); 
                trace( "hardware address: " + interfaceObj.hardwareAddress ); 
                if( interfaceObj.subInterfaces != null ) 
                { 
                    trace( "# subinterfaces: " + interfaceObj.subInterfaces.length ); 
                } 
                trace("# addresses: "     + interfaceObj.addresses.length ); 
                for each ( var address:InterfaceAddress in interfaceObj.addresses ) 
                { 
                    trace( "  type: "           + address.ipVersion ); 
                    trace( "  address: "         + address.address ); 
                    trace( "  broadcast: "         + address.broadcast ); 
                    trace( "  prefix length: "     + address.prefixLength ); 
                } 
            }             
        } 
    }     
} 
}

Mer information finns i:

• NetworkInfo

• NetworkInterface

• InterfaceAddress

• Flexpert: Detecting the network connection type with Flex 4.5 (Upptäcka nätverksanslutningstyp med Flex)

AIR-programmet kan köras i miljöer där nätverksanslutningen är osäker och ändras. Om en nätverksanslutning blir tillgänglig eller inte längre kan användas, skickar Adobe AIR en nätverksändringshändelse. Det blir då lättare för ett program att hantera anslutningarna till olika onlineresurser. Både NetworkInfo-objektet och programmets NativeApplication-objekt skickar händelsen networkChange . Om programmet ska reagera på den här händelsen lägger du till en lyssnare:

NetworkInfo.networkInfo.addEventListener(Event.NETWORK_CHANGE, onNetworkChange); 

Ange också en händelsehanterarfunktion:

function onNetworkChange(event:Event) 
{ 
    //Check resource availability 
} 

Händelsen networkChange indikerar inte någon ändring i all nätverksaktivitet, utan bara att en enskild nätverksanslutning har ändrats. AIR försöker inte tolka innebörden av den här nätverksändringen. En nätverksansluten dator kan ha många verkliga och virtuella anslutningar. Att en anslutning försvinner behöver alltså inte innebära att en resurs går förlorad. Nya anslutningar garanterar inte heller förbättrad resurstillgänglighet. Ibland kan en ny anslutning till och med blockera åtkomst till resurser som varit tillgängliga tidigare (till exempel vid anslutning till VPN).

Vanligtvis kan ett program bara avgöra om det kan ansluta till en fjärresurs genom att prova. I ramverket för tjänstövervakning tillhandahålls en händelsebaserad metod att svara på ändringar i nätverksanslutning till en angiven värd.

Du kan leta upp DNS-resursposter med hjälp av klassen DNSResolver. I DNS-resursposter tillhandahålls information som IP-adressen för ett domännamn och domännamnet för en IP-adress. Du kan leta upp följande typer av DNS-resursposter:

• ARecord – IPv4-adress för en värd.

• AAAARecord – IPv6-adress för en värd.

• MXRecord – post för utbyte av e-post för en värd.

• PTRRecord – värdnamn för en IP-adress.

• SRVRecord – tjänstpost för en tjänst.

Om du vill leta upp en post skickar du en frågesträng och det klassobjekt som representerar posttypen till lookup() -metoden för DNSResolver-objektet. Vilken frågesträng som ska användas beror på posttypen:

I följande kodexempel letas IP-adressen för värden "example.com" upp.

package 
{ 
    import flash.display.Sprite; 
    import flash.events.DNSResolverEvent; 
    import flash.events.ErrorEvent; 
    import flash.net.dns.ARecord; 
    import flash.net.dns.DNSResolver; 
 
    public class DNSResolverExample extends Sprite 
    { 
         
        public function DNSResolverExample() 
        { 
            var resolver:DNSResolver = new DNSResolver(); 
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete ); 
            resolver.addEventListener( ErrorEvent.ERROR, lookupError ); 
 
            resolver.lookup( "example.com.", ARecord ); 
        } 
         
        private function lookupComplete( event:DNSResolverEvent ):void 
        { 
            trace( "Query string: " + event.host ); 
            trace( "Record count: " + event.resourceRecords.length ); 
            for each( var record:* in event.resourceRecords ) 
            { 
                if( record is ARecord ) trace( record.address ); 
            } 
             
        } 
 
        private function lookupError( error:ErrorEvent ):void 
        { 
            trace("Error: " + error.text ); 
        } 
    } 
}

Mer information finns i:

• DNSResolver

• DNSResolverEvent

• ARecord

• AAAARecord

• MXRecord

• PTRRecord

• SRVRecord