Använda komponenten Slider

När en Slider-förekomst har fokus kan du använda följande tangenter för att styra den:

Mer information om att kontrollera fokus finns i avsnittet om gränssnittet IFocusManager och i klassen FocusManager i Referenshandbok för ActionScript 3.0 i Adobe Flash Professional och Arbeta med FocusManager .

En direktförhandsvisning av varje Slider-förekomst reflekterar ändringar som gjorts på parametrar i egenskapsinspektören eller komponentinspektören vid redigeringen.

Du kan ställa in följande utvecklingsparametrar i egenskapsinspektören eller komponentinspektören för varje förekomst av Slider-komponenten: direction , liveDragging , maximum , minimum , snapInterval , tickInterval och value . Var och en av de här parametrarna har en motsvarande ActionScript-egenskap med samma namn. Information om möjliga värden på de här parametrarna finns i avsnittet om klassen Slider i Referenshandbok för ActionScript 3.0 i Adobe Flash Professional .

Följande exempel skapar en Slider-förekomst som gör att användaren kan uttrycka sin nöjdhetnivå med en hypotetisk händelse. Användaren flyttar reglaget till höger eller vänster för att ange en högre eller lägre nöjdhetsnivå.

1. Skapa ett nytt Flash-dokument (ActionScript 3.0).

2. Dra en Label-komponent från panelen Komponenter till mitten av scenen.

   • Ge den förekomstnamnet valueLabel .

   • Tilldela värdet 0 procent till text -parametern.

3. Dra en Slider-komponent från panelen Komponenter och centrera den nedanför value_lbl .

   • Ge den förekomstnamnet aSlider .

   • Tilldela den en bredd (W:) på 200 .

   • Tilldela den en höjd (H:) på 10 .

   • Tilldela ett värde på 100 till maximum -parametern.

   • Tilldela ett värde på 10 till både snapInterval - och tickInterval -parametern.

4. Dra en annan Label-förekomst från bibliotekspanelen och centrera den nedanför aSlider.

   • Ge den förekomstnamnet promptLabel .

   • Tilldela den en bredd (W:) på 250.

   • Tilldela den en höjd (H:) på 22.

   • Skriv Ange din nöjdhetsnivå som text -parameter.

5. Öppna åtgärdspanelen, markera bildruta 1 i huvudtidslinjen och ange följande ActionScript-kod:

   import fl.controls.Slider; 
   import fl.events.SliderEvent; 
   import fl.controls.Label; 
    
   aSlider.addEventListener(SliderEvent.CHANGE, changeHandler); 
    
   function changeHandler(event:SliderEvent):void { 
       valueLabel.text = event.value + "percent";     
   }

6. Välj Kontroll > Testa filmen.

   När du flyttar skjutreglaget från ett intervall till ett annat i det här exemplet uppdaterar en avlyssnare för SliderEvent.CHANGE -händelsen egenskapen text för valueLabel så att den visar den procentandel som motsvarar reglagets position.

Följande exempel skapar en Slider med ActionScript. Exemplet läser in en bild av en blomma och använder Slider så att användaren kan tona ut bilden eller göra den ljusare genom att ändra dess alpha -egenskap så att den motsvarar värdet på Slider.

1. Skapa ett nytt Flash-dokument (ActionScript 3.0).

2. Dra Label-komponenten och Slicer-komponenten från panelen Komponenter till det aktuella dokumentets bibliotekspanel.

   Komponenterna läggs till i biblioteket, men de syns inte i programmet.

3. Öppna panelen Åtgärder, markera bildruta 1 i huvudtidslinjen och ange följande kod för att skapa och placera komponentförekomsterna:

   import fl.controls.Slider; 
   import fl.events.SliderEvent; 
   import fl.controls.Label; 
   import fl.containers.UILoader; 
    
   var sliderLabel:Label = new Label(); 
   sliderLabel.width = 120; 
   sliderLabel.text = "< Fade - Brighten >"; 
   sliderLabel.move(170, 350); 
    
   var aSlider:Slider = new Slider(); 
   aSlider.width = 200; 
   aSlider.snapInterval = 10; 
   aSlider.tickInterval = 10; 
   aSlider.maximum = 100; 
   aSlider.value = 100; 
   aSlider.move(120, 330); 
    
   var aLoader:UILoader = new UILoader(); 
   aLoader.source = "http://www.flash-mx.com/images/image1.jpg"; 
   aLoader.scaleContent = false; 
    
   addChild(sliderLabel); 
   addChild(aSlider); 
   addChild(aLoader); 
    
   aLoader.addEventListener(Event.COMPLETE, completeHandler); 
    
   function completeHandler(event:Event) { 
       trace("Number of bytes loaded: " + aLoader.bytesLoaded); 
   } 
    
   aSlider.addEventListener(SliderEvent.CHANGE, changeHandler); 
    
   function changeHandler(event:SliderEvent):void { 
           aLoader.alpha = event.value * .01; 
   }

4. Välj Kontroll > Testa filmen för att köra programmet.

5. Flytta skjutreglaget till vänster om du vill tona ut bilden och till höger om du vill göra den ljusare.