Использование компонента Slider

Когда экземпляр Slider получает фокус, им можно управлять с помощью следующих клавиш.

Дополнительные сведения об управлении фокусом см. в описании интерфейса IFocusManager и класса FocusManager в справочнике ActionScript® 3.0 для Adobe® Flash® Professional CS5 и разделе « Работа с FocusManager ».

Интерактивный просмотр каждого элемента Slider отражает изменения, которые были внесены в параметры в Инспекторе свойств или Инспекторе компонентов во время разработки.

В Инспекторе свойств или Инспекторе компонентов можно задать следующие параметры разработки для каждого экземпляра компонента Slider: direction , liveDragging , maximum , minimum , snapInterval , tickInterval и value . Каждый из этих параметров имеет соответствующее свойство ActionScript с тем же именем. Сведения о возможных значениях этих параметров см. в описании класса Slider в справочнике ActionScript® 3.0 для Adobe® Flash® Professional CS5 .

В следующем примере создается экземпляр Slider, чтобы пользователь мог сообщить, насколько ему понравилось предполагаемое событие. Пользователь перемещает экземпляр Slider вправо или влево, чтобы выразить большую или меньшую степень удовлетворения.

1. Создайте новый документ Flash (ActionScript 3.0).

2. Перетащите компонент Label с панели «Компоненты» в центр рабочей области.

   • Присвойте ему имя экземпляра valueLabel .

   • Задайте значение 0 % для параметра text .

3. Перетащите компонент Slider с панели «Компоненты» и поместите его под экземпляром value_lbl .

   • Присвойте ему имя экземпляра aSlider .

   • Введите 200 для значения ширины (W).

   • Введите 10 для значения высоты (H).

   • Задайте значение 100 параметру maximum .

   • Задайте значение 10 параметрам snapInterval и tickInterval .

4. Перетащите еще один экземпляр Label с панели «Библиотека» прямо под aSlider.

   • Присвойте ему имя экземпляра promptLabel.

   • Введите 250 для значения ширины (W).

   • Введите 22 для значения высоты (H).

   • Введите значение Насколько вам понравилось для параметра text .

5. Откройте панель «Действия», выберите «Кадр 1» на главной временной шкале и введите следующий код ActionScript.

   import fl.controls.Slider; 
   import fl.events.SliderEvent; 
   import fl.controls.Label; 
    
   aSlider.addEventListener(SliderEvent.CHANGE, changeHandler); 
    
   function changeHandler(event:SliderEvent):void { 
       valueLabel.text = event.value + "percent";     
   }

6. Выберите «Управление» > «Тестировать ролик».

   В этом примере при перемещении ползунка от одного интервала к другому прослушиватель события SliderEvent.CHANGE обновляет свойство text экземпляра valueLabel , отображая процент, соответствующий позиции ползунка.

В следующем примере компонент Slider создается с помощью ActionScript. Загружается изображение цветка, и с помощью экземпляра Slider пользователю предоставляется возможность сделать его более насыщенным или более прозрачным путем изменения свойства alpha в соответствии с позицией ползунка.

1. Создайте новый документ Flash (ActionScript 3.0).

2. Перетащите компоненты Label и Slider с панели «Компоненты» на панель «Библиотека» текущего документа.

   В результате этого компоненты добавляются в библиотеку, но остаются невидимым в приложении.

3. Откройте панель «Действия», выберите Кадр 1 на основной временной шкале и введите следующий код, чтобы создать и разместить экземпляры компонентов:

   import fl.controls.Slider; 
   import fl.events.SliderEvent; 
   import fl.controls.Label; 
   import fl.containers.UILoader; 
    
   var sliderLabel:Label = new Label(); 
   sliderLabel.width = 120; 
   sliderLabel.text = "< Fade - Brighten >"; 
   sliderLabel.move(170, 350); 
    
   var aSlider:Slider = new Slider(); 
   aSlider.width = 200; 
   aSlider.snapInterval = 10; 
   aSlider.tickInterval = 10; 
   aSlider.maximum = 100; 
   aSlider.value = 100; 
   aSlider.move(120, 330); 
    
   var aLoader:UILoader = new UILoader(); 
   aLoader.source = "http://www.flash-mx.com/images/image1.jpg"; 
   aLoader.scaleContent = false; 
    
   addChild(sliderLabel); 
   addChild(aSlider); 
   addChild(aLoader); 
    
   aLoader.addEventListener(Event.COMPLETE, completeHandler); 
    
   function completeHandler(event:Event) { 
       trace("Number of bytes loaded: " + aLoader.bytesLoaded); 
   } 
    
   aSlider.addEventListener(SliderEvent.CHANGE, changeHandler); 
    
   function changeHandler(event:SliderEvent):void { 
           aLoader.alpha = event.value * .01; 
   }

4. Для запуска приложения выберите команды «Управление» > «Тестировать ролик».

5. Переместите ползунок экземпляра Slider влево, чтобы сделать изображение прозрачнее, или вправо, чтобы оно стало более насыщенным.