Загрузка внешних данных

Во многих API-интерфейсах, загружающих внешние данные, класс URLRequest используется для определения свойств необходимого сетевого запроса.

Класс URLLoader позволяет отправлять запрос на сервер и получать доступ к возвращенной информации. Класс URLLoader можно также использовать для доступа к файлам в локальной файловой системе в контекстах, в которых доступ к локальным файлам разрешен (например, в локальной изолированной программной среде с файловой системой Flash Player и изолированной программной среде приложения AIR). Класс URLLoader загружает данные с URL-адреса в виде текста, двоичных данных или переменных в кодировке URL. Класс URLLoader отправляет такие события, как complete , httpStatus , ioError , open , progress и securityError .

Модель обработки событий ActionScript 3.0 значительно отличается от модели ActionScript 2.0, в которой использовались обработчики событий LoadVars.onData , LoadVars.onHTTPStatus и LoadVars.onLoad . Дополнительные сведения об обработке событий в среде ActionScript 3.0 см. в разделе « Обработка событий »

Загруженные данные доступны только после завершения загрузки. Можно отслеживать ход выполнения загрузки (количество загруженных байтов и общее количество байтов) путем прослушивания отправляемого события progress . Однако, если файл загружается достаточно быстро, событие progress может не отправляться. При успешной загрузке файла отправляется событие complete . Путем задания свойства dataFormat объекта URLLoader можно получать данные в виде текста, двоичных данных без сжатия или объекта URLVariables.

Метод URLLoader.load() (и дополнительно конструктор класса URLLoader) имеет один параметр, request , который является объектом URLRequest. Объект URLRequest содержит всю информацию для одного HTTP-запроса, такую как целевой URL-адрес, метод запроса ( GET или POST ), дополнительную информацию заголовка и тип MIME.

Например, для выгрузки пакета XML в серверный сценарий можно использовать такой код:

var secondsUTC:Number = new Date().time; 
var dataXML:XML =  
    <clock> 
        <time>{secondsUTC}</time> 
    </clock>; 
var request:URLRequest = new URLRequest("http://www.yourdomain.com/time.cfm"); 
request.contentType = "text/xml"; 
request.data = dataXML.toXMLString(); 
request.method = URLRequestMethod.POST; 
var loader:URLLoader = new URLLoader(); 
loader.load(request); 

Предыдущий фрагмент кода создает документ XML с именем dataXML , который содержит пакет XML для отправки на сервер. В примере свойству contentType объекта URLRequest задается значение text/xml , а документ XML назначается свойству data объекта URLRequest. Наконец, в примере создается объект URLLoader и осуществляется отправка запроса в удаленный сценарий с использованием метода load() .

Класс URLStream предоставляет доступ к загружаемым данным по мере их получения. Класс URLStream также позволяет закрыть поток до завершения загрузки. Загруженные данные доступны в виде двоичных данных без сжатия.

Перед чтением данных из объекта URLStream используйте свойство bytesAvailable для определения наличия достаточного объема данных. Исключение EOFError создается при попытке чтения данных, объем которых превышает доступный объем.

При создании динамических приложений может потребоваться загрузка данных из внешних файлов или серверных сценариев. Это позволяет разрабатывать динамические приложения без редактирования и повторной компиляции приложения. Например, чтобы создать приложение типа «совет дня», можно создать сценарий, выполняемый на стороне сервера, который получает случайно выбранный совет и сохраняет его в текстовом файле раз в день. Затем приложение может загружать содержимое статического текстового файла, чтобы каждый раз не отправлять запрос в базу данных.

Следующий код создает экземпляр URLRequest и объект URLLoader, загружающий содержимое внешнего текстового файла params.txt:

var request:URLRequest = new URLRequest("params.txt"); 
var loader:URLLoader = new URLLoader(); 
loader.load(request);

var request:URLRequest = new URLRequest("sendfeedback.cfm"); 
request.method = URLRequestMethod.POST;

Внешний документ, params.txt, загружаемый во время выполнения, содержит следующие данные:

monthNames=January,February,March,April,May,June,July,August,September,October,November,December&dayNames=Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday

Файл содержит два параметра: monthNames и dayNames . Каждый параметр содержит список значений, разделенных запятыми, который анализируется как строки. Можно разбить список на массивы при помощи метода String.split() .

Старайтесь не использовать зарезервированные слова или языковые конструкции в качестве имен переменных в файлах внешних данных, так как это усложняет чтение и отладку кода.

function completeHandler(event) 
{ 
    var loader2 = event.target; 
    air.trace(loader2.data); 
}

Если удаленный документ содержит пары «имя-значение», разбор данных можно выполнить при помощи класса URLVariables, передав ему содержимое загруженного файла, как показано ниже:

private function completeHandler(event:Event):void 
{ 
    var loader2:URLLoader = URLLoader(event.target); 
    var variables:URLVariables = new URLVariables(loader2.data); 
    trace(variables.dayNames); 
}

Каждая пара «имя-значение» во внешнем файле воссоздается в виде свойства в объекте URLVariables. Каждое свойство в объекте переменных в предыдущем примере кода рассматривается как строка. Если пара «имя-значение» представляет собой список элементов, можно преобразовать строку в массив при помощи метода String.split() , как показано ниже:

var dayNameArray:Array = variables.dayNames.split(",");

Если загружаются числовые данные из внешних текстовых файлов, значения необходимо преобразовать в числовые с помощью функции верхнего уровня, такой как int() , uint() или Number() .

Вместо того, чтобы загружать содержимое удаленного файла в виде строки и создавать новый объект URLVariables, можно задать в качестве значения свойства URLLoader.dataFormat одно из статических свойств класса URLLoaderDataFormat. Свойство URLLoader.dataFormat может иметь одно из трех значений.

• URLLoaderDataFormat.BINARY — свойство URLLoader.data будет содержать бинарные данные, сохраненные в объекте ByteArray;

• URLLoaderDataFormat.TEXT — свойство URLLoader.data будет содержать текст в объекте String;

• URLLoaderDataFormat.VARIABLES — свойство URLLoader.data будет содержать переменные в кодировке URL, сохраненные в объекте URLVariables.

На примере следующего кода показано, как свойство URLLoader.dataFormat в значении URLLoaderDataFormat.VARIABLES позволяет автоматически разбирать загруженные данные и передавать их в объект URLVariables.

package 
{ 
    import flash.display.Sprite; 
    import flash.events.*; 
    import flash.net.URLLoader; 
    import flash.net.URLLoaderDataFormat; 
    import flash.net.URLRequest; 
 
    public class URLLoaderDataFormatExample extends Sprite 
    { 
        public function URLLoaderDataFormatExample() 
        { 
            var request:URLRequest = new URLRequest("http://www.[yourdomain].com/params.txt"); 
            var variables:URLLoader = new URLLoader(); 
            variables.dataFormat = URLLoaderDataFormat.VARIABLES; 
            variables.addEventListener(Event.COMPLETE, completeHandler); 
            try 
            { 
                variables.load(request); 
            }  
            catch (error:Error) 
            { 
                trace("Unable to load URL: " + error); 
            } 
        } 
        private function completeHandler(event:Event):void 
        { 
        var loader:URLLoader = URLLoader(event.target); 
        trace(loader.data.dayNames); 
        } 
    } 
}

Как показано в следующем примере, загрузка XML из внешнего файла не отличается от загрузки URLVariables. Можно создать экземпляр URLRequest и экземпляр URLLoader и использовать их для загрузки удаленного документа XML. После завершения загрузки файла, отправляется событие Event.COMPLETE , и содержимое внешнего файла преобразуется в экземпляр XML, который можно разобрать с помощью методов и свойств XML.

package 
{ 
    import flash.display.Sprite; 
    import flash.errors.*; 
    import flash.events.*; 
    import flash.net.URLLoader; 
    import flash.net.URLRequest; 
 
    public class ExternalDocs extends Sprite 
    { 
        public function ExternalDocs() 
        { 
            var request:URLRequest = new URLRequest("http://www.[yourdomain].com/data.xml"); 
            var loader:URLLoader = new URLLoader(); 
            loader.addEventListener(Event.COMPLETE, completeHandler); 
            try 
            { 
                loader.load(request); 
            } 
            catch (error:ArgumentError) 
            { 
                trace("An ArgumentError has occurred."); 
            } 
            catch (error:SecurityError) 
            { 
                trace("A SecurityError has occurred."); 
            } 
        } 
        private function completeHandler(event:Event):void 
        { 
            var dataXML:XML = XML(event.target.data); 
            trace(dataXML.toXMLString()); 
        } 
    } 
}

Класс URLVariables можно использовать не только для загрузки внешних файлов данных, но и для отправки переменных сценарию, выполняемому на стороне сервера, и обработки ответа сервера. Это используется, например, при программировании какой-либо игры, когда необходимо отправить количество набранных пользователем очков серверу, чтобы определить, нужно ли включать это количество в список лучших результатов, или когда нужно отправить серверу данные пользователя для входа в систему с целью проверки. Сценарий со стороны сервера может обработать имя пользователя и пароль, проверить их по базе данных и возвратить подтверждение подлинности предоставленных пользователем учетных данных.

Следующий код создает объект URLVariables с именем variables, который создает новую переменную с именем name . Затем создается объект URLRequest, задающий URL-адрес серверного сценария, которому нужно отправить переменные. После этого задается свойство method объекта URLRequest для отправки переменных в качестве запроса HTTP POST . Чтобы добавить объект URLVariables в запрос URL, свойству data объекта URLRequest присваивается созданный ранее объект URLVariables. Наконец, создается экземпляр URLLoader и вызывается метод URLLoader.load() , который инициирует запрос.

var variables:URLVariables = new URLVariables("name=Franklin"); 
var request:URLRequest = new URLRequest(); 
request.url = "http://www.[yourdomain].com/greeting.cfm"; 
request.method = URLRequestMethod.POST; 
request.data = variables; 
var loader:URLLoader = new URLLoader(); 
loader.dataFormat = URLLoaderDataFormat.VARIABLES; 
loader.addEventListener(Event.COMPLETE, completeHandler); 
try 
{ 
    loader.load(request); 
} 
catch (error:Error) 
{ 
    trace("Unable to load URL"); 
} 
 
function completeHandler(event:Event):void 
{ 
    trace(event.target.data.welcomeMessage); 
}

Следующий код включает содержимое документа Adobe ColdFusion® greeting.cfm, использованное в предыдущем примере.

<cfif NOT IsDefined("Form.name") OR Len(Trim(Form.Name)) EQ 0> 
    <cfset Form.Name = "Stranger" /> 
</cfif> 
<cfoutput>welcomeMessage=#UrlEncodedFormat("Welcome, " & Form.name)# 
</cfoutput>