Arbeta med omvänd kinematik (IK – inverse kinematics)

Med omvänd kinematik (IK) kan du skapa realistisk animering genom att koppla ihop delarna så att de flyttas i förhållande till varandra på ett verklighetstroget sätt.

Med omvänd kinematik kan du till exempel flytta ett ben till en viss position genom att röra de leder i benet som behövs för att uppnå önskad ställning. Omvänd kinematik använder ett ramverk med ben sammankopplade i en struktur som kallas för en IK-armatur. Med paketet fl.ik kan du skapa animeringar som påminner om naturlig rörelse. Med det kan du animera flera IK-armaturer sömlöst utan att behöva kunna något om fysiken bakom IK-algoritmerna.

Skapa IK-armaturen med stödjande ben och leder med Flash Professional. Sedan kan du använda IK-klasser för att animera dem vid körning.

Mer information om hur du skapar en IK-armatur finns i avsnittet Använda omvänd kinematik i Använda Flash Professional .

När du har skapat en IK-armatur i Flash Professional använder du fl.ik -klasserna för att begränsa dess rörelser, spåra dess händelser och animera den vid körning.

I bilden nedan visas ett filmklipp med namnet Wheel. Axeln är en instans av en IKArmature med namnet Axle . Klassen IKMover flyttar armaturen samtidigt som hjulet roterar. Ett IKBone, ikBone2 , i armaturen kopplas till hjulet vid leden vid änden.

A.

Hjul

B.

Axel

C.

ikBone2

Vid körning snurrar hjulet tillsammans med rörelseinterpoleringen __motion_Wheel , som behandlas i Beskriva animeringen . Ett IKMover-objekt initieras och kontrollerar axelns rörelser. I bilden nedan visas två ögonblicksbilder av axelarmaturen som kopplas till spinnrocken vid olika bildrutor i rotationen.

import fl.ik.* 
 
var tree:IKArmature = IKManager.getArmatureByName("Axle"); 
var bone:IKBone = tree.getBoneByName("ikBone2"); 
var endEffector:IKJoint = bone.tailJoint; 
var pos:Point = endEffector.position; 
 
var ik:IKMover = new IKMover(endEffector, pos); 
ik.limitByDistance = true; 
ik.distanceLimit = 0.1; 
ik.limitByIteration = true; 
ik.iterationLimit = 10; 
 
Wheel.addEventListener(Event.ENTER_FRAME, frameFunc); 
 
function frameFunc(event:Event) 
{ 
    if (Wheel != null) 
    { 
        var mat:Matrix = Wheel.transform.matrix; 
        var pt = new Point(90, 0); 
        pt = mat.transformPoint(pt); 
         
        ik.moveTo(pt); 
    } 
}

Följande IK-klasser används för att flytta axeln:

Fullständiga och detaljerade beskrivningar av de här klasserna finns i ik-paketet .

Deklarera först variabler för armaturen, benet och leden som utgör de delar som du vill flytta.

Följande kod använder metoden getArmatureByName() för klassen IKManager för att tilldela värdet på axelarmaturen till IKArmature-variabeln tree . Axelarmaturen har redan skapats med Flash Professional.

var tree:IKArmature = IKManager.getArmatureByName("Axle");

Följande kod använder på ett liknande sätt metoden getBoneByName() för klassen IKArmature för att tilldela värdet på benet ikBone2 till IKBone-variabeln.

var bone:IKBone = tree.getBoneByName("ikBone2");

Ändleden för benet ikBone2 är den del av armaturen som kopplas till spinnrocken.

Följande rad deklarerar variabeln endEffector och tilldelar den till egenskapen tailjoint för benet ikBone2 :

var endEffector:IKJoint = home.tailjoint;

var pos:Point = endEffector.position;

I det här exemplet är pos positionen för leden i slutet på axeln där den ansluter till hjulet. Det ursprungliga värdet på den här variabeln hämtas från egenskapen position för IKJoint.

En instans av klassen IKMover flyttar axeln.

var ik:IKMover = new IKMover(endEffector, pos);

