Работа с инструкциями SQL

Создайте экземпляр SQLStatement.

Объект SQLStatement представляет инструкцию SQL в вашем приложении.

var selectData:SQLStatement = new SQLStatement(); 

Укажите базу данных, в отношении которой выполняется запрос.

Для этого задайте для свойства sqlConnection объекта SQLStatement экземпляр SQLConnection, подключенный к нужной базе данных.

// A SQLConnection named "conn" has been created previously 
selectData.sqlConnection = conn;

Укажите саму инструкцию SQL.

Создайте текст инструкции в виде строки и присвойте его свойству text экземпляра SQLStatement.

selectData.text = "SELECT col1, col2 FROM my_table WHERE col1 = :param1";

Определите функции для обработки результата операции execute (только для режима асинхронного выполнения).

При помощи метода addEventListener() зарегистрируйте функции в качестве прослушивателей событий result и error экземпляра SQLStatement.

// using listener methods and addEventListener() 
     
selectData.addEventListener(SQLEvent.RESULT, resultHandler); 
selectData.addEventListener(SQLErrorEvent.ERROR, errorHandler); 
     
function resultHandler(event:SQLEvent):void 
{ 
    // do something after the statement execution succeeds 
} 
     
function errorHandler(event:SQLErrorEvent):void 
{ 
    // do something after the statement execution fails 
} 

Вместо этого можно задать методы прослушивателей с использованием объекта Responder. В таком случае нужно создать экземпляр Responder и связать с ним методы прослушивателей.

// using a Responder (flash.net.Responder) 
     
var selectResponder = new Responder(onResult, onError); 
     
function onResult(result:SQLResult):void 
{ 
    // do something after the statement execution succeeds 
} 
     
function onError(error:SQLError):void 
{ 
    // do something after the statement execution fails 
} 

Если текст инструкции содержит определения параметров, присвойте значения этим параметрам.

Для присвоения значений параметрам используйте свойство ассоциативного массива parameters экземпляра SQLStatement.

selectData.parameters[":param1"] = 25;

Выполните инструкцию SQL.

Вызовите метод execute() экземпляра SQLStatement.

// using synchronous execution mode 
// or listener methods in asynchronous execution mode 
selectData.execute();

Более того, если вы используете Responder вместо прослушивателей событий в режиме асинхронного выполнения, передайте экземпляр Responder методу execute().

// using a Responder in asynchronous execution mode 
selectData.execute(-1, selectResponder);

Конкретные примеры, иллюстрирующие выполнение этих шагов, см. в разделах:

Извлечение данных из базы данных

 Вставка данных

 Изменение или удаление данных