Använda komponenten DataGrid

Använda en lokal DataProvider med en DataGrid-komponent:

I det här exemplet skapas en DataGrid som visar ett fotbollslags spelarlista (roster). Spelarlistan (roster) definieras i en Array ( aRoster ) som tilldelas DataGridens dataProvider -egenskap.

1. I Flash väljer du först Arkiv > Ny och sedan Flash File (ActionScript 3.0).

2. Dra en DataGrid-komponent från panelen Komponenter till scenen.

3. Ange förekomstnamnet aDg i egenskapsinspektören.

4. Öppna åtgärdspanelen, markera bildruta 1 i huvudtidslinjen och ange följande ActionScript-kod:

   import fl.data.DataProvider; 
    
   bldRosterGrid(aDg); 
   var aRoster:Array = new Array(); 
   aRoster = [ 
           {Name:"Wilma Carter", Bats:"R", Throws:"R", Year:"So", Home: "Redlands, CA"},  
           {Name:"Sue Pennypacker", Bats:"L", Throws:"R", Year:"Fr", Home: "Athens, GA"}, 
           {Name:"Jill Smithfield", Bats:"R", Throws:"L", Year:"Sr", Home: "Spokane, WA"}, 
           {Name:"Shirley Goth", Bats:"R", Throws:"R", Year:"Sr", Home: "Carson, NV"}, 
           {Name:"Jennifer Dunbar", Bats:"R", Throws:"R", Year:"Fr", Home: "Seaside, CA"}, 
           {Name:"Patty Crawford", Bats:"L", Throws:"L", Year:"Jr", Home: "Whittier, CA"}, 
           {Name:"Angelina Davis", Bats:"R", Throws:"R", Year:"So", Home: "Odessa, TX"}, 
           {Name:"Maria Santiago", Bats:"L", Throws:"L", Year:"Sr", Home: "Tacoma, WA"}, 
           {Name:"Debbie Ferguson", Bats:"R", Throws:"R", Year: "Jr", Home: "Bend, OR"}, 
           {Name:"Karen Bronson", Bats:"R", Throws:"R", Year: "Sr", Home: "Billings, MO"}, 
           {Name:"Sylvia Munson", Bats:"R", Throws:"R", Year: "Jr", Home: "Pasadena, CA"}, 
           {Name:"Carla Gomez", Bats:"R", Throws:"L", Year: "Sr", Home: "Corona, CA"}, 
           {Name:"Betty Kay", Bats:"R", Throws:"R", Year: "Fr", Home: "Palo Alto, CA"}, 
   ]; 
   aDg.dataProvider = new DataProvider(aRoster); 
   aDg.rowCount = aDg.length; 
    
   function bldRosterGrid(dg:DataGrid){ 
       dg.setSize(400, 300); 
       dg.columns = ["Name", "Bats", "Throws", "Year", "Home"]; 
       dg.columns[0].width = 120; 
       dg.columns[1].width = 50; 
       dg.columns[2].width = 50; 
       dg.columns[3].width = 40; 
       dg.columns[4].width = 120; 
       dg.move(50,50); 
   };

   Funktionen bldRosterGrid() anger storleken på DataGrid samt ordningen på kolumnerna och deras storlek.

5. Välj Kontroll > Testa filmen.

Ange kolumner och lägg till sortering för en DataGrid-komponent i ett program

Observera att du kan klicka på vilken kolumnrubrik som helst för att sortera DataGrid-innehållet i fallande ordning efter kolumnens värden.

I följande exempel används metoden addColumn() för att lägga till DataGridColumn-förekomster i en DataGrid. Kolumnerna representerar spelarnamn och deras resultat. I exemplet anges också egenskapen sortOptions för att specificera sorteringsalternativen för varje kolumn: Array.CASEINSENSITIVE för namnkolumnen och Array.NUMERIC för resultatkolumnen. Storleken på DataGrid ändras genom att längden ställs in till antalet rader och bredden till 200.

1. I Flash väljer du först Arkiv > Ny och sedan Flash File (ActionScript 3.0).

2. Dra en DataGrid-komponent från panelen Komponenter till scenen.

3. Ange förekomstnamnet aDg i egenskapsinspektören.

