Управление окнами

Для управления окном необходимо сначала получить экземпляр окна. Экземпляр окна можно получить следующим образом:

• Для создания окна используется конструктор класса NativeWindow.

  var win:NativeWindow = new NativeWindow(initOptions);

• Свойство nativeWindow рабочей области окна.

  var win:NativeWindow = stage.nativeWindow;

• Свойство stage объекта display в окне.

  var win:NativeWindow = displayObject.stage.nativeWindow;

• Свойство target события NativeWindow, размещенного в окне.

  private function onNativeWindowEvent(event:NativeWindowBoundsEvent):void 
  { 
      var win:NativeWindow = event.target as NativeWindow; 
  }

• Свойство nativeWindow для страницы HTML, отображаемой в окне.

  var win:NativeWindow = htmlLoader.window.nativeWindow;

• Свойства activeWindow и openedWindows объекта NativeApplication.

  var nativeWin:NativeWindow = NativeApplication.nativeApplication.activeWindow; 
  var firstWindow:NativeWindow = NativeApplication.nativeApplication.openedWindows[0];

  NativeApplication.nativeApplication.activeWindow содержит ссылку на активное окно приложения (но возвращает null , если активное окно не является окном данного приложения AIR). Массив NativeApplication.nativeApplication.openedWindows содержит все окна приложения AIR, которые не были закрыты.

Поскольку объекты Flex mx:WindowedApplication и mx:Window являются экранными объектами, можно легко создать ссылку на окно приложения в MXML-файле при помощи свойства stage , как показано ниже:

<?xml version="1.0" encoding="utf-8"?> 
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" applicationComplete="init();"> 
    <mx:Script> 
        <![CDATA[ 
            import flash.display.NativeWindow; 
 
            public function init():void{ 
                var appWindow:NativeWindow = this.stage.nativeWindow; 
                //set window properties 
                appWindow.visible = true; 
            } 
        ]]> 
    </mx:Script> 
</WindowedApplication

Для активации окна необходимо вызвать метод NativeWindow activate() . Активация окна переносит его на передний план, окно получает фокус клавиатуры и мыши и при необходимости становится видимым за счет восстановления или присвоения свойству visible значения true . Активация окна не меняет порядок других окон в приложении. При вызове метода activate() окно отправляет событие activate .

Для отображения скрытого окна без его активации задайте для свойства visible значение true . При этом окно переходит на передний план, но не получает фокус.

Чтобы скрыть окно, задайте для свойства visible значение false . Скрывание окна подавляет отображение как самого окна, так и соответствующих значков панели задач, а также, в Mac OS X, входа в меню Windows.

При изменении видимости окна видимость всех остальных окон, также изменяется. Например, если окно было скрыто, все принадлежащие ему окна также скрываются.

AIR предоставляет несколько методов прямого изменения порядка отображения окон. Можно переместить окно в начало или конец порядка отображения, поверх другого окна или за него. В то же время пользователь может изменить порядок окон путем их активации.

Чтобы окно всегда отображалось поверх других окон, необходимо задать для свойства alwaysInFront значение true . Если такую настройку имеют несколько окон, то между ними происходит отдельная сортировка порядка отображения, но они всегда будут отображаться поверх окон, свойство alwaysInFront которых имеет значение false.

Окна, занимающие верхние позиции в порядке отображения, также отображаются поверх окон других приложений, даже если приложение AIR неактивно. Поскольку такое поведение может мешать пользователю, задание для свойства alwaysInFront значения true должно быть оправдано. Примерами оправданного использования такой настройки являются следующие:

• Временные всплывающие окна элементов управления, например подсказки, раскрывающиеся списки, пользовательские меню или комбинированные окна. Поскольку эти окна закрываются, когда теряют фокус, они не загораживают другие окна и не представляют помехи для пользователя.

• Сверхважные сообщения об ошибках и уведомления. Выдвижение окна уведомления на передний план оправдано, если в случае несвоевременной реакции пользователя может произойти неисправимое изменение. Однако большинство ошибок и уведомлений могут обрабатываться в обычном порядке отображения окон.

• Кратковременные всплывающие в системном лотке уведомления.

Если окно является владельцем других окон, эти окна всегда располагаются перед ним. Если для окна, которое является владельцем других окон, вызывается метод orderToFront() или для свойства alwaysInFront устанавливается значение true , порядок подчиненных окон изменяется: окно-владелец располагается перед другими окнами, но подчиненные окна по-прежнему отображаются перед окном-владельцем.

Вызов методов изменения порядка окон для подчиненных окон действует обычным образом для окон, которые имеют одного владельца, но также при этом может изменяться порядок всей группы подчиненных окон относительно окон, не входящих в данную группу. Например, при вызове метода orderToFront() для подчиненного окна данное окно, его владелец и любые другие окна, которые принадлежат тому же владельцу, перемещаются на передний план.

Класс NativeWindow содержит следующие свойства и методы для установки порядка отображения окон:

В операционной системе Linux различные диспетчеры окон реализуют различные правила в отношении порядка отображения окон:

• В некоторых таких диспетчерах окна служебных программ всегда отображаются поверх нормальных окон.

• В некоторых диспетчерах окон полноэкранные окна, в которых для свойства alwaysInFront установлено значение true , всегда отображаются поверх других окон, которые также имеют в свойстве alwaysInFront значение true .

Чтобы закрыть окно, используйте метод NativeWindow.close() .

При закрытии окна выгружается его содержимое, но если другие объекты содержат ссылку на это содержимое, такие объекты содержимого не будут разрушены. Метод NativeWindow.close() выполняется асинхронно, в процессе закрытия приложение, содержащееся в окне, продолжает работать. Метод close отправляет событие close по завершении операции закрытия. Объект NativeWindow остается технически действующим, но при попытке получить доступ к большинству свойств и методов при закрытом окне выдается ошибка IllegalOperationError. Закрытое окно нельзя снова открыть. Чтобы проверить, закрыто ли окно, нужно обратиться к свойству closed окна. Если требуется просто скрыть окно, установите свойство NativeWindow.visible на значение false .

Если свойство Nativeapplication.autoExit имеет значение true , которое является значением по умолчанию, то приложение закрывается при закрытии последнего окна.

Все окна, которые имеют владельца, закрываются при закрытии окна-владельца. Подчиненные окна не отправляют событие closing и, соответственно, не могут предотвратить закрытие. Отправляется событие закрытия.

Если окно использует системный Chrome, действия с окном, совершаемые пользователем, можно отменить, прослушав и отменив поведение по умолчанию соответствующих событий. Например, при нажатии пользователем кнопки закрытия на системном Chrome отправляется событие closing . Если какой-либо зарегистрированный прослушиватель вызывает метод preventDefault() события, окно не закрывается.

Если окно не использует системный Chrome, перед изменением уведомляющие об этих изменениях события не отправляются автоматически. Следовательно, при вызове методов для закрытия окна, изменения состояния окна или при задании свойств границ окна такое изменение невозможно отменить. Для уведомления компонентов приложения о предстоящих изменениях окна логикой приложения может быть предусмотрена отправка соответствующего уведомляющего события при помощи метода dispatchEvent() окна.

Например, следующая логика реализует отменяемый обработчик событий, вызванных кнопкой закрытия окна:

public function onCloseCommand(event:MouseEvent):void{ 
    var closingEvent:Event = new Event(Event.CLOSING,true,true); 
    dispatchEvent(closing); 
    if(!closingEvent.isDefaultPrevented()){ 
        win.close(); 
    } 
} 

Метод dispatchEvent() возвращает false , если прослушиватель вызывает метод события preventDefault() . Однако этот метод может возвращать значение false и по другим причинам, поэтому рекомендуется использовать метод isDefaultPrevented() явным образом, чтобы проверить, действительно ли отменяется изменение.

Чтобы развернуть окно, используйте метод NativeWindow maximize() .

myWindow.maximize(); 

Чтобы свернуть окно, используйте метод NativeWindow minimize() .

myWindow.minimize(); 

Чтобы восстановить окно (т. е. восстановить его размер до сворачивания или разворачивания), используйте метод NativeWindow restore() .

myWindow.restore(); 

Окно, которое имеет владельца, сворачивается и восстанавливается при минимизации и восстановлении окна-владельца. При сворачивании подчиненное окно не отправляет никаких событий, так как сворачивается его владелец.

В операционной системе Linux различные диспетчеры окон реализуют различные правила в отношении установки состояния отображения окон:

• В некоторых диспетчерах окон нельзя развернуть до максимального размера окна служебных программ.

• Если для окна задан максимальный размер, то некоторые окна не позволяют окну развернуться до максимального размера. Некоторые другие диспетчеры окон устанавливают максимальное состояние отображения, но не изменяют размер окна. В любом из случаев событие изменения состояния отображения отправляться не будет.

• Некоторые диспетчеры окон не учитывают параметры окон maximizable или minimizable .

Следующее небольшое MXML-приложение иллюстрирует методы maximize() , minimize() , restore() и close() окна:

<?xml version="1.0" encoding="utf-8"?> 
 
<mx:WindowedApplication  
    xmlns:mx="http://www.adobe.com/2006/mxml"  
    layout="vertical"> 
     
     
    <mx:Script> 
    <![CDATA[ 
    public function minimizeWindow():void 
    { 
        this.stage.nativeWindow.minimize(); 
    } 
 
    public function maximizeWindow():void 
    { 
        this.stage.nativeWindow.maximize(); 
    }           
     
    public function restoreWindow():void 
    { 
        this.stage.nativeWindow.restore(); 
    }           
 
    public function closeWindow():void 
    { 
        this.stage.nativeWindow.close(); 
    } 
    ]]> 
    </mx:Script> 
 
    <mx:VBox> 
        <mx:Button label="Minimize" click="minimizeWindow()"/> 
        <mx:Button label="Restore" click="restoreWindow()"/> 
        <mx:Button label="Maximize" click="maximizeWindow()"/> 
        <mx:Button label="Close" click="closeWindow()"/> 
    </mx:VBox> 
 
</mx:WindowedApplication>

Следующий пример сценария ActionScript для Flash создает четыре гипертекстовых поля, инициирующих методы NativeWindow minimize() , maximize() , restore() и close() :

package 
{ 
    import flash.display.Sprite; 
    import flash.events.MouseEvent; 
    import flash.text.TextField; 
     
    public class MinimizeExample extends Sprite 
    { 
        public function MinimizeExample():void  
        { 
            var minTextBtn:TextField = new TextField(); 
            minTextBtn.x = 10; 
            minTextBtn.y = 10; 
            minTextBtn.text = "Minimize"; 
            minTextBtn.background = true; 
            minTextBtn.border = true; 
            minTextBtn.selectable = false; 
            addChild(minTextBtn); 
            minTextBtn.addEventListener(MouseEvent.CLICK, onMinimize); 
         
            var maxTextBtn:TextField = new TextField(); 
            maxTextBtn.x = 120; 
            maxTextBtn.y = 10; 
            maxTextBtn.text = "Maximize"; 
            maxTextBtn.background = true; 
            maxTextBtn.border = true; 
            maxTextBtn.selectable = false; 
            addChild(maxTextBtn); 
            maxTextBtn.addEventListener(MouseEvent.CLICK, onMaximize); 
         
            var restoreTextBtn:TextField = new TextField(); 
            restoreTextBtn.x = 230; 
            restoreTextBtn.y = 10; 
            restoreTextBtn.text = "Restore"; 
            restoreTextBtn.background = true; 
            restoreTextBtn.border = true; 
            restoreTextBtn.selectable = false; 
            addChild(restoreTextBtn); 
            restoreTextBtn.addEventListener(MouseEvent.CLICK, onRestore); 
             
            var closeTextBtn:TextField = new TextField(); 
            closeTextBtn.x = 340; 
            closeTextBtn.y = 10; 
            closeTextBtn.text = "Close Window"; 
            closeTextBtn.background = true; 
            closeTextBtn.border = true; 
            closeTextBtn.selectable = false; 
            addChild(closeTextBtn); 
            closeTextBtn.addEventListener(MouseEvent.CLICK, onCloseWindow); 
        } 
        function onMinimize(event:MouseEvent):void 
        { 
            this.stage.nativeWindow.minimize(); 
        } 
        function onMaximize(event:MouseEvent):void 
        { 
            this.stage.nativeWindow.maximize(); 
        } 
        function onRestore(event:MouseEvent):void 
        { 
            this.stage.nativeWindow.restore(); 
        } 
        function onCloseWindow(event:MouseEvent):void 
        { 
            this.stage.nativeWindow.close(); 
        } 
    } 
}

Если окно использует системный Chrome, то Chrome предоставляет элементы управления изменением размера окна и его перемещением на рабочем столе. Если окно не использует системный Chrome, необходимо добавить собственные элементы управления, при помощи которых пользователь может изменять размер окна и перемещать его.

Следующий пример иллюстрирует инициацию операций изменения размера и перемещения окна:

package 
{ 
    import flash.display.Sprite; 
    import flash.events.MouseEvent; 
    import flash.display.NativeWindowResize; 
 
    public class NativeWindowResizeExample extends Sprite 
    { 
        public function NativeWindowResizeExample():void 
        { 
            // Fills a background area. 
            this.graphics.beginFill(0xFFFFFF); 
            this.graphics.drawRect(0, 0, 400, 300); 
            this.graphics.endFill(); 
     
            // Creates a square area where a mouse down will start the resize. 
            var resizeHandle:Sprite =  
                createSprite(0xCCCCCC, 20, this.width - 20, this.height - 20); 
            resizeHandle.addEventListener(MouseEvent.MOUSE_DOWN, onStartResize); 
     
            // Creates a square area where a mouse down will start the move. 
            var moveHandle:Sprite = createSprite(0xCCCCCC, 20, this.width - 20, 0); 
            moveHandle.addEventListener(MouseEvent.MOUSE_DOWN, onStartMove); 
        } 
     
        public function createSprite(color:int, size:int, x:int, y:int):Sprite 
        { 
            var s:Sprite = new Sprite(); 
            s.graphics.beginFill(color); 
            s.graphics.drawRect(0, 0, size, size); 
            s.graphics.endFill(); 
            s.x = x; 
            s.y = y; 
            this.addChild(s);     
            return s;         
        } 
     
        public function onStartResize(event:MouseEvent):void 
        { 
            this.stage.nativeWindow.startResize(NativeWindowResize.BOTTOM_RIGHT); 
        } 
 
        public function onStartMove(event:MouseEvent):void 
        { 
            this.stage.nativeWindow.startMove(); 
        } 
    } 
}