Значки панели задач AIR

В стандартное меню дока можно добавить команды, создав объект NativeMenu, содержащий эти команды, и присвоив его свойству NativeApplication.nativeApplication.icon.menu . Добавленные пункты меню отображаются поверх стандартных пунктов меню значков дока.

Подпрыгивание значка дока достигается при помощи метода NativeApplication.nativeApplication.icon.bounce() . Если для параметра bounce() priority задано значение informational, значок прыгает один раз. Если для него задано значение critical, значок прыгает до тех пор, пока пользователь не активирует приложение. Константы для параметра priority определены в классе NotificationType.

При нажатии на значок дока объект NativeApplication отправляет событие invoke . Если приложение еще не запущено, система запускает его. В противном случае событие invoke отправляется экземпляру выполняющегося приложения.

Можно добавить меню к значку области уведомлений, создав объект NativeMenu и присвоив его свойству NativeApplication.nativeApplication.icon.menu (операционная система не предоставляет меню по умолчанию). Доступ к меню значка области уведомлений осуществляется щелчком правой кнопки мыши.

Можно добавить к значку всплывающую подсказку, задав свойство tooltip:

NativeApplication.nativeApplication.icon.tooltip = "Application name"; 

Объект SystemTrayIcon, на который указывает свойство NativeApplication.nativeApplication.icon, отправляет ScreenMouseEvent для событий click , mouseDown , mouseUp , rightClick , rightMouseDown и rightMouseUp . Эти события, а также меню значков, позволяют пользователям взаимодействовать с приложением при отсутствии его видимых окон.

Следующий пример создает приложение AIR, которое имеет значки в области уведомлений, но не имеет видимых окон. (Для свойства visible приложения не должно быть установлено значение true в дескрипторе приложения; в противном случае окно будет видимо при запуске приложения.)

package 
{ 
    import flash.display.Loader; 
    import flash.display.NativeMenu; 
    import flash.display.NativeMenuItem; 
    import flash.display.NativeWindow; 
    import flash.display.Sprite; 
    import flash.desktop.DockIcon; 
    import flash.desktop.SystemTrayIcon; 
    import flash.events.Event; 
    import flash.net.URLRequest; 
    import flash.desktop.NativeApplication; 
 
    public class SysTrayApp extends Sprite 
    { 
        public function SysTrayApp():void{ 
            NativeApplication.nativeApplication.autoExit = false; 
            var icon:Loader = new Loader(); 
            var iconMenu:NativeMenu = new NativeMenu(); 
            var exitCommand:NativeMenuItem = iconMenu.addItem(new NativeMenuItem("Exit")); 
                exitCommand.addEventListener(Event.SELECT, function(event:Event):void { 
                    NativeApplication.nativeApplication.icon.bitmaps = []; 
                    NativeApplication.nativeApplication.exit(); 
                }); 
 
            if (NativeApplication.supportsSystemTrayIcon) { 
                NativeApplication.nativeApplication.autoExit = false; 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE, iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_16.png")); 
                 
                var systray:SystemTrayIcon =  
                    NativeApplication.nativeApplication.icon as SystemTrayIcon; 
                systray.tooltip = "AIR application"; 
                systray.menu = iconMenu; 
            } 
 
            if (NativeApplication.supportsDockIcon){ 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE,iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_128.png")); 
                var dock:DockIcon = NativeApplication.nativeApplication.icon as DockIcon;  
                dock.menu = iconMenu; 
            } 
        } 
         
        private function iconLoadComplete(event:Event):void 
        { 
            NativeApplication.nativeApplication.icon.bitmaps = 
                [event.target.content.bitmapData]; 
        } 
    } 
} 

Если окно открыто в фоновом режиме, можно уведомить пользователя о том, что произошло ожидаемое событие, связанное с окном. В Mac OS X оповещение пользователя может осуществляться за счет прыгающего значка приложения в доке (как описано в разделе Оповещения дока ). В Windows и Linux можно подсветить кнопку окна на панели задач, вызвав метод notifyUser() экземпляра NativeWindow. Параметр type , передаваемый этому методу, определяет срочность оповещения:

• NotificationType.CRITICAL : значок окна мигает до тех пор, пока пользователь не активирует окно.

• NotificationType.INFORMATIONAL : значок окна подсвечивается, изменяя цвет.

  Примечание. В Linux поддерживается только информационный тип уведомлений. Передача значения любого типа в функцию notifyUser() создаст точно такой же эффект.

  Следующее выражение подсвечивает кнопку окна на панели задач:

  stage.nativeWindow.notifyUser(NotificationType.CRITICAL); 

  Вызов метода NativeWindow.notifyUser() в операционной системе, не поддерживающей оповещение на уровне окон, не действует. При помощи свойства NativeWindow.supportsNotification можно определить, поддерживается ли оповещение на уровне окон.

В операционной системе Windows окна типов utility или lightweight не отображаются на панели задач. Невидимые окна также не отображаются на панели задач.

Поскольку начальное окно всегда относится к типу normal , для создания приложения, окна которого не должны отображаться на панели задач, необходимо либо закрыть исходное окно, либо сделать его невидимым. Чтобы закрыть все окна приложения, не завершая работу самого приложения, задайте для свойства autoExit объекта NativeApplication значение false перед закрытием последнего окна. Чтобы сделать начальное окно постоянно невидимым, вставьте <visible>false</visible> в элемент <initalWindow> файла дескриптора приложения (не задавайте для свойства visible значение true и не вызывайте метод activate() окна).

Для новых окон, открытых в приложении, установите свойство type объекта NativeWindowInitOption, передаваемого конструктору окна, на значение NativeWindowType.UTILITY или NativeWindowType.LIGHTWEIGHT .

В Mac OS X свернутые окна отображаются на панели задач дока. Чтобы значок свернутого окна не отображался, рекомендуется скрыть окно, а не сворачивать его. Следующий пример прослушивает событие изменения nativeWindowDisplayState и отменяет его при сворачивании окна. Вместо этого обработчик задает для свойства visible значение false :

private function preventMinimize(event:NativeWindowDisplayStateEvent):void{ 
    if(event.afterDisplayState == NativeWindowDisplayState.MINIMIZED){ 
        event.preventDefault(); 
        event.target.visible = false; 
    } 
} 

При сворачивании окна в док Mac OS X при установке свойства visible на значение false значок дока не удаляется. Пользователь может щелкнуть значок, чтобы снова отобразить окно.