Objetos compartilhados

Os objetos compartilhados funcionam como os cookies do navegador. Utilize a classe SharedObject para armazenar dados no disco rígido local do usuário e chamar dados durante a mesma sessão ou em uma sessão posterior. Os aplicativos podem acessar apenas seus próprios dados SharedObject, e somente quando executam no mesmo domínio. Os dados não foram enviados ao servidor e não estão acessíveis por outros aplicativos em execução nos outros domínios, mas podem tornar-se acessíveis por aplicativos do mesmo domínio.

Para criar um objeto SharedObject utilize o método SharedObject.getLocal() , que possui a sintaxe a seguir:

SharedObject.getLocal("objectName" [, pathname]): SharedObject

O exemplo a seguir cria um objeto compartilhado denominado mySO:

public var mySO:SharedObject; 
mySO = SharedObject.getLocal("preferences");

Isso cria um arquivo na máquina do cliente denominado preferences.sol.

O termo local faz referência ao local do objeto compartilhado. Nesse caso, o Adobe® Flash® Player armazena o arquivo SharedObject localmente no diretório base do cliente.

Quando você cria um objeto compartilhado, o Flash Player cria um novo diretório para o aplicativo e o domínio dentro da sua caixa de proteção. Cria, também, um arquivo *.sol que armazena os dados do SharedObject. O local padrão desse arquivo é um subdiretório no diretório base do usuário. A tabela a seguir apresenta os locais padrão desse diretório:

c:/Documents and Settings/username/Application Data/Macromedia/Flash Player/#SharedObjects

c:/Users/username/AppData/Roaming/Macromedia/Flash Player/#SharedObjects

/Users/username/Library/Preferences/Macromedia/Flash Player/#SharedObjects/web_domain/path_to_application/application_name/object_name.sol

/home/username/.macromedia/Flash_Player/#SharedObjects/web_domain/path_to_application/application_name/object_name.sol

Abaixo do diretório #SharedObjects, está um diretório nomeado randomicamente. Abaixo desse diretório, vem um diretório que corresponde ao nome do host, em seguida, o caminho para o aplicativo e, finalmente, o arquivo *.sol.

Por exemplo, se você solicitar um aplicativo denominado MyApp.swf no host local, dentro de um subdiretório denominado /sos, o Flash Player armazenará o arquivo *.sol no seguinte local (no Windows XP):

c:/Documents and Settings/fred/Application Data/Macromedia/Flash Player/#SharedObjects/KROKWXRK/#localhost/sos/MyApp.swf/data.sol

Por padrão, o Flash pode salvar objetos SharedObject persistentes de até 100 KB por domínio. Esse valor pode ser configurado pelo usuário. Quando o aplicativo tenta salvar dados para um objeto compartilhado que ultrapassariam 100 KB, o Flash Player exibe a caixa de diálogo Armazenamento local, oferecendo a opção ao usuário de permitir ou negar o armazenamento local para o domínio que está solicitando o acesso.

Ao criar um SharedObject remoto ou local usando getLocal() ou getRemote() , há um parâmetro opcional denominado secure que determina se o acesso a esse objeto compartilhado é restrito para arquivos SWF que são entregues por uma conexão HTTPS. Se esse parâmetro estiver definido como true e o arquivo SWF for entregue por HTTPS, o Flash Player criará um novo objeto compartilhado protegido ou obterá uma referência a um objeto compartilhado protegido existente. Esse objeto compartilhado protegido pode ser lido ou gravado apenas por arquivos SWF entregues por HTTPS que chamam SharedObject.getLocal() com o parâmetro secure definido como true . Se esse parâmetro estiver definido como false e o arquivo SWF for entregue por HTTPS, o Flash Player criará um novo objeto compartilhado ou obterá uma referência a um objeto compartilhado existente.

Esse objeto compartilhado pode ser lido ou gravado por arquivos SWF entregues por conexões não HTTPS. Se o arquivo SWF for entregue por uma conexão não HTTPS e você tentar definir esse parâmetro como true , haverá uma falha na criação de um novo objeto compartilhado (ou o acesso de um objeto compartilhado protegido criado anteriormente), um erro será emitido e o objeto compartilhado será definido como null . Se você tentar executar o seguinte snippet em uma conexão não HTTPS, o método SharedObject.getLocal() emitirá um erro:

try 
{ 
    var so:SharedObject = SharedObject.getLocal("contactManager", null, true); 
} 
catch (error:Error) 
{ 
    trace("Unable to create SharedObject."); 
}

Independentemente do valor desse parâmetro, os objetos compartilhados criados serão levados em consideração na contagem da quantidade total de espaço em disco permitida para um domínio.

Os valores são armazenados em objetos compartilhados dentro da propriedade data . Você pode executar um loop em cada valor dentro de uma ocorrência do objeto compartilhado usando um loop for..in , conforme mostrado no exemplo a seguir:

var so:SharedObject = SharedObject.getLocal("test"); 
so.data.hello = "world"; 
so.data.foo = "bar"; 
so.data.timezone = new Date().timezoneOffset; 
for (var i:String in so.data) 
{ 
    trace(i + ":\t" + so.data[i]); 
}

Para destruir um SharedObject no cliente, use o método SharedObject.clear() . Isso não destruirá os diretórios no caminho padrão dos objetos compartilhados do aplicativo.

O exemplo a seguir exclui o arquivo SharedObject do cliente:

public function destroySharedObject():void { 
    mySO.clear(); 
}

O exemplo a seguir demonstra que é possível armazenar objetos simples como, por exemplo, Date em um objeto SharedObject sem a necessidade de serializar e desserializar esses objetos.

Este exemplo inicia dando boas-vindas a você pela sua primeira visita. Assim que você clicar em Log Out, o aplicativo armazenará a data atual em um objeto compartilhado. Na próxima vez que iniciar o aplicativo ou atualizar a página, o aplicativo dará boas-vindas pelo seu retorno, com um lembrete sobre o tempo em que esteve desconectado.

Para ver o aplicativo em ação, inicie o aplicativo, clique em Log Out e atualize a página. O aplicativo exibirá a data e hora em que você clicou no botão Log Out na visita anterior. A qualquer momento, é possível excluir as informações armazenadas clicando no botão Excluir LSO.

<?xml version="1.0"?> 
<!-- lsos/WelcomeMessage.mxml --> 
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" initialize="initApp()"> 
  <mx:Script><![CDATA[ 
  public var mySO:SharedObject; 
  [Bindable] 
  public var welcomeMessage:String; 
 
  public function initApp():void { 
     mySO = SharedObject.getLocal("mydata"); 
     if (mySO.data.visitDate==null) { 
        welcomeMessage = "Hello first-timer!" 
     } else { 
        welcomeMessage = "Welcome back. You last visited on " + 
           getVisitDate(); 
     } 
  } 
 
  private function getVisitDate():Date { 
     return mySO.data.visitDate; 
  } 
 
  private function storeDate():void { 
     mySO.data.visitDate = new Date(); 
     mySO.flush(); 
  } 
  
  private function deleteLSO():void { 
     // Deletes the SharedObject from the client machine. 
     // Next time they log in, they will be a 'first-timer'. 
     mySO.clear(); 
  } 
  
  ]]></mx:Script> 
  <mx:Label id="label1" text="{welcomeMessage}"/> 
  <mx:Button label="Log Out" click="storeDate()"/> 
  <mx:Button label="Delete LSO" click="deleteLSO()"/> 
</mx:Application>