Använda komponenten UIScrollBar

Med komponenten UIScrollBar-komponent som gör att du kan lägga till en rullningslist i ett textfält. Du kan lägga till en rullningslist i ett textfält under utvecklingen, eller under körning med ActionScript. Om du vill använda UIScrollBar-komponenten skapar du ett textfält på scenen och drar UIScrollBar-komponenten från panelen Komponenter till någon av kvadranterna i textfältets begränsningsram.

Om rullningslistens är kortare än den kombinerade storleken på rullningspilarna visas den inte korrekt. En av piltangenterna döljs bakom den andra. Flash har ingen felsökning för det här. I det här fallet är det en god idé att dölja rullningslisten med ActionScript. Om rullningslisten har en sådan storlek att det inte finns plats för rullningrutan (reglaget) gör Flash rullningsrutan osynlig.

Komponenten UIScrollBar fungerar på samma sätt som alla rullningslister. Den har pilknappar i varje ände, och ett rullningsspår och en rullningsruta (reglage) däremellan. Den kan fästas vid någon av kanterna på ett textfält och användas både lodrätt och vågrätt.

Mer information om TextField finns i avsnittet om klassen TextField i Referenshandbok för ActionScript 3.0 i Adobe Flash Professional .

Använda komponenten UIScrollBar

Till skillnad från många andra komponenter kan UIScrollBar ta emot kontinuerliga indata från musen, till exempel när användaren håller ned musknappen, i stället för att kräva upprepade klickningar.

Det finns ingen tangentbordsinteraktion för UIScrollBar-komponenten.

UIScrollBar-komponentparametrar

Du kan ställa in följande utvecklingsparametrar i egenskapsinspektören eller komponentinspektören för varje förekomst av UIScrollBar-komponenten: direction och scrollTargetName . Var och en av de här parametrarna har en motsvarande ActionScript-egenskap med samma namn.

Du kan skriva ActionScript för att ange ytterligare alternativ för UIScrollBar-förekomster genom att använda metoder, egenskaper och händelser för klassen. Mer information finns i avsnittet om klassen UIScrollBar i Referenshandbok för ActionScript 3.0 i Adobe Flash Professional .

Skapa ett program med komponenten UIScrollBar

I proceduren nedan beskrivs hur du lägger till en UIScrollBar-komponent i ett program när du redigerar.

  1. Skapa ett nytt Flash-dokument (ActionScript 3.0).

  2. Skapa ett dynamiskt textfält som är tillräckligt högt för att en eller två textrader ska få plats, och ge det förekomstnamnet myText i egenskapsinspektören.

  3. I egenskapsinspektören anger du Multiline eller Multiline No Wrap som värde för textindatafältets Line Type om du tänker använda rullningslisten vågrätt.

  4. Öppna åtgärdspanelen, välj bildruta 1 i huvudtidslinjen och ange följande ActionScript-kod för att fylla text -egenskapen så att användaren måste rulla nedåt för att se allt: 

    myText.text="When the moon is in the seventh house and Jupiter aligns with Mars, then peace will guide the planet and love will rule the stars."
    Obs! Se till att textfältet på scenen är så litet att du behöver rulla i det för att se all text. Om det inte är tillräckligt litet visas inte rullningslisten, eller också visas den som två rader utan reglage (den del som du drar för att rulla innehållet).

  5. Kontrollera att objektfästning är aktiverad (Visa > Fästning > Fäst mot objekt).

  6. Dra en UIScrollBar-förekomst från panelen Komponenter till textindatafältet, i närheten av den sida som du vill fästa den vid. Komponenten måste överlappa textfältet när du släpper musknappen för att den ska fästa ordentligt vid fältet. Ge den förekomstnamnet mySb .

    Komponentens scrollTargetName -egenskap fylls automatiskt i med textfältets förekomstnamn i egenskapsinspektören och komponentinspektören. Om den inte visas på fliken Parametrar kan det hända att du inte har överlappat UIScrollBar-förekomsten tillräckligt.

  7. Välj Kontroll > Testa filmen.

Skapa en förekomst av en UIScrollBar-komponent med ActionScript

Du kan skapa en UIScrollBar-förekomst med ActionScript och associera den med ett textfält vid körningen. Följande exempel skapar en vågrät UIScrollBar-förekomst och fäster den vid nederkanten på en textfältförekomst som kallas myTxt , som fylls i med text från en URL. I exemplet ställs också rullningslistens storlek in så att den överensstämmer med textfältets storlek:

  1. Skapa ett nytt Flash-dokument (ActionScript 3.0).

  2. Dra ScrollBar-komponenten till bibliotekspanelen.

  3. Öppna åtgärdspanelen, markera bildruta 1 i huvudtidslinjen och ange följande ActionScript-kod: 

    import flash.net.URLLoader; 
import fl.controls.UIScrollBar; 
import flash.events.Event; 
 
var myTxt:TextField = new TextField(); 
myTxt.border = true; 
myTxt.width = 200; 
myTxt.height = 16; 
myTxt.x = 200; 
myTxt.y = 150; 
 
var mySb:UIScrollBar = new UIScrollBar(); 
mySb.direction = "horizontal"; 
// Size it to match the text field. 
mySb.setSize(myTxt.width, myTxt.height);  
 
// Move it immediately below the text field. 
mySb.move(myTxt.x, myTxt.height + myTxt.y); 
 
// put them on the Stage 
addChild(myTxt); 
addChild(mySb); 
// load text 
var loader:URLLoader = new URLLoader(); 
var request:URLRequest = new URLRequest("http://www.helpexamples.com/flash/lorem.txt"); 
loader.load(request); 
loader.addEventListener(Event.COMPLETE, loadcomplete); 
 
function loadcomplete(event:Event) { 
    // move loaded text to text field 
    myTxt.text = loader.data; 
    // Set myTxt as target for scroll bar. 
    mySb.scrollTarget = myTxt; 
}

  4. Välj Kontroll > Testa filmen.