Arbeta med File-objekt i AIR

Du kan använda klassen File för följande:

• Hämta sökvägen till specialkataloger, bland annat användarkatalogen, användarens dokumentkatalog, katalogen som programmet startades från samt programkatalogen.

• Kopiera filer och kataloger.

• Flytta filer och kataloger.

• Ta bort filer och kataloger (eller flytta dem till papperskorgen)

• Visa filer och kataloger som finns i en katalog

• Skapa tillfälliga filer och mappar

När ett File-objekt pekar på en filsökväg, kan du använda den om du vill läsa och skriva fildata, med hjälp av klassen FileStream.

Ett File-objekt kan peka på sökvägen till en fil eller katalog som inte längre finns. Du kan använda sådana File-filobjekt när du skapar en fil eller katalog.

Varje File-objekt har två egenskaper som definierar sökvägen:

Klassen File inkluderar statiska egenskaper som du använder för att peka på standardkataloger i Mac OS, Windows och Linux. Bland dessa egenskaper finns:

Dessa egenskaper har olika värden på olika operativsystem. Mac och Windows har till exempel olika systemsökvägar till användarens skrivbordskatalog. Egenskapen File.desktopDirectory pekar däremot på en lämplig katalogsökväg på alla plattformar. Om du vill skriva program som fungerar bra på olika plattformar använder du de här egenskaperna som utgångspunkt för att referera till andra kataloger och filer som används av programmet. Sedan använder du metoden resolvePath() för att närmare specificera sökvägen. Den här koden pekar till exempel på filen preferences.xml i programmets katalog:

var prefsFile:File = File.applicationStorageDirectory; 
prefsFile = prefsFile.resolvePath("preferences.xml");

Även om du kan använda klassen File för att peka på en viss sökväg kan det leda till att programmet inte fungerar på alla plattformar. Sökvägen C:\Documents and Settings\joe\ fungerar till exempel bara på Windows. Därför är det bäst att använda de statiska egenskaperna i klassen File, som File.documentsDirectory.

De faktiska systemsökvägarna för dessa kataloger varierar beroende på operativsystem och datorkonfiguration. Sökvägarna i den här tabellen är exempel. Du bör alltid använda lämpliga statiska egenskaper för klassen File för att referera till de här katalogerna så att programmet fungerar som det ska oavsett plattform. I ett riktigt AIR-program hämtas värdena för applicationID och filename (som visas i tabellen) från programbeskrivningsfilen. Om du anger ett utgivar-ID i programbeskrivningsfilen läggs utgivar-ID:t till program-ID:t i dessa sökvägar. Värdet på userName är kontonamnet för den användare som installerar programmet.

För att skydda systemfilerna på enheter med AIR for TV kan ett AIR-program bara komma åt en begränsad uppsättning kataloger. AIR for TV hindrar programmet från att komma åt några andra kataloger. Dessutom isolerar AIR for TV varje användares egna data för varje AIR-program.

AIR-programmet använder katalognamn som bara är avsedda för ActionScript 3.0-användning. De här namnen representerar inte några verkliga kataloger på enheten. AIR for TV mappar dessa ActionScript 3.0-katalognamn till verkliga kataloger på enheten. Den här mappningen ser till AIR for TV-program inte kommer åt lokala filer som de inte äger, vare sig det är av misstag eller av andra skäl.

ActionScript 3.0-katalognamnen är:

Om ett program försöker få tillgång till en skyddad katalog genereras ett undantagsfel som ActionScript-koden kan hantera.

I följande tabell visas File.nativePath-värdena för olika File-egenskaper och -metoder. Värdena speglar programmets begränsade vy av enhetens filsystem.

Ta även hänsyn till beteendet för följande metoder på enheter med AIR for TV:

Du kan ställa in ett File-objekt på två sätt så att det pekar mot en katalog.

Du kan ställa in filen som ett File-objekt pekar mot på olika sätt.

Du kan också ändra sökvägen för ett befintligt File-objekt genom att anropa metoden resolvePath() eller ändra egenskapen nativePath eller url för objektet, som i följande exempel (i Windows):

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
trace(file1.nativePath); // C:\Documents and Settings\userName\My Documents\AIR Test 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath(".."); 
trace(file2.nativePath); // C:\Documents and Settings\userName 
var file3:File = File.documentsDirectory; 
file3.nativePath += "/subdirectory"; 
trace(file3.nativePath); // C:\Documents and Settings\userName\My Documents\subdirectory 
var file4:File = new File(); 
file4.url = "file:///c:/AIR Test/test.txt"; 
trace(file4.nativePath); // C:\AIR Test\test.txt 

När du använder egenskapen nativePath använder du snedstrecket (/) som katalogavgränsare. På Windows kan du även använda omvänt snedstreck (\), men du bör inte göra det eftersom det kan innebära att koden inte fungerar på alla plattformar.

I AIR kan du använda följande URL-scheman när du definierar egenskapen url för ett File-objekt:

file:///c:/AIR Test/test.txt

app:/images

app-storage:/settings/prefs.xml

Med metoden getRelativePath() kan du söka efter den relativa sökvägen mellan två filer:

var file1:File = File.documentsDirectory.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
 
trace(file1.getRelativePath(file2)); // bob/test.txt 

Den andra parametern för metoden getRelativePath(), parametern useDotDot, gör att syntaxen .. kan returneras i resultat, vilket anger överordnade kataloger:

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
var file3:File = File.documentsDirectory; 
file3 = file3.resolvePath("AIR Test/susan/test.txt"); 
 
trace(file2.getRelativePath(file1, true)); // ../.. 
trace(file3.getRelativePath(file2, true)); // ../../bob/test.txt 

Fil- och sökvägsnamn är inte skiftlägeskänsliga i Windows och Mac OS. Nedan pekar två File-objekt mot samma fil:

File.documentsDirectory.resolvePath("test.txt"); 
File.documentsDirectory.resolvePath("TeSt.TxT");

Dokument- och katalognamnen har emellertid samma skiftläge. Nedan förutsätts det att det finns en mapp med namnet AIR Test i dokumentkatalogen:

var file:File = File.documentsDirectory.resolvePath("AIR test"); 
trace(file.nativePath); // ... AIR test 
file.canonicalize(); 
trace(file.nativePath); // ... AIR Test 

Metoden canonicalize() konverterar nativePath-objektet så att rätt skiftläge används för fil- eller katalognamnet. Om användningen av gemener och versaler är det enda som skiljer olika filer åt i ett system som är skiftlägeskänsligt (t.ex. Linux) justerar canonicalize()-metoden sökvägen så att den matchar den första fil som hittas (i den ordning som fastställs av filsystemet).

Du kan också använda metoden canonicalize() om du vill konvertera korta filnamn (”8.3”-namn) till långa filnamn i Windows, som i följande exempel:

var path:File = new File(); 
path.nativePath = "C:\\AIR~1"; 
path.canonicalize(); 
trace(path.nativePath); // C:\AIR Test

Olika operativsystem stöder paketfiler och filer med symboliska länkar:

Paket – I Mac OS kan kataloger definieras som paket och visas som en fil i Finder i Mac OS i stället för som en katalog.

Symboliska länkar – Symboliska länkar stöds i Mac OS, Linux och Windows Vista. Med hjälp av symboliska länkar kan en fil peka på en annan fil eller katalog på disken. Även om de påminner om varandra är symboliska länkar och alias inte samma sak. Ett alias rapporteras alltid som en fil (i stället för som en katalog), och om du läser eller skriver till aliaset eller genvägen påverkar detta inte den ursprungliga fil eller katalog som dessa pekar på. En symbolisk länk fungerar däremot precis som den fil eller katalog den pekar på. Den kan rapporteras som en fil eller katalog, och om du läser eller skriver till en symbolisk länk påverkar detta den fil eller katalog som länken pekar på, inte den symboliska länken. I Windows är dessutom egenskapen isSymbolicLink för ett File-objekt som refererar till en knutpunkt (används i NTFS-filsystemet) angiven som true .

Klassen File omfattar egenskaperna isPackage och isSymbolicLink som kontrollerar om ett File-objekt refererar till ett paket eller en symbolisk länk.

Följande kod itererar genom användarens skrivbordskatalog, och visar underkataloger som inte är paket:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isDirectory && !!desktopNodes[i].isPackage) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

Följande kod itererar genom användarens skrivbordskatalog, och visar filer och kataloger som inte är symboliska länkar:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (!desktopNodes[i].isSymbolicLink) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

Metoden canonicalize() ändrar sökvägen för en symbolisk länk till att peka mot filen eller katalogen som länken refererar till. Följande kod itererar genom användarens skrivbordskatalog, och rapporterar sökvägarna som refereras av filer som är symboliska länkar:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isSymbolicLink) 
    { 
        var linkNode:File = desktopNodes[i] as File; 
        linkNode.canonicalize(); 
        trace(linkNode.nativePath); 
    } 
} 

Egenskapen spaceAvailable för ett File-objekt anger det lediga utrymmet vid File-platsen, i byte. Följande kod kontrollerar det lediga utrymmet i programlagringskatalogen:

trace(File.applicationStorageDirectory.spaceAvailable); 

Om filobjektet refererar till en katalog, visar egenskapen spaceAvailable utrymmet i den katalog som filen kan använda. Om filobjektet refererar till en fil, visar egenskapen spaceAvailable utrymmet som filen kan växa till. Om filplatsen inte finns, är egenskapen spaceAvailable inställd på 0. Om filobjektet refererar till en symbolisk länk, ställs egenskapen spaceAvailable in på det lediga utrymme som den symboliska länken pekar ut.

Vanligtvis är det tillgängliga utrymmet för en katalog eller fil samma som det tillgängliga utrymmet i volymen som innehåller katalogen eller filen. Kvoter och kataloggränser räknas dock med i tillgängligt utrymme.

Att lägga till en fil eller en katalog i en volym kräver generellt mer utrymme än den befintliga storleken på filen eller på innehållet i katalogen. Operativsystemet kan till exempel kräva mer utrymme för att lagra indexinformation. Eller också kan disksektorerna kräva mer utrymme. Tillgängligt utrymme ändras dynamiskt. Du kan alltså inte förvänta dig att tilldelas hela det rapporterade utrymmet för fillagring. Information om hur du skriver till filsystemet finns i Läsa och skriva filer.

Metoden StorageVolumeInfo.getStorageVolumes() ger mer detaljerad information om monterade lagringsvolymer (se Arbeta med lagringsvolymer).

I AIR 2 kan du öppna en fil med hjälp av det program som registrerats i operativsystemet för att öppna filen. Ett AIR-program kan till exempel öppna en DOC-fil med det program som registrerats för att öppna den. Använd metoden openWithDefaultApplication() för ett File-objekt för att öppna filen. Med följande kod öppnas till exempel en fil med namnet test.doc på användarens skrivbord med hjälp av standardprogrammet för DOC-filer:

var file:File = File.deskopDirectory; 
file = file.resolvePath("test.doc"); 
file.openWithDefaultApplication();

Med följande kod kan användaren navigera till en mp3-fil och öppna den i standardprogrammet för att spela upp mp3-filer:

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Du kan inte använda metoden openWithDefaultApplication() med filer som finns i programkatalogen.

Med AIR förhindras du att använda metoden openWithDefaultApplication() för att öppna vissa filer. I Windows förhindras du av AIR att öppna filer med vissa filtyper, till exempel EXE eller BAT. I Mac OS och Linux förhindrar AIR att du öppnar filer i vissa program. (Det gäller bland annat terminalen och AppletLauncher i Mac OS och csh, bash eller ruby i Linux.) Om du försöker öppna någon av dessa filer med metoden openWithDefaultApplication() resulterar det i ett undantag. En komplett lista över förhindrade filtyper finns under språkreferensposten för metoden File.openWithDefaultApplication().