Montagem e transformação de objetos XML

Flash Player 9 e posterior, Adobe AIR 1.0 e posterior

Use o método prependChild() ou o método appendChild() para adicionar uma propriedade ao início ou ao final de uma lista de propriedades do objeto XML, como mostra o exemplo a seguir:

var x1:XML = <p>Line 1</p>  
var x2:XML = <p>Line 2</p>  
var x:XML = <body></body> 
x = x.appendChild(x1); 
x = x.appendChild(x2); 
x = x.prependChild(<p>Line 0</p>); 
    // x == <body><p>Line 0</p><p>Line 1</p><p>Line 2</p></body>

Use o método insertChildBefore() ou o método insertChildAfter() para adicionar uma propriedade antes ou depois de uma propriedade especificada, do seguinte modo:

var x:XML =  
    <body> 
        <p>Paragraph 1</p>  
        <p>Paragraph 2</p> 
    </body> 
var newNode:XML = <p>Paragraph 1.5</p>  
x = x.insertChildAfter(x.p[0], newNode) 
x = x.insertChildBefore(x.p[2], <p>Paragraph 1.75</p>)

Como mostra o exemplo a seguir, você também pode usar os operadores de chaves ( { e } ) para possar dados por referência (de outras variáveis) ao criar objetos XML:

var ids:Array = [121, 122, 123];  
var names:Array = [["Murphy","Pat"], ["Thibaut","Jean"], ["Smith","Vijay"]] 
var x:XML = new XML("<employeeList></employeeList>"); 
 
for (var i:int = 0; i < 3; i++) 
{ 
    var newnode:XML = new XML();  
    newnode = 
        <employee id={ids[i]}> 
            <last>{names[i][0]}</last> 
            <first>{names[i][1]}</first> 
        </employee>; 
 
    x = x.appendChild(newnode) 
}

É possível atribuir propriedades e atributos a um objeto XML usando o operador =, conforme mostrado a seguir:

var x:XML =  
    <employee> 
        <lastname>Smith</lastname> 
    </employee> 
x.firstname = "Jean"; 
x.@id = "239";

Isso define o objeto XML x como:

<employee id="239"> 
    <lastname>Smith</lastname> 
    <firstname>Jean</firstname> 
</employee>

Você pode usar os operadores + e += para concatenar objetos XMLList:

var x1:XML = <a>test1</a>  
var x2:XML = <b>test2</b>  
var xList:XMLList = x1 + x2; 
xList += <c>test3</c>

Isso define o objeto XMLList xList como:

<a>test1</a> 
<b>test2</b> 
<c>test3</c>