Exemplo de clipe de filme: RuntimeAssetsExplorer

Para que o explorador interaja adequadamente com uma biblioteca SWF, a estrutura das bibliotecas de ativos de tempo de execução deve ser formalizada. Faremos isso criando uma interface, que é semelhante a uma classe pois trata-se de um projeto de métodos que demarca uma estrutura esperada, mas, diferentemente de uma classe, não inclui nenhum corpo de método. A interface fornece um meio de comunicação ente a biblioteca de tempo de execução e o explorador. Cada SWF de ativos de tempo de execução que for carregado em nosso navegador implementará essa interface. Para obter informações sobre interfaces e como elas podem ser úteis, consulte Interfaces em Aprendizado do ActionScript 3.0 .

A interface RuntimeLibrary será bem simples: precisamos apenas de uma função que forneça ao explorador uma matriz de caminhos de classe para os símbolos a serem exportados e disponibilizados na biblioteca de tempo de execução. Para esse fim, a interface possui um único método: getAssets() .

package com.example.programmingas3.runtimeassetexplorer 
{ 
    public interface RuntimeLibrary 
    { 
        function getAssets():Array; 
    } 
}

Ao definir a interface RuntimeLibrary, é possível criar vários arquivos SWF de biblioteca de ativos que podem ser carregados em outro arquivo SWF. A criação de uma biblioteca SWF individual de ativos envolve quatro tarefas:

• Criação de uma classe para o arquivo SWF da biblioteca de ativos

• Criação de classes para ativos individuais contidos na biblioteca

• Criação dos ativos gráficos em si

• Associação de elementos gráficos a classes e publicação do SWF da biblioteca

package 
{ 
    import flash.display.Sprite; 
    import com.example.programmingas3.runtimeassetexplorer.RuntimeLibrary; 
     
    public class GeometricAssets extends Sprite implements RuntimeLibrary  
    { 
        public function GeometricAssets() { 
             
        } 
        public function getAssets():Array { 
            return [ "com.example.programmingas3.runtimeassetexplorer.AnimatingBox", 
                     "com.example.programmingas3.runtimeassetexplorer.AnimatingStar" ];     
        } 
    } 
}

package com.example.programmingas3.runtimeassetexplorer 
{ 
    import flash.display.MovieClip; 
     
    public class AnimatingStar extends MovieClip 
    { 
        public function AnimatingStar() { 
        } 
    } 
}

A última questão funcional a ser resolvida é a interface do usuário para o explorador de ativos. Neste exemplo, o caminho para a biblioteca de tempo de execução é codificado como uma variável chamada ASSETS_PATH . Se preferir, você pode usar a classe FileReference, por exemplo, para criar uma interface que navegue para um arquivo SWF específico do seu disco rígido.

Quando a biblioteca de tempo de execução é carregada com êxito, o Flash Player chama o método runtimeAssetsLoadComplete() :

private function runtimeAssetsLoadComplete(event:Event):void 
{ 
    var rl:* = event.target.content; 
    var assetList:Array = rl.getAssets(); 
    populateDropdown(assetList); 
    stage.frameRate = 60; 
}

Nesse método, a variável rl representa o arquivo SWF carregado. O código chama o método getAssets() do arquivo SWF carregado, obtendo uma lista de ativos que estão disponíveis e os usa para preencher um componente ComboBox com uma lista de ativos disponíveis, chamando o método populateDropDown() . Esse método por sua vez armazena o caminho de classe completo de cada ativo. Ao ser clicado, o botão Adicionar da interface do usuário dispara o método addAsset() :

private function addAsset():void 
{ 
    var className:String = assetNameCbo.selectedItem.data; 
    var AssetClass:Class = getDefinitionByName(className) as Class; 
    var mc:MovieClip = new AssetClass(); 
    ... 
}

que obtém o caminho de classe do ativo atualmente selecionado no ComboBox ( assetNameCbo.selectedItem.data ) e usa a função getDefinitionByName() (do pacote flash.utils) para obter uma referência real para a classe do ativo a fim de criar uma nova ocorrência desse ativo.