Comportamentos de isolamento

Isole eventos como o Event.ENTER_FRAME em um manipulador único, quando possível.

O código pode ser otimizado ainda mais pelo isolamento do evento Event.ENTER_FRAME na classe Apple em um único manipulador. Esta técnica economiza recursos de CPU. O exemplo a seguir mostra esta aproximação diferente, onde a classe BitmapApple não manipula mais o comportamento do movimento:

package org.bytearray.bitmap 
{ 
    import flash.display.Bitmap; 
    import flash.display.BitmapData; 
     
    public class BitmapApple extends Bitmap 
    { 
        private var destinationX:Number; 
        private var destinationY:Number; 
         
        public function BitmapApple(buffer:BitmapData) 
        { 
            super (buffer); 
             
            smoothing = true; 
        } 
}

O código a seguir instancia as maçãs e manipula seu movimento em um único manipulador:

import org.bytearray.bitmap.BitmapApple; 
 
const MAX_NUM:int = 100; 
var holder:Sprite = new Sprite(); 
 
addChild(holder); 
 
var holderVector:Vector.<BitmapApple> = new Vector.<BitmapApple>(MAX_NUM, true); 
var source:AppleSource = new AppleSource(); 
var bounds:Object = source.getBounds(source); 
     
var mat:Matrix = new Matrix(); 
mat.translate(-bounds.x,-bounds.y); 
 
stage.quality = StageQuality.BEST; 
 
var buffer:BitmapData = new BitmapData(source.width+1,source.height+1, true,0); 
buffer.draw(source,mat); 
 
stage.quality = StageQuality.LOW; 
     
var bitmapApple:BitmapApple; 
     
for (var i:int = 0; i< MAX_NUM; i++) 
{ 
    bitmapApple = new BitmapApple(buffer); 
     
    bitmapApple.destinationX = Math.random()*stage.stageWidth; 
    bitmapApple.destinationY = Math.random()*stage.stageHeight; 
     
    holderVector[i] = bitmapApple; 
         
    holder.addChild(bitmapApple); 
} 
 
stage.addEventListener(Event.ENTER_FRAME,onFrame); 
 
var lng:int = holderVector.length 
 
function onFrame(e:Event):void 
{     
        for (var i:int = 0; i < lng; i++) 
        { 
            bitmapApple = holderVector[i]; 
            bitmapApple.alpha = Math.random(); 
             
            bitmapApple.x -= (bitmapApple.x - bitmapApple.destinationX) *.5; 
            bitmapApple.y -= (bitmapApple.y - bitmapApple.destinationY) *.5; 
             
            if (Math.abs(bitmapApple.x - bitmapApple.destinationX ) < 1 &&      
                Math.abs(bitmapApple.y - bitmapApple.destinationY ) < 1) 
            { 
                    bitmapApple.destinationX = Math.random()*stage.stageWidth; 
                    bitmapApple.destinationY = Math.random()*stage.stageHeight; 
            } 
        } 
}

O resultado é um único evento Event.ENTER_FRAME manipulando o movimento, em vez de 200 manipuladores movendo cada maçã. Toda a animação pode ser facilmente pausada, o que pode ser útil em um jogo.

Por exemplo, um jogo simples pode usar o seguinte manipulador:

stage.addEventListener(Event.ENTER_FRAME, updateGame); 
function updateGame (e:Event):void 
{ 
    gameEngine.update(); 
}

A próxima etapa é fazer com que as maçãs interajam com o mouse ou o teclado, o que requer modificações na classe BitmapApple .

package org.bytearray.bitmap 
{ 
    import flash.display.Bitmap; 
    import flash.display.BitmapData; 
    import flash.display.Sprite; 
     
    public class BitmapApple extends Sprite 
    { 
        public var destinationX:Number; 
        public var destinationY:Number; 
        private var container:Sprite; 
        private var containerBitmap:Bitmap; 
         
        public function BitmapApple(buffer:BitmapData) 
        { 
            container = new Sprite(); 
            containerBitmap = new Bitmap(buffer); 
            containerBitmap.smoothing = true; 
            container.addChild(containerBitmap); 
            addChild(container); 
        } 
}

O resultado são instâncias interativas de BitmapApple , como objetos Sprite tradicionais. No entanto, as instâncias são vinculadas a um único bitmap, que não é amostrado novamente quando os objetos de exibição são transformados.