Ícones da barra de tarefas no AIR

É possível adicionar comandos ao menu de encaixe padrão criando um objeto NativeMenu que contenha os comandos e atribuindo o objeto à propriedade NativeApplication.nativeApplication.icon.menu . Os itens do menu são exibidos acima dos itens padrão do menu com ícones no encaixe.

É possível fazer com que o ícone no encaixe pule chamando o método NativeApplication.nativeApplication.icon.bounce() . Se você definir o parâmetro bounce() priority como informativo, o ícone pulará uma vez. Se você definir o parâmetro como crítico, o ícone pulará até o usuário ativar o aplicativo. As constantes do parâmetro priority são definidas na classe NotificationType.

Quando o usuário clica em um ícone no encaixe, o objeto NativeApplication despacha um evento invoke . Se o aplicativo não estiver em execução, será iniciado pelo sistema. Caso contrário, o evento invoke será entregue à ocorrência do aplicativo em execução.

É possível adicionar um menu ao ícone da bandeja do sistema criando-se um objeto NativeMenu e o atribuindo à propriedade NativeApplication.nativeApplication.icon.menu (o sistema operacional não oferece um menu padrão). Acesse o menu do ícone da bandeja do sistema clicando no ícone com o botão direito do mouse.

Adicione uma dica de ferramenta a um ícone definindo a propriedade tooltip:

NativeApplication.nativeApplication.icon.tooltip = "Application name"; 

O objeto SystemTrayIcon referenciado pela propriedade NativeApplication.nativeApplication.icon despacha um ScreenMouseEvent para eventos click , mouseDown , mouseUp , rightClick , rightMouseDown e rightMouseUp . Você pode usar esses eventos, junto com um menu de ícone, para que os usuários possam interagir com seu aplicativo quando ele não tiver janelas visíveis.

O exemplo a seguir cria um aplicativo do AIR que tem um ícone na bandeja do sistema, mas nenhuma janela visível. (A propriedade visible do aplicativo não deve ser definida como true no descrito do aplicativo, ou a janela será visível quando o aplicativo for iniciado.)

package 
{ 
    import flash.display.Loader; 
    import flash.display.NativeMenu; 
    import flash.display.NativeMenuItem; 
    import flash.display.NativeWindow; 
    import flash.display.Sprite; 
    import flash.desktop.DockIcon; 
    import flash.desktop.SystemTrayIcon; 
    import flash.events.Event; 
    import flash.net.URLRequest; 
    import flash.desktop.NativeApplication; 
 
    public class SysTrayApp extends Sprite 
    { 
        public function SysTrayApp():void{ 
            NativeApplication.nativeApplication.autoExit = false; 
            var icon:Loader = new Loader(); 
            var iconMenu:NativeMenu = new NativeMenu(); 
            var exitCommand:NativeMenuItem = iconMenu.addItem(new NativeMenuItem("Exit")); 
                exitCommand.addEventListener(Event.SELECT, function(event:Event):void { 
                    NativeApplication.nativeApplication.icon.bitmaps = []; 
                    NativeApplication.nativeApplication.exit(); 
                }); 
 
            if (NativeApplication.supportsSystemTrayIcon) { 
                NativeApplication.nativeApplication.autoExit = false; 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE, iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_16.png")); 
                 
                var systray:SystemTrayIcon =  
                    NativeApplication.nativeApplication.icon as SystemTrayIcon; 
                systray.tooltip = "AIR application"; 
                systray.menu = iconMenu; 
            } 
 
            if (NativeApplication.supportsDockIcon){ 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE,iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_128.png")); 
                var dock:DockIcon = NativeApplication.nativeApplication.icon as DockIcon;  
                dock.menu = iconMenu; 
            } 
        } 
         
        private function iconLoadComplete(event:Event):void 
        { 
            NativeApplication.nativeApplication.icon.bitmaps = 
                [event.target.content.bitmapData]; 
        } 
    } 
} 

Quando uma janela está em segundo plano, você pode notificar o usuário de que ocorreu um evento de interesse relacionado à janela. No Mac OS X, você pode notificar o usuário fazendo o ícone de encaixe do aplicativo pular (conforme descrito em Fazer o encaixe pular ). No Windows e no Linux, você pode realçar o botão da barra de tarefas da janela chamando o método notifyUser() da ocorrência NativeWindow. O parâmetro type passado para o método determina a urgência da notificação:

• NotificationType.CRITICAL : o ícone da janela fica piscando até o usuário colocar a janela no primeiro plano.

• NotificationType.INFORMATIONAL : o ícone da janela fica realçado pela troca de cores.

  Nota: No Linux, só há suporte para o tipo informativo de notificação. Passar um dos valores de tipo para a função notifyUser() criará o mesmo efeito.

  A seguinte instrução realça o botão da barra de tarefas de uma janela:

  stage.nativeWindow.notifyUser(NotificationType.CRITICAL); 

  Chamar o método NativeWindow.notifyUser() em um sistema operacional que não dá suporte a notificações de janela não produz qualquer efeito. Use a propriedade NativeWindow.supportsNotification para determinar se a notificação de janela é suportada.

No sistema operacional Windows, as janelas criadas com os tipos utility ou lightweight não aparecem na barra de tarefas. As janelas invisíveis também não.

Como a janela inicial é necessariamente do tipo normal , para criar um aplicativo sem nenhuma janela aparecendo na barra de tarefas, você deve fechar a janela inicial ou deixá-la invisível. Para fechar todas as janelas do seu aplicativo sem encerrá-lo, defina a propriedade autoExit do objeto NativeApplication como false antes de fechar a última janela. Para impedir que a janela inicial se torne visível, adicione <visible>false</visible> ao elemento <initalWindow> do arquivo de descrição do aplicativo (e não defina a propriedade visible como true ou chame o método activate() da janela).

Nas novas janelas abertas pelo aplicativo, defina a propriedade type do objeto NativeWindowInitOption passado para o construtor de janela como NativeWindowType.UTILITY ou NativeWindowType.LIGHTWEIGHT .

No Mac OS X, as janelas minimizadas são exibidas na barra de tarefas do encaixe. Para impedir que o ícone minimizado seja exibido, oculte a janela em vez de minimizá-la. O exemplo a seguir monitora um evento de alteração nativeWindowDisplayState e o cancela se a janela está sendo minimizada. O manipulador define a propriedade visible da janela como false :

private function preventMinimize(event:NativeWindowDisplayStateEvent):void{ 
    if(event.afterDisplayState == NativeWindowDisplayState.MINIMIZED){ 
        event.preventDefault(); 
        event.target.visible = false; 
    } 
} 

Se uma janela está minimizada no encaixe do Mac OS X quando você define a propriedade visible como false , o ícone no encaixe não é removido. Um usuário ainda poderá clicar no ícone para fazer com que a janela reapareça.