Пример XML в ActionScript: загрузка данных RSS из Интернета

Класс RSSParser включает метод xmlLoaded() , который преобразует входные RSS-данные, хранимые в переменной rssXML , в строку rssOutput , содержащую выходные данные в формате HTML.

Если исходные RSS-данные включают пространство имени по умолчанию, незадолго до начала работы метода с помощью кода задается пространство имени XML по умолчанию.

if (rssXML.namespace("") != undefined) 
{ 
    default xml namespace = rssXML.namespace(""); 
}

Следующие строки впоследствии проходят через содержимое исходных XML-данных, исследуя каждое свойство более низкого уровня с именем item :

for each (var item:XML in rssXML..item) 
{ 
    var itemTitle:String = item.title.toString(); 
    var itemDescription:String = item.description.toString(); 
    var itemLink:String = item.link.toString(); 
    outXML += buildItemHTML(itemTitle,  
                            itemDescription, 
                            itemLink); 
}

Первые три строки просто задают переменные для представления свойств заголовков, описаний и ссылок свойства item XML-данных. Следующая строка впоследствии вызывает метод buildItemHTML() для получения HTML-данных в форме объекта XMLList с помощью трех новых строковых переменных, выступающих в роли параметров.

HTML-данные (объект XMLList) имеют следующую форму:

<b>itemTitle</b> 
<p> 
    itemDescription 
    <br /> 
    <a href="link"> 
        <font color="#008000">More...</font> 
    </a> 
</p>

Первые строки метода удаляют пространство имени xml по умолчанию:

default xml namespace = new Namespace();

Директива default xml namespace функционирует в пределах определенной области. Это означает, что областью действия данной декларации является метод buildItemHTML() .

Строки, идущие после компоновки XMLList, на основе строковых аргументов передаются в функцию:

var body:XMLList = new XMLList(); 
body += new XML("<b>" + itemTitle + "</b>"); 
var p:XML = new XML("<p>" + itemDescription + "</p>"); 
 
var link:XML = <a></a>; 
link.@href = itemLink; // <link href="itemLinkString"></link> 
link.font.@color = "#008000";  
        // <font color="#008000"></font></a> 
        // 0x008000 = green 
link.font = "More..."; 
 
p.appendChild(<br/>);  
p.appendChild(link);  
body += p;

Этот объект XMLList представляет строковые данные, подходящие для текстового поля HTML ActionScript.

Метод xmlLoaded() использует возвращаемое значение метода buildItemHTML() и преобразует его в строку:

XML.prettyPrinting = false; 
rssOutput = outXML.toXMLString();    

Метод xmlLoaded() задает строковую переменную rssTitle на основе исходных XML-данных RSS-канала.

rssTitle = rssXML.channel.title.toString();

И, наконец, метод xmlLoaded() генерирует событие, которое уведомляет приложение о том, что синтаксический анализ данных выполнен и данные доступны:

            dataWritten = new Event("dataWritten", true);