4. Öppna åtgärdspanelen, markera bildruta 1 i huvudtidslinjen och ange följande ActionScript-kod:

   import fl.controls.dataGridClasses.DataGridColumn; 
   import fl.events.DataGridEvent; 
   import fl.data.DataProvider; 
   // Create columns to enable sorting of data. 
   var nameDGC:DataGridColumn = new DataGridColumn("name"); 
   nameDGC.sortOptions = Array.CASEINSENSITIVE; 
   var scoreDGC:DataGridColumn = new DataGridColumn("score"); 
   scoreDGC.sortOptions = Array.NUMERIC; 
   aDg.addColumn(nameDGC); 
   aDg.addColumn(scoreDGC); 
   var aDP_array:Array = new Array({name:"clark", score:3135}, {name:"Bruce", score:403}, {name:"Peter", score:25}) 
   aDg.dataProvider = new DataProvider(aDP_array); 
   aDg.rowCount = aDg.length; 
   aDg.width = 200;

5. Välj Kontroll > Testa filmen.

Skapa en förekomst av en DataGrid-komponent med ActionScript

I det här exemplet skapas en DataGrid med ActionScript som fylls i med en Array med spelarnamn och resultat.

1. Skapa ett nytt Flash-dokument (ActionScript 3.0).

2. Dra DataGrid-komponenten från panelen Komponenter till det aktuella dokumentets bibliotekspanel.

   Komponenten läggs till i biblioteket, men den syns inte i programmet.

3. Öppna åtgärdspanelen, markera bildruta 1 i huvudtidslinjen och ange följande ActionScript-kod:

   import fl.controls.DataGrid; 
   import fl.data.DataProvider; 
    
   var aDg:DataGrid = new DataGrid(); 
   addChild(aDg); 
   aDg.columns = [ "Name", "Score" ]; 
   aDg.setSize(140, 100); 
   aDg.move(10, 40);

   Den här koden skapar DataGrid-förekomsten och ändrar sedan storlek på och placerar rutnätet.

4. Skapa en array, lägga till data i arrayen och identifiera arrayen som DataProvider för DataGrid:

   var aDP_array:Array = new Array(); 
   aDP_array.push({Name:"Clark", Score:3135}); 
   aDP_array.push({Name:"Bruce", Score:403}); 
   aDP_array.push({Name:"Peter", Score:25}); 
   aDg.dataProvider = new DataProvider(aDP_array); 
   aDg.rowCount = aDg.length;

5. Välj Kontroll > Testa filmen.

Läsa in en DataGrid med en XML-fil

I följande exempel används klassen DataGridColumn för att skapa DataGrid-kolumner. DataGrid fylls i genom att ett XML-objekt skickas som value -parametern för DataProvider() -konstruktorn.

1. Använd en textredigerare för att skapa en XML-fil med följande data och spara den som team.xml i samma mapp som du tänker spara FLA-fil.

   <team> 
       <player name="Player A" avg="0.293" /> 
       <player name="Player B" avg="0.214" /> 
       <player name="Player C" avg="0.317" /> 
   </team>

2. Skapa ett nytt Flash-dokument (ActionScript 3.0).

3. I panelen Komponenter dubbelklickar du på komponenten DataGrid för att lägg till den på scenen.

4. Ange förekomstnamnet aDg i egenskapsinspektören.

5. Öppna åtgärdspanelen, markera bildruta 1 i huvudtidslinjen och ange följande ActionScript-kod:

   import fl.controls.dataGridClasses.DataGridColumn; 
   import fl.data.DataProvider; 
   import flash.net.*; 
   import flash.events.*; 
    
   var request:URLRequest = new URLRequest("team.xml"); 
   var loader:URLLoader = new URLLoader; 
    
    
   loader.load(request); 
   loader.addEventListener(Event.COMPLETE, loaderCompleteHandler); 
    
   function loaderCompleteHandler(event:Event):void { 
    
       var teamXML:XML = new XML(loader.data); 
    
       var nameCol:DataGridColumn = new DataGridColumn("name"); 
       nameCol.headerText = "Name"; 
       nameCol.width = 120; 
       var avgCol:DataGridColumn = new DataGridColumn("avg"); 
       avgCol.headerText = "Average"; 
       avgCol.width = 60; 
        
       var myDP:DataProvider = new DataProvider(teamXML); 
        
       aDg.columns = [nameCol, avgCol]; 
       aDg.width = 200; 
       aDg.dataProvider = myDP; 
       aDg.rowCount = aDg.length; 
   }

6. Välj Kontroll > Testa filmen.