Захват введенного текста

По умолчанию свойство type текстового поля имеет значение dynamic. При установке свойства type на значение input с помощью класса TextFieldType можно получить пользовательский ввод и сохранить это значение для использования в других частях приложения. Текстовые поля ввода можно использовать в формах и приложениях для определения текстовых значений, используемых в другом месте программы.

Например, следующий код создает текстовое поле ввода myTextBox. При вводе пользователем текста в поле инициируется событие textInput. Обработчик события с именем textInputCapture захватывает строку введенного текста и назначает его переменной. Flash Player или AIR отображает новый текст в другом текстовом окне с именем myOutputBox.

package 
{ 
    import flash.display.Sprite; 
    import flash.display.Stage; 
    import flash.text.*; 
    import flash.events.*; 
 
    public class CaptureUserInput extends Sprite 
    { 
        private var myTextBox:TextField = new TextField(); 
        private var myOutputBox:TextField = new TextField(); 
        private var myText:String = "Type your text here."; 
 
        public function CaptureUserInput() 
        { 
            captureText(); 
        } 
         
        public function captureText():void 
        { 
            myTextBox.type = TextFieldType.INPUT; 
            myTextBox.background = true; 
            addChild(myTextBox); 
            myTextBox.text = myText; 
            myTextBox.addEventListener(TextEvent.TEXT_INPUT, textInputCapture); 
        } 
         
        public function textInputCapture(event:TextEvent):void 
        { 
            var str:String = myTextBox.text; 
            createOutputBox(str); 
        } 
             
        public function createOutputBox(str:String):void 
        { 
            myOutputBox.background = true; 
            myOutputBox.x = 200; 
            addChild(myOutputBox); 
            myOutputBox.text = str; 
        } 
         
    } 
}