Med egenskaperna för klassen IKMover kan du begränsa armaturens rörelse. Du kan begränsa rörelsen utifrån rörelsens avstånd, iterationer och tid.

Följande egenskapspar framtvingar dessa gränser. Paren består av ett booleskt värde, som anger om rörelsen begränsas, och ett heltal, som anger gränsen:

Som standard anges alla booleska värden till false , vilket innebär att rörelsen inte är begränsad om du inte uttryckligen anger ett booleskt värde som true . Om du vill tvinga fram en begränsning anger du relevant egenskap som true och anger sedan ett värde för motsvarande heltalsegenskap. Om du anger begränsningen som ett värde utan att ange motsvarande boolesk egenskap ignoreras gränsen. I så fall fortsätter IK-motorn att flytta objektet tills en annan gräns eller målpositionen för IKMover uppnås.

ik.limitByDistance = true; 
ik.distanceLimit = 0.1; 
ik.limitByIteration = true; 
ik.iterationLimit = 10; 

Omvänd kinematik i Flash Professional CS5 har stöd för benfjädring. Benfjädring kan appliceras under redigering, och benfjädringsattribut kan läggas till eller ändras under körningstid. Fjädring är en egenskap för ett ben och dess leder. Den har två attribut: IKJoint.springStrength , som anger fjädringsmängden samt IKJoint.springDamping , som ökar styrkevärdets motstånd och ändrar fjädringens minskningstakt.

Fjädringsstyrka är ett procentvärde från standardvärde 0 (helt rigid) till 100 (mycket lös och kontrollerad av fysiken). Ben med fjädring reagerar på tillhörande leds rörelser. Om ingen annan översättning (rotation, x eller y) är aktiverad har fjädringsinställningarna ingen effekt.

Fjädringsdämpning är ett procentvärde från standardvärde 0 (inget motstånd) till 100 (kraftigt dämpad). Dämpning påverkar den tid som löper mellan ett bens initiala rörelse och dess återgång till viloläge.

Du kan se om det finns aktiverade fjädrar för ett IKArmature-objekt genom att kontrollera dess IKArmature.springsEnabled -egenskap. De övriga fjäderegenskaperna och metoderna hör till enskilda IKJoint-objekt. En led kan aktiveras för en vinkelrotation och översättning längs x- och y-axlarna. Du kan positionera en roterande leds fjädervinkel med IKJoint.setSpringAngle och en översättningsbar leds fjäderposition med IKJoint.setSpringPt .

I det här exemplet väljs ett ben efter namn och dess tailJoint identifieras. Koden testar den överordnade armaturen för att se om fjädrarna är aktiverade och anger därefter fjädringsegenskaperna för leden.

var arm:IKArmature = IKManager.getArmatureAt(0); 
var bone:IKBone = arm.getBoneByName("c"); 
var joint:IKJoint = bone.tailJoint; 
if (arm.springsEnabled) { 
    joint.springStrength = 50; //medium spring strength 
    joint.springDamping = 10; //light damping resistance 
    if (joint.hasSpringAngle) { 
        joint.setSpringAngle(30); //set angle for rotational spring 
    } 
}

Med klassen IKEvent kan du skapa ett händelseobjekt som innehåller information om IK-händelser. IKEvent-informationen beskriver rörelsen som har avbrutits på grund av att angiven gräns för tid, avstånd eller iteration överskrids.

Följande kod visar en händelseavlyssnare och hanterare för spårning av tidsgränshändelser. Den här händelsehanteraren rapporterar tid, avstånd och antal iterationer samt ledegenskaper för en händelse som utlöses när tidsgränsen för IKMover överskrids.

var ikmover:IKMover = new IKMover(endjoint, pos); 
ikMover.limitByTime = true; 
ikMover.timeLimit = 1000; 
 
ikmover.addEventListener(IKEvent.TIME_LIMIT, timeLimitFunction); 
 
function timeLimitFunction(evt:IKEvent):void 
{ 
    trace("timeLimit hit"); 
    trace("time is " + evt.time); 
    trace("distance is " + evt.distance); 
    trace("iterationCount is " + evt.iterationCount); 
    trace("IKJoint is " + evt.joint.name); 
}