Написание методов обратного вызова для метаданных и ключевых точек

Если задать свойству client экземпляр класса Object или подкласса NetStream, можно изменить маршрут методов обратного вызова onMetaData и onCuePoint или полностью их игнорировать. Следующий пример демонстрирует, как с помощью пустого экземпляра Object можно игнорировать методы обратного вызова, не прослушивая событие asyncError .

var nc:NetConnection = new NetConnection(); 
nc.connect(null); 
 
var customClient:Object = new Object(); 
 
var ns:NetStream = new NetStream(nc); 
ns.client = customClient; 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Если требуется прослушивать метод обратного вызова onMetaData или onCuePoint , необходимо определить методы для его обработки, как показано в следующем примере.

var customClient:Object = new Object(); 
customClient.onMetaData = metaDataHandler; 
function metaDataHandler(infoObject:Object):void 
{ 
    trace("metadata"); 
}

Предыдущий код прослушивает метод обратного вызова onMetaData и вызывает метод metaDataHandler() , который отслеживает строку. Когда среда выполнения Flash находит ключевые точки, то ошибки не создаются, даже если не определен метод обратного вызова onCuePoint .

Следующий код задает свойству client объекта NetStream пользовательский класс, CustomClient, который определяет обработчики для методов обратного вызова.

var nc:NetConnection = new NetConnection(); 
nc.connect(null); 
 
var ns:NetStream = new NetStream(nc); 
ns.client = new CustomClient(); 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Определение класса CustomClient выглядит следующим образом:

package 
{ 
    public class CustomClient 
    { 
        public function onMetaData(infoObject:Object):void 
        { 
            trace("metadata"); 
        } 
    } 
}

Класс CustomClient определяет обработчика для метода обратного вызова onMetaData . Когда встречается ключевая точка и вызывается метод обратного вызова onCuePoint , отправляется событие asyncError ( AsyncErrorEvent.ASYNC_ERROR ) со строкой «flash.net.NetStream was unable to invoke callback onCuePoint» (Метод flash.net.NetStream не смог вызвать метод обратного вызова onCuePoint). Чтобы предотвратить эту ошибку, нужно определить метод обратного вызова onCuePoint в классе CustomClient или определить обработчик для события asyncError .

Следующий код создает экземпляр класса CustomNetStream, который определяется в другом коде.

var ns:CustomNetStream = new CustomNetStream(); 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Следующий код определяет класс CustomNetStream, расширяющий класс NetStream, создает необходимый объект NetConnection и обрабатывает методы обратного вызова onMetaData и onCuePoint .

package 
{ 
    import flash.net.NetConnection; 
    import flash.net.NetStream; 
    public class CustomNetStream extends NetStream 
    { 
        private var nc:NetConnection; 
        public function CustomNetStream() 
        { 
            nc = new NetConnection(); 
            nc.connect(null); 
            super(nc); 
        } 
        public function onMetaData(infoObject:Object):void 
        { 
            trace("metadata"); 
        } 
        public function onCuePoint(infoObject:Object):void 
        { 
            trace("cue point"); 
        } 
    } 
}

Если требуется переименовать методы onMetaData() и onCuePoint() в классе CustomNetStream, нужно использовать следующий код:

package 
{ 
    import flash.net.NetConnection; 
    import flash.net.NetStream; 
    public class CustomNetStream extends NetStream 
    { 
        private var nc:NetConnection; 
        public var onMetaData:Function; 
        public var onCuePoint:Function; 
        public function CustomNetStream() 
        { 
            onMetaData = metaDataHandler; 
            onCuePoint = cuePointHandler; 
            nc = new NetConnection(); 
            nc.connect(null); 
            super(nc); 
        } 
        private function metaDataHandler(infoObject:Object):void 
        { 
            trace("metadata"); 
        } 
        private function cuePointHandler(infoObject:Object):void 
        { 
            trace("cue point"); 
        } 
    } 
}

Можно расширить класс NetStream и сделать его подкласс динамическим, чтобы обработчики обратного вызова onCuePoint и onMetaData добавлялись динамически. Это демонстрируется в следующем примере.

var ns:DynamicCustomNetStream = new DynamicCustomNetStream(); 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Определение класса DynamicCustomNetStream выглядит следующим образом:

package 
{ 
    import flash.net.NetConnection; 
    import flash.net.NetStream; 
    public dynamic class DynamicCustomNetStream extends NetStream 
    { 
        private var nc:NetConnection; 
        public function DynamicCustomNetStream() 
        { 
            nc = new NetConnection(); 
            nc.connect(null); 
            super(nc); 
        } 
    } 
}

Даже если нет обработчиков для методов обратного вызова onMetaData и onCuePoint , ошибки не генерируются, так как класс DynamicCustomNetStream является динамическим. Если требуется определить методы для обработчиков обратного вызова onMetaData и onCuePoint , можно использовать следующий код:

var ns:DynamicCustomNetStream = new DynamicCustomNetStream(); 
ns.onMetaData = metaDataHandler; 
ns.onCuePoint = cuePointHandler; 
ns.play("http://www.helpexamples.com/flash/video/cuepoints.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid); 
 
function metaDataHandler(infoObject:Object):void 
{ 
    trace("metadata"); 
} 
function cuePointHandler(infoObject:Object):void 
{ 
    trace("cue point"); 
}

Если задать свойству client значение this , приложение ищет методы onMetaData() и onCuePoint() в текущей области действия. Это демонстрируется в следующем примере.

var nc:NetConnection = new NetConnection(); 
nc.connect(null); 
 
var ns:NetStream = new NetStream(nc); 
ns.client = this; 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Если вызываются обработчики обратного вызова onMetaData и onCuePoint и нет методов для их обработки, ошибки не генерируются. Чтобы обработать эти методы обратного вызова, создайте в коде методы onMetaData() и onCuePoint() , как показано в следующем примере:

function onMetaData(infoObject:Object):void 
{ 
    trace("metadata"); 
} 
function onCuePoint(infoObject:Object):void 
{ 
    trace("cue point"); 
}