Работа с объектами File в AIR

Класс File имеет целый ряд применений:

• Получение путей к определенным каталогам, включая каталог пользователей, каталог документов пользователей, каталог запуска приложения и каталог самого приложения.

• Копирование файлов и каталогов

• Перемещение файлов и каталогов

• Удаление файлов и каталогов (или перемещение в корзину)

• Составление списка файлов и каталогов внутри каталога

• Создание временных файлов и папок

Объект File, указывающий путь к файлу, можно использовать для чтения и записи данных с помощью класса FileStream.

Объект File может указывать путь к еще не существующему файлу или каталогу. В этом случае этот объект можно использовать для создания файла или каталога.

У каждого объекта File есть два свойства, определяющие его путь:

Класс File включает в себя статические свойства для указания на стандартные каталоги в ОС Mac OS, Windows и Linux. К таким свойствам относятся:

В различных операционных системах эти свойства имеют разные значения. Например, в ОС Mac и Windows собственные пути к каталогу рабочего стола пользователя различаются. Однако свойство File.desktopDirectory указывает соответствующий путь к каталогу на каждой платформе. При создании приложений для работы на различных платформах используйте эти свойства как основу для указания на другие каталоги и файлы, используемые приложением. Затем используйте метод resolvePath() для коррекции пути. Например, данный код указывает на файл preferences.xml в каталоге хранилища приложения:

var prefsFile:File = File.applicationStorageDirectory; 
prefsFile = prefsFile.resolvePath("preferences.xml");

Хотя класс File позволяет указывать определенный путь к файлу, он может привести к приложениям, которые не могут работать на разных платформах. Например, путь C:\Documents and Settings\joe\ работает только в ОС Windows. По этим причинам лучше использовать статические свойства класса File, такие как File.documentsDirectory .

Фактические собственные пути к этим каталогам варьируются в зависимости от операционной системы и конфигурации компьютера. Пути, показанные в данной таблице, являются типовыми примерами. При ссылке на эти каталоги всегда следует использовать соответствующие статические свойства класса File. В приложении AIR значения свойств applicationID и filename , приведенные в таблице, взяты из дескриптора приложения. Если в дескрипторе приложения указано свойство publisher ID, идентификатор издателя будет добавлен к идентификатору приложения в этих путях. Значением свойства userName является имя учетной записи пользователя, выполняющего установку.

Существует ряд способов настроить объект File так, чтобы он указывал на каталог.

Существует несколько способов задания файла, на который указывает объект File.

Путь к существующему объекту File можно изменить, вызвав метод resolvePath() или изменив свойство nativePath или url объекта, как показано ниже (для Windows):

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
trace(file1.nativePath); // C:\Documents and Settings\userName\My Documents\AIR Test 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath(".."); 
trace(file2.nativePath); // C:\Documents and Settings\userName 
var file3:File = File.documentsDirectory; 
file3.nativePath += "/subdirectory"; 
trace(file3.nativePath); // C:\Documents and Settings\userName\My Documents\subdirectory 
var file4:File = new File(); 
file4.url = "file:///c:/AIR Test/test.txt"; 
trace(file4.nativePath); // C:\AIR Test\test.txt 

При использовании свойства nativePath в качестве разделителя пути к файлу используйте переднюю косую черту (/). В Windows можно также использовать обратную косую черту (\), но при этом приложение может не работать на других платформах.

В AIR для определения свойства url объекта File могут использоваться следующие схемы URL-адресов.

file:///c:/AIR Test/test.txt

app:/images

app-storage:/settings/prefs.xml

Некоторые операционные системы, в частности, iOS и Mac OS X, имеют возможность автоматического резервного копирования файлов приложений на удаленное хранилище. Кроме того, в iOS существуют определенные правила, касающиеся резервного копирования и мест хранения файлов с различным назначением.

Ниже приведен краткий обзор этих правил — рекомендаций Apple в отношении резервного копирования и хранения файлов. Дополнительная информация приведена в следующих разделах.

• Если файл не подлежит резервному копированию и (только в iOS) может быть удален операционной системой при сокращении свободного места на устройстве, его следует сохранить в каталог кэша ( File.cacheDirectory ). Этот каталог является предпочтительным местом хранения файлов на iOS, его следует использовать для большинства файлов, которые могут быть созданы или загружены заново.

• Если файл не подлежит резервному копированию, но также не подлежит удалению операционной системой, его следует сохранить в один их каталогов библиотеки приложений, например в каталог хранилища приложений ( File.applicationStorageDirectory ) или в каталог документов ( File.documentsDirectory ). Свойство preventBackup такого объекта File следует задать как true . Таковы рекомендации Apple в отношении содержимого, которое можно восстановить или загрузить заново, но которое необходимо для правильной работы приложения в автономном режиме.

Метод getRelativePath() может использоваться для нахождения пути к одному файлу относительно другого:

var file1:File = File.documentsDirectory.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
 
trace(file1.getRelativePath(file2)); // bob/test.txt 

Второй параметр метода getRelativePath() — useDotDot — позволяет возвращать синтаксис .. для определения родительских каталогов:

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
var file3:File = File.documentsDirectory; 
file3 = file3.resolvePath("AIR Test/susan/test.txt"); 
 
trace(file2.getRelativePath(file1, true)); // ../.. 
trace(file3.getRelativePath(file2, true)); // ../../bob/test.txt 

Имена файлов и пути к ним в Windows и Mac OS не учитывают регистр. В примере ниже два объекта File указывают на один и тот же файл:

File.documentsDirectory.resolvePath("test.txt"); 
File.documentsDirectory.resolvePath("TeSt.TxT");

Однако в именах документов и каталогов используются заглавные буквы. Так, в примерах ниже мы исходим из того, что в каталоге документов существует некая папка с названием AIR Test:

var file:File = File.documentsDirectory.resolvePath("AIR test"); 
trace(file.nativePath); // ... AIR test 
file.canonicalize(); 
trace(file.nativePath); // ... AIR Test 

Метод canonicalize() преобразует объект nativePath так, чтобы в имени файла или каталога использовался правильный регистр. В файловых системах, чувствительных к регистру (таких как Linux), если существует несколько файлов, имена которых различаются только регистрами, метод canonicalize() настраивает путь для первого найденного файла (в порядке, определяемом файловой системой).

Метод canonicalize() также можно использовать для преобразования коротких имен файлов (имен «8.3») в длинные имена в Windows, как показано ниже:

var path:File = new File(); 
path.nativePath = "C:\\AIR~1"; 
path.canonicalize(); 
trace(path.nativePath); // C:\AIR Test

Разные операционные системы поддерживают пакетные файлы и файлы символьных ссылок:

Пакеты . В Mac OS каталог может быть назначен пакетом и в этом случае будет отображаться в файловом менеджере Mac OS Finder как единый файл, а не как каталог.

Символьные ссылки . Символьные ссылки поддерживаются в Mac OS, Linux и Windows Vista. С помощью символьных ссылок один файл может ссылаться на другой файл или каталог на диске. Не путайте символьные ссылки с псевдонимами. Псевдонимы всегда считаются файлами (не каталогами), а чтение или запись псевдонимов и ярлыков никаким образом не изменяет файлы, на которые они указывают. Символьная ссылка, в свою очередь, повторяет поведение файла или каталога, на который она указывает. Она может считаться файлом или каталогом, а при чтении и записи символьной ссылки изменения будут производиться над самим файлом, на который она указывает, а не над ссылкой. Кроме того, в Windows для свойства isSymbolicLink объекта File, ссылающегося на узловой пункт (используется в файловой системе NTFS), устанавливается значение true .

Класс File включает свойства isPackage и isSymbolicLink , позволяющие проверить, ссылается ли объект File на пакет или символьную ссылку.

В приведенном ниже коде каталог рабочего стола просматривается и создается список подкаталогов, не являющихся пакетами:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isDirectory && !desktopNodes[i].isPackage) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

В приведенном ниже коде просматривается каталог рабочего стола и создается список файлов и каталогов, не являющихся символьными ссылками:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (!desktopNodes[i].isSymbolicLink) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

Метод canonicalize() изменяет путь к символьной ссылке, так чтобы он указывал на файл или каталог, на который она ссылается. В приведенном ниже коде просматривается каталог рабочего стола пользователя и выводятся пути, на которые ссылаются файлы, являющиеся символьными ссылками:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isSymbolicLink) 
    { 
        var linkNode:File = desktopNodes[i] as File; 
        linkNode.canonicalize(); 
        trace(linkNode.nativePath); 
    } 
} 

Свойство spaceAvailable объекта File указывает на количество свободного места в расположении объекта File в байтах. Например, в приведенном ниже коде проверяется свободное место в каталоге хранилища приложения.

trace(File.applicationStorageDirectory.spaceAvailable); 

Если объект File ссылается на каталог, свойство spaceAvailable указывает объем свободного места, доступного для использования файлом. Если объект File ссылается на файл, свойство spaceAvailable обозначает объем, который потенциально может занять файл. Если расположения файла не существует, свойство spaceAvailable принимает значение 0. Если объект File ссылается на символьную ссылку, свойство spaceAvailable означает свободный объем в том месте, на которое указывает символьная ссылка.

Как правило, объем, который потенциально может занять файл, равен свободному объему всего тома, на котором содержится файл или каталог. Тем не менее при подсчете свободного места могут учитываться квоты и ограничения на каждый каталог.

При добавлении к тому файла или каталога, как правило, требуется чуть больше места, чем сам размер файла или каталога. Например, операционной системе может потребоваться больше места для хранения индексов. Либо секторы дисков могут задействовать дополнительное место. Кроме того, объем свободного места изменяется динамически. Поэтому не следует ожидать, что вы сможете использовать все заявленное свободное место. Сведения о записи в файловую систему см. в разделе « Чтение и запись файлов ».

Метод StorageVolumeInfo.getStorageVolumes() предоставляет дополнительные сведения о подключенных томах запоминающих устройств (см. раздел « Работа с томами запоминающих устройств »).

В AIR 2 можно открыть файл с помощью программы, зарегистрированной в операционной системе для его открытия. Например, приложение AIR может открыть DOC-файл с помощью программы, которая зарегистрирована для его открытия. Используйте метод openWithDefaultApplication() объекта File для открытия файла. Например, следующий код открывает файл test.doc на рабочем столе пользователя с помощью программы, выбранной по умолчанию для файлов DOC:

var file:File = File.deskopDirectory; 
file = file.resolvePath("test.doc"); 
file.openWithDefaultApplication();

Следующий код дает пользователю возможность перейти к mp3-файлу и открыть его в приложении, которое выбрано по умолчанию для воспроизведения mp3-файлов:

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Метод openWithDefaultApplication() нельзя использовать по отношению к файлам, расположенным в каталоге приложения.

AIR не позволяет применять метод openWithDefaultApplication() для открытия ряда файлов. В Windows AIR запрещает открывать файлы определенных типов (например, EXE или BAT). В ОС Mac OS и Linux среда AIR предотвращает открытие файлов в определенном приложении. (Включая приложения «Терминал» и AppletLauncher в ОС Mac OS и csh, bash или ruby в ОС Linux.) Попытка открыть один из этих файлов с помощью метода openWithDefaultApplication() приводит к появлению исключения. Полный список запрещаемых типов файлов см. в записи справочника по языку для метода File.openWithDefaultApplication() .