Noções básicas de rede e comunicação

Você pode usar o objeto NetworkInfo para detectar as interfaces de rede de hardware e software à disposição do seu aplicativo. O objeto NetworkInfo é um objeto singleton, e você não precisa criá-lo. Em vez disso, use a propriedade estática de classe networkInfo para acessar o único objeto NetworkInfo. Além disso, o objeto NetworkInfo gera um evento networkChange quando uma das interfaces disponíveis mudar.

Chame o método findInterfaces() para obter uma lista de objetos NetworkInterface. Cada objeto NetworkInterface da lista descreve uma das interfaces disponíveis. O objeto NetworkInterface fornece informações, tais como o endereço IP, endereço de hardware, unidade máxima de transmissão e se a interface está ativa.

O exemplo de código a seguir rastreia as propriedades do NetworkInterface de cada interface no computador cliente:

package { 
import flash.display.Sprite; 
import flash.net.InterfaceAddress; 
import flash.net.NetworkInfo; 
import flash.net.NetworkInterface; 
 
public class NetworkInformationExample extends Sprite 
{ 
    public function NetworkInformationExample() 
    { 
        var networkInfo:NetworkInfo = NetworkInfo.networkInfo; 
        var interfaces:Vector.<NetworkInterface> = networkInfo.findInterfaces(); 
         
        if( interfaces != null ) 
        { 
            trace( "Interface count: " + interfaces.length ); 
            for each ( var interfaceObj:NetworkInterface in interfaces ) 
            { 
                trace( "\nname: "             + interfaceObj.name ); 
                trace( "display name: "     + interfaceObj.displayName ); 
                trace( "mtu: "                 + interfaceObj.mtu ); 
                trace( "active?: "             + interfaceObj.active ); 
                trace( "parent interface: " + interfaceObj.parent ); 
                trace( "hardware address: " + interfaceObj.hardwareAddress ); 
                if( interfaceObj.subInterfaces != null ) 
                { 
                    trace( "# subinterfaces: " + interfaceObj.subInterfaces.length ); 
                } 
                trace("# addresses: "     + interfaceObj.addresses.length ); 
                for each ( var address:InterfaceAddress in interfaceObj.addresses ) 
                { 
                    trace( "  type: "           + address.ipVersion ); 
                    trace( "  address: "         + address.address ); 
                    trace( "  broadcast: "         + address.broadcast ); 
                    trace( "  prefix length: "     + address.prefixLength ); 
                } 
            }             
        } 
    }     
} 
}

Para obter mais informações, consulte:

• NetworkInfo

• NetworkInterface

• InterfaceAddress

Seu aplicativo AIR pode ser executado em ambientes com conectividade de rede incerta e em mudança. Para ajudar um aplicativo a gerenciar conexões em recursos on-line, o Adobe AIR envia um evento de mudança de rede sempre que uma conexão de rede se torna disponível ou indisponível. O objeto NetworkInfo e o objeto NativeApplication do aplicativo geram o evento networkChange. Para reagir a esse evento, adicione um ouvinte:

NetworkInfo.networkInfo.addEventListener(Event.NETWORK_CHANGE, onNetworkChange); 

E defina uma função do manipulador de eventos:

function onNetworkChange(event:Event) 
{ 
    //Check resource availability 
} 

O evento networkChange não indica uma mudança em toda a atividade de rede, mas apenas que uma conexão de rede individual sofreu mudança. O AIR não tenta interpretar o significado da mudança de rede. Um computador em rede pode ter várias conexões reais e virtuais, portanto, perder uma conexão não significa necessariamente perder um recurso. Por outro lado, novas conexões também não garantem melhor disponibilidade de recursos. Às vezes uma nova conexão pode até bloquear o acesso a recursos anteriormente disponíveis (por exemplo, ao se conectar a uma VPN).

Em geral, a única maneira de um aplicativo determinar se ele pode se conectar a um recurso remoto é por tentativa. A estrutura de monitoramento de serviço é um meio, com base em eventos, de reagir a mudanças na conectividade de rede de um host específico.

Você pode consultar os registros do recurso de DNS através da classe DNSResolver. Os registros do recurso de DNS geram informações como o endereço IP de um nome de domínio e o nome de domínio de um endereço IP. Você pode consultar os seguintes tipos de registros do recurso de DNS:

• ARecord—endereço IPv4 de um host.

• AAAARecord—endereço IPv6 de um host.

• MXRecord—registro de troca de email de um host.

• PTRRecord—nome de host de um endereço IP.

• SRVRecord—registro de um serviço.

Para consultar um registro, transmita uma sequência de caracteres de consulta e o objeto de classe que representa o tipo de registro ao método lookup() do objeto DNSResolver. A sequência de caracteres de consulta a ser usada depende do tipo de registro:

O seguinte exemplo de código consulta o endereço IP do host “example.com”.

package 
{ 
    import flash.display.Sprite; 
    import flash.events.DNSResolverEvent; 
    import flash.events.ErrorEvent; 
    import flash.net.dns.ARecord; 
    import flash.net.dns.DNSResolver; 
 
    public class DNSResolverExample extends Sprite 
    { 
         
        public function DNSResolverExample() 
        { 
            var resolver:DNSResolver = new DNSResolver(); 
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete ); 
            resolver.addEventListener( ErrorEvent.ERROR, lookupError ); 
 
            resolver.lookup( "example.com.", ARecord ); 
        } 
         
        private function lookupComplete( event:DNSResolverEvent ):void 
        { 
            trace( "Query string: " + event.host ); 
            trace( "Record count: " + event.resourceRecords.length ); 
            for each( var record:* in event.resourceRecords ) 
            { 
                if( record is ARecord ) trace( record.address ); 
            } 
             
        } 
 
        private function lookupError( error:ErrorEvent ):void 
        { 
            trace("Error: " + error.text ); 
        } 
    } 
}

Para obter mais informações, consulte:

• DNSResolver

• DNSResolverEvent

• ARecord

• AAAARecord

• MXRecord

• PTRRecord

• SRVRecord