Основные сведения о работе с сетью и обмене данными

Объект NetworkInfo можно использовать для обнаружения аппаратных и программных сетевых интерфейсов, доступных для приложения. Объект NetworkInfo является одиночным объектом, его не требуется создавать. Вместо этого используйте статическое свойство класса, networkInfo , чтобы получить доступ к одиночному объекту NetworkInfo. Объект NetworkInfo также отправляет событие networkChange при изменении одного из доступных интерфейсов.

Вызовите метод findInterfaces() для получения списка объектов NetworkInterface. Каждый объект NetworkInterface в списке описывает один из доступных интерфейсов. Объект NetworkInterface предоставляет такие данные, как IP-адрес, аппаратный адрес, максимальный размер пакета, а также сообщает, активен ли этот интерфейс.

Следующий код отслеживает свойства NetworkInterface для каждого интерфейса на клиентском компьютере.

package { 
import flash.display.Sprite; 
import flash.net.InterfaceAddress; 
import flash.net.NetworkInfo; 
import flash.net.NetworkInterface; 
 
public class NetworkInformationExample extends Sprite 
{ 
    public function NetworkInformationExample() 
    { 
        var networkInfo:NetworkInfo = NetworkInfo.networkInfo; 
        var interfaces:Vector.<NetworkInterface> = networkInfo.findInterfaces(); 
         
        if( interfaces != null ) 
        { 
            trace( "Interface count: " + interfaces.length ); 
            for each ( var interfaceObj:NetworkInterface in interfaces ) 
            { 
                trace( "\nname: "             + interfaceObj.name ); 
                trace( "display name: "     + interfaceObj.displayName ); 
                trace( "mtu: "                 + interfaceObj.mtu ); 
                trace( "active?: "             + interfaceObj.active ); 
                trace( "parent interface: " + interfaceObj.parent ); 
                trace( "hardware address: " + interfaceObj.hardwareAddress ); 
                if( interfaceObj.subInterfaces != null ) 
                { 
                    trace( "# subinterfaces: " + interfaceObj.subInterfaces.length ); 
                } 
                trace("# addresses: "     + interfaceObj.addresses.length ); 
                for each ( var address:InterfaceAddress in interfaceObj.addresses ) 
                { 
                    trace( "  type: "           + address.ipVersion ); 
                    trace( "  address: "         + address.address ); 
                    trace( "  broadcast: "         + address.broadcast ); 
                    trace( "  prefix length: "     + address.prefixLength ); 
                } 
            }             
        } 
    }     
} 
}

Дополнительные сведения см. в разделе:

• NetworkInfo

• NetworkInterface

• InterfaceAddress

• Flexpert: определение типа сетевого подключения с помощью Flex 4.5

Приложение AIR может работать в средах с нестабильными или переменчивыми условиями сетевого подключения. Чтобы приложение могло управлять подключением к интернет-ресурсам, Adobe AIR отправляет событие изменения сетевого состояния, когда подключение становится доступно или наоборот недоступно. Объект NetworkInfo, как и объект приложения NativeApplication, отправляет событие networkChange . Чтобы отвечать на это событие, добавьте прослушиватель:

NetworkInfo.networkInfo.addEventListener(Event.NETWORK_CHANGE, onNetworkChange); 

Также нужно определить функцию обработчика события:

function onNetworkChange(event:Event) 
{ 
    //Check resource availability 
} 

Событие networkChange говорит не об изменении сетевой активности в целом, а лишь о том, что изменилось отдельное подключение к сети. AIR не предпринимает попыток интерпретировать характер изменения. Компьютер, подключенный к сети, может иметь множество реальных и виртуальных подключений, поэтому разрыв соединения не всегда означат перекрытие доступа к ресурсу. С другой стороны, новые подключения не гарантируют лучшей доступности ресурса. Порой новое соединение может даже заблокировать доступ к ранее доступным ресурсам (например, при подключении к VPN).

В целом, единственным способом определить возможность подключения к удаленному ресурсу является практическая проверка. Инфраструктура мониторинга служб предоставляет основанные на событиях средства для реагирования на изменения сетевых подключений к определенному хосту.

Поиск записей ресурсов DNS можно выполнять с помощью класса DNSResolver. Записи ресурсов DNS предоставляют такую информацию, как IP-адрес доменного имени и доменное имя IP-адреса. Можно выполнять поиск следующих записей ресурсов DNS:

• ARecord — IPv4-адрес для хоста;

• AAAARecord — IPv6-адрес для хоста;

• MXRecord — запись почтового обменника для хоста;

• PTRRecord — имя хоста для IP-адреса.

• SRVRecord — запись службы для службы..

Чтобы найти запись, необходимо передать методу lookup() объекта DNSResolver строку запроса и объекта класса, представляющего тип записи. Строка запроса варьируется в зависимости от типа записи.

Следующий пример выполняет поиск IP-адреса для хоста example.com.

package 
{ 
    import flash.display.Sprite; 
    import flash.events.DNSResolverEvent; 
    import flash.events.ErrorEvent; 
    import flash.net.dns.ARecord; 
    import flash.net.dns.DNSResolver; 
 
    public class DNSResolverExample extends Sprite 
    { 
         
        public function DNSResolverExample() 
        { 
            var resolver:DNSResolver = new DNSResolver(); 
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete ); 
            resolver.addEventListener( ErrorEvent.ERROR, lookupError ); 
 
            resolver.lookup( "example.com.", ARecord ); 
        } 
         
        private function lookupComplete( event:DNSResolverEvent ):void 
        { 
            trace( "Query string: " + event.host ); 
            trace( "Record count: " + event.resourceRecords.length ); 
            for each( var record:* in event.resourceRecords ) 
            { 
                if( record is ARecord ) trace( record.address ); 
            } 
             
        } 
 
        private function lookupError( error:ErrorEvent ):void 
        { 
            trace("Error: " + error.text ); 
        } 
    } 
}

Дополнительные сведения см. в разделе:

• DNSResolver

• DNSResolverEvent

• ARecord

• AAAARecord

• MXRecord

• PTRRecord

• SRVRecord