Работа со списком отображения

Объект можно добавить в объект DisplayObjectContainer, вызвав метод addChild() или addChildAt() для контейнера. Если контейнером является рабочая область, добавить объект в список отображения можно в ходе разработки: для этого его нужно создать или, если это компонент, перетащить в рабочую область с панели «Компоненты». Чтобы добавить объект в контейнер с помощью ActionScript, сначала создайте его экземпляр, вызвав конструктор с оператором new , а после этого вызовите метод addChild() или addChildAt() , чтобы поместить его в рабочую область и в список отображения. Метод addChild() помещает объект в следующую позицию списка отображения, а addChildAt() задает позицию, в которую требуется добавить объект. Если указать позицию, которая уже занята другим объектом, этот объект и все находящиеся над ним перемещаются на одну позицию вверх. Свойство numChildren объекта DisplayObjectContainer содержит число экранных объектов, содержащихся в контейнере. Чтобы извлечь объект из списка отображения, вызовите метод getChildAt() и укажите позицию, а если известно имя объекта, вызовите метод getChildByName() .

В следующем примере отображаются имена и позиции трех компонентов в списке отображения. Сначала перетащите компоненты NumericStepper, Button и ComboBox в рабочую область так, чтобы они пересекались друг с другом и присвойте их экземплярам имена aNs , aButton и aCb . Затем добавьте следующий код на панель «Действия» в кадре 1 временной шкалы:

var i:int = 0; 
while(i < numChildren) { 
    trace(getChildAt(i).name + " is at position: " + i++); 
}

На панели вывода должны появится следующие строки.

aNs is at position: 0 
aButton is at position: 1 
aCb is at position: 2

Можно изменить позицию объекта в списке отображения и его глубину отображения с помощью метода addChildAt() , указав в качестве параметров имя объекта и позицию, в которую его требуется добавить. Например, добавьте следующий код к предыдущему примеру, чтобы первым отображался компонент NumericStepper и повторите цикл, чтобы показать новые позиции компонентов в списке отображения.

this.addChildAt(aNs, numChildren - 1); 
i = 0; 
while(i < numChildren) { 
    trace(getChildAt(i).name + " is at position: " + i++); 
}

На панели вывода должны появится следующие строки.

aNs is at position: 0 
aButton is at position: 1 
aCb is at position: 2 
aButton is at position: 0 
aCb is at position: 1 
aNs is at position: 2

Кроме того, экземпляр NumericStepper должен появится перед остальными компонентами на экране.

Обратите внимание, что свойство numChildren представляет количество объектов (от 1 до n ) в списке отображения, а порядковые номера объектов отсчитываются от 0. Поэтому если в списке отображения содержится три объекта, то третий объект будет занимать в индексе позицию 2. Это означает, что позиция последнего объекта в списке отображения, или верхнего объекта с точки зрения глубины, вычисляется как numChildren — 1 .

Удалить компонент их контейнера экранных объектов и его списка отображения можно с помощью методов removeChild() и removeChildAt() . В следующем примере в рабочую область добавляется три экземпляра Button, один перед другим, а также по одному прослушивателю событий для каждого из них. При щелчке по каждой кнопке обработчик события удаляет ее из списка отображения и с рабочей области.

1. Создайте новый файл Flash (ActionScript 3.0).

2. Перетащите компонент Button с панели «Компоненты» на панель «Библиотека».

3. Откройте панель «Действия», выберите «Кадр 1» на главной временной шкале и введите следующий код.

   import fl.controls.Button; 
    
   var i:int = 0; 
   while(i++ < 3) { 
       makeButton(i); 
   } 
   function removeButton(event:MouseEvent):void { 
       removeChildAt(numChildren -1); 
   } 
   function makeButton(num) { 
       var aButton:Button = new Button(); 
       aButton.name = "Button" + num; 
       aButton.label = aButton.name; 
       aButton.move(200, 200); 
       addChild(aButton); 
       aButton.addEventListener(MouseEvent.CLICK, removeButton); 
   }

   Полное описание списка отображения см. в разделе «Программирование отображаемого содержимого» руководства Программирование на ActionScript 3.0 .