Exemplo XML no ActionScript: carregamento de dados RSS da Web

A classe RSSParser inclui um método xmlLoaded() que converte os dados RSS de entrada, armazenados na variável rssXML, em uma string que contém a saída em formato HTML, rssOutput.

Logo do início do método, o código define o namespace XML padrão se os dados RSS de origem incluírem um namespace padrão:

if (rssXML.namespace("") != undefined) 
{ 
    default xml namespace = rssXML.namespace(""); 
}

As próximas linhas percorrem o conteúdo dos dados XML de origem, examinando cada propriedade de descendente chamada item:

for each (var item:XML in rssXML..item) 
{ 
    var itemTitle:String = item.title.toString(); 
    var itemDescription:String = item.description.toString(); 
    var itemLink:String = item.link.toString(); 
    outXML += buildItemHTML(itemTitle,  
                            itemDescription, 
                            itemLink); 
}

As três primeiras linhas simplesmente definem variáveis de string para representar as propriedades de título, descrição e link da propriedade item dos dados XML. Em seguida, a próxima linha chama o método buildItemHTML() para obter os dados HTML em forma de um objeto XMLList, usando as três novas variáveis de string como parâmetros.

Os dados HTML (um objeto XMLList) têm uma das seguintes formas:

<b>itemTitle</b> 
<p> 
    itemDescription 
    <br /> 
    <a href="link"> 
        <font color="#008000">More...</font> 
    </a> 
</p>

As primeiras linhas do método apagam o namespace XML padrão:

default xml namespace = new Namespace();

A diretiva de namespace XML padrão tem o escopo do nível de bloqueio da função. Isso significa que os escopo dessa instrução é o método buildItemHTML().

As próximas linhas montam o XMLList, com base nos argumentos de string transmitidos para a função:

var body:XMLList = new XMLList(); 
body += new XML("<b>" + itemTitle + "</b>"); 
var p:XML = new XML("<p>" + itemDescription + "</p>"); 
 
var link:XML = <a></a>; 
link.@href = itemLink; // <link href="itemLinkString"></link> 
link.font.@color = "#008000";  
        // <font color="#008000"></font></a> 
        // 0x008000 = green 
link.font = "More..."; 
 
p.appendChild(<br/>);  
p.appendChild(link);  
body += p;

Esse objeto XMLList representa dados de string adequados para um campo de texto HTML do ActionScript.

O método xmlLoaded() usa o valor de retorno do método buildItemHTML() e o converte em uma string:

XML.prettyPrinting = false; 
rssOutput = outXML.toXMLString();    

O método xmlLoaded() define uma variável de string rssTitle, com base nas informações dos dados XML RSS de origem:

rssTitle = rssXML.channel.title.toString();

Finalmente, o método xmlLoaded() gera um evento, que informa ao aplicativo que os dados estão analisados e disponíveis:

            dataWritten = new Event("dataWritten", true);