Métodos para usar expressões regulares com strings

O método test() da classe RegExp verifica simplesmente a string fornecida para ver se ela contém uma correspondência para a expressão regular, como mostra o exemplo a seguir:

var pattern:RegExp = /Class-\w/; 
var str = "Class-A"; 
trace(pattern.test(str)); // output: true

O método exec() da classe RegExp verifica a string fornecida quanto a uma correspondência da expressão regular e retorna uma matriz com o seguinte:

• A substring de correspondência

• Correspondência de substring para qualquer grupo entre parênteses na expressão regular

A matriz também inclui uma propriedade index , indicando a posição de índice do início da correspondência de substring.

Por exemplo, considere o seguinte código:

var pattern:RegExp = /\d{3}\-\d{3}-\d{4}/; //U.S phone number 
var str:String = "phone: 415-555-1212"; 
var result:Array = pattern.exec(str); 
trace(result.index, " - ", result); 
// 7-415-555-1212

Use o método exec() várias vezes para corresponder várias substrings quando o sinalizador g ( global ) está definido para uma expressão regular:

var pattern:RegExp = /\w*sh\w*/gi; 
var str:String = "She sells seashells by the seashore"; 
var result:Array = pattern.exec(str); 
     
while (result != null) 
{ 
    trace(result.index, "\t", pattern.lastIndex, "\t", result); 
    result = pattern.exec(str); 
} 
//output:  
// 0      3      She 
// 10      19      seashells 
// 27      35      seashore

Os seguintes métodos da classe String usam as expressões regulares como parâmetros: match() , replace() , search() e split() . Para obter mais informações sobre esses métodos, consulte Localização de padrões em sequências de caracteres e substituição de subsequências de caracteres .