Klasy

Język ActionScript 3.0 udostępnia cztery atrybuty specjalne służące do sterowania dostępem do właściwości zdefiniowanych wewnątrz klasy: public , private , protected i internal .

Atrybut public powoduje, że właściwość będzie widoczna w każdym miejscu skryptu. Na przykład, aby udostępnić metodę dla kodu poza jej pakietem, należy zadeklarować ją z atrybutem public . Zasada ta dotyczy wszystkich właściwości, niezależnie od tego, czy są zadeklarowane za pomocą słowa kluczowego var , const , czy function .

Atrybut private powoduje, że właściwość jest widoczna tylko dla kodu wywołującego w klasie definiującej tę właściwość. Atrybut private działa zatem inaczej niż w języku ActionScript 2.0, gdzie podklasy miały dostęp do klas prywatnych nadklasy. Inna ważna różnica w działaniu dotyczy dostępu w czasie wykonywania. W języku ActionScript 2.0 słowo kluczowe private uniemożliwiało dostęp wyłącznie w trybie kompilacji i dawało się łatwo obejść w czasie wykonywania. W języku ActionScript 3.0 nie jest to już możliwe. Właściwości oznaczone private są niedostępne zarówno w czasie kompilacji, jak i w czasie wykonywania.

Na przykład następujący kod tworzy prostą klasę o nazwie PrivateExample, zawierającą jedną zmienną prywatną, a potem próbuje uzyskać dostęp do tej zmiennej prywatnej spoza klasy.

class PrivateExample 
{ 
    private var privVar:String = "private variable"; 
} 
 
var myExample:PrivateExample = new PrivateExample(); 
trace(myExample.privVar);// compile-time error in strict mode 
trace(myExample["privVar"]); // ActionScript 2.0 allows access, but in ActionScript 3.0, this is a run-time error. 

W języku ActionScript 3.0 próba dostępu do właściwości prywatnej za pomocą kropki ( myExample.privVar ) powoduje błąd kompilacji w trybie ścisłym. W trybie standardowym błąd zostanie zgłoszony podczas wykonywania, podobnie jak przy próbie użycia operatora dostępu do właściwości ( myExample["privVar"] ).

W poniższej tabeli zamieszczono podsumowanie wyników, jakie da próba dostępu do właściwości prywatnej należącej do klasy zapieczętowanej (niedynamicznej):

W klasach zadeklarowanych z atrybutem dynamic próba dostępu do zmiennej prywatnej nie powoduje błędu w czasie wykonania. Zmienna nie jest widoczna, dlatego zwracana jest wartość undefined . Jednak próba użycia kropki w trybie ścisłym spowoduje zgłoszenie błędu w czasie kompilacji. Poniższy przykład jest prawie identyczny z poprzednim, z tym że klasa PrivateExample jest zadeklarowana jako dynamiczna:

dynamic class PrivateExample 
{ 
    private var privVar:String = "private variable"; 
} 
 
var myExample:PrivateExample = new PrivateExample(); 
trace(myExample.privVar);// compile-time error in strict mode 
trace(myExample["privVar"]); // output: undefined

Klasy dynamiczne z reguły zwracają wartość undefined , a nie powodują zgłoszenia błędu przy próbie dostępu do właściwości prywatnej z kodu zewnętrznego względem klasy. Zgodnie z poniższą tabelą, błąd jest generowany tylko przy próbie dostępu do właściwości prywatnej za pomocą kropki w trybie ścisłym:

Atrybut protected , będący nowym elementem języka ActionScript 3.0, powoduje, że właściwość jest widoczna dla kodu wywołującego wewnątrz jej własnej klasy lub podklas. Innymi słowy, właściwość z atrybutem protected (chroniona) jest dostępna dla własnej klasy i dla wszystkich klas znajdujących się poniżej w hierarchii dziedziczenia. Zasada ta obowiązuje niezależnie od tego, czy podklasy znajdują się w tym samym, czy w różnych pakietach.

Dla użytkowników, którzy wcześniej korzystali z języka ActionScript 2.0, ta funkcja jest podobna do atrybutu private w języku ActionScript 2.0. Atrybut protected w języku ActionScript 3.0 jest również podobny do atrybutu protected w języku Java. Obydwa atrybuty różnią się jednak, ponieważ wersja Java zapewnia dostęp do modułów wywołujących w tym samym pakiecie. Atrybut protected jest użyteczny, jeśli mamy zmienną lub metodę potrzebną w podklasach, ale chcemy ukryć ją przed kodem zewnętrznym względem łańcucha dziedziczenia

Atrybut internal , będący nowym elementem języka ActionScript 3.0, powoduje, że właściwość jest widoczna dla kodu wewnątrz jej własnego pakietu. Jest to domyślny atrybut dla kodu w pakiecie i obowiązuje dla każdej właściwości, której jawnie nie przypisano żadnego z poniższych atrybutów:

• public

• private

• protected

• przestrzeni nazw zdefiniowanej przez użytkownika

Atrybut internal działa podobnie jak domyślna kontrola dostępu w języku Java, z tym że w języku Java ten poziom dostępu nie ma jawnej nazwy i deklarowany jest po prostu przez pominięcie innych modyfikatorów dostępu. Atrybut internal w języku ActionScript 3.0 umożliwia jawne wyrażenie zamiaru uwidocznienia właściwości wyłącznie dla kodu w jej pakiecie.

Atrybut static , którego można używać z właściwościami zadeklarowanymi za pomocą słów kluczowych var , const lub function , umożliwia powiązanie właściwości z klasą, a nie z instancjami tej klasy. Kod zewnętrzny względem klasy odwołuje się do właściwości statycznych za pośrednictwem nazwy klasy, a nie nazwy instancji.

Właściwości statyczne nie są dziedziczone przez podklasy, ale właściwości stanowią część łańcucha zasięgów podklas. Oznacza to, że w treści podklasy można używać zmiennej lub metody statycznej bez odwoływania się do klasy, w której została ona zdefiniowana.

Alternatywą dla wstępnie zdefiniowanych atrybutów kontroli dostępu jest utworzenie niestandardowych przestrzeni nazw i korzystanie z nich jak z atrybutów. W każdej definicji można użyć tylko jednego atrybutu w postaci przestrzeni nazw, a ponadto nie można używać przestrzeni nazw razem z którymkolwiek z atrybutów kontroli dostępu: ( public , private , protected , internal ).

Konstruktory (nazywane też metodami-konstruktorami) to funkcje o tej samej nazwie, co klasa, w której są zdefiniowane. Kod zawarty w konstruktorze jest wykonywany za każdym razem, gdy za pomocą słowa kluczowego new tworzona jest nowa instancja klasy. Na przykład w poniższym kodzie zdefiniowano prostą klasę o nazwie Example, która zawiera jedną właściwość o nazwie status . Wartość początkowa zmiennej status jest przypisywana wewnątrz konstruktora.

class Example 
{ 
    public var status:String; 
    public function Example() 
    { 
        status = "initialized"; 
    } 
} 
 
var myExample:Example = new Example(); 
trace(myExample.status); // output: initialized

Konstruktory mogą być tylko publiczne, ale użycie atrybutu public jest opcjonalne. W odniesieniu do konstruktora nie można używać żadnych innych specyfikatorów dostępu, w tym private , protected lub internal . Konstruktora nie można również zadeklarować w przestrzeni nazw zdefiniowanej przez użytkownika.

Konstruktor może jawnie wywołać konstruktor swojej bezpośredniej nadklasy. Służy do tego instrukcja super() . Jeśli konstruktor nadklasy nie zostanie wywołany jawnie, kompilator automatycznie wstawi wywołanie przed pierwszą instrukcją w treści konstruktora. Możliwa jest również wywoływanie metod nadklasy poprzez dodanie przedrostka super jako odwołania do nadklasy. Jeśli w tym samym konstruktorze ma być używana zarówno instrukcja super() , jak i przedrostek super , to instrukcja super() musi występować wcześniej. W przeciwnym razie odwołanie przez przedrostek super nie będzie działać zgodnie z oczekiwaniami. Konstruktor super() należy także wywołać przed ewentualną instrukcją throw lub return .

Poniższy przykład ilustruje skutki użycia odwołania super przed wywołaniem konstruktora super() . Nowa klasa, ExampleEx, rozszerza klasę Example. Konstruktor ExampleEx próbuje uzyskać dostęp do zmiennej status zdefiniowanej w jego nadklasie, ale próba ta ma miejsce przed wywołaniem super() . Instrukcja trace() w konstruktorze ExampleEx wyświetla wartość null , ponieważ zmienna status nie jest dostępna przed wykonaniem konstruktora super() .

class ExampleEx extends Example 
{ 
    public function ExampleEx() 
    { 
        trace(super.status); 
        super(); 
    } 
} 
 
var mySample:ExampleEx = new ExampleEx(); // output: null

Mimo że formalnie dozwolone jest użycie instrukcji return w konstruktorze, nie jest dozwolone zwrócenie wartości. Innymi słowy, instrukcja return nie może być skojarzona z wyrażeniem lub wartością. W związku z tym konstruktory nie mogą zwracać wartości i nie mogą mieć określonego typu zwracanej wartości.

Jeśli w klasie nie zostanie zdefiniowany konstruktor, kompilator automatycznie utworzy pustą metodę-konstruktor. Jeśli klasa rozszerza inną klasę, kompilator doda wywołanie super() do wygenerowanego konstruktora.

Metody statyczne, nazywane także metodami klas , to metody zadeklarowane ze słowem kluczowym static . Metody statyczne, które są powiązane z klasą, a nie z instancją klasy, są przydatne do enkapsulacji funkcjonalności wpływającej na coś innego niż stan konkretnej instancji. Ponieważ metody statyczne są powiązane z klasą jako całością, dostęp do nich jest możliwy tylko za pośrednictwem klasy, a nie jej instancji.

Metody statyczne są przydatne do enkapsulacji funkcjonalności, która nie ogranicza się do zmiany stanu instancji klasy. Innymi słowy, metoda powinna być statyczna, jeśli jej działanie nie wpływa bezpośrednio na wartość instancji klasy. Na przykład klasa Date ma metodę statyczną o nazwie parse() , która konwertuje ciąg znaków na liczbę. Metoda jest statyczna, ponieważ nie wpływa na poszczególne instancje klasy. Metoda parse() analizuje ciąg znaków reprezentujący wartość daty i zwraca liczbę zgodną z wewnętrzną reprezentacją obiektu Date. Ta metoda nie jest metodą instancji, ponieważ nie ma sensu stosowanie jej do instancji klasy Date.

Porównajmy teraz metodę statyczną parse() z jedną z metod instancji klasy Date, np. z metodą getMonth() . getMonth() to metoda instancji, ponieważ operuje bezpośrednio na wartości instancji, pobierając konkretny składnik — miesiąc — instancji Date.

Ponieważ metody statyczne nie są powiązane z poszczególnymi instancjami, nie jest dozwolone użycie słów kluczowych this lub super w treści metody statycznej. Zarówno odwołanie this , jak i odwołanie super , mają znaczenie tylko w kontekście metody instancji.

Inaczej niż w niektórych innych językach programowania opartych na koncepcji klas, metody statyczne w języku ActionScript 3.0 nie są dziedziczone.

Metody instancji są to metody zadeklarowane bez słowa kluczowego static . Metody instancji, które są powiązane z instancjami klasy, a nie z klasą jako całością, są użyteczne przy implementowaniu funkcjonalności wpływającej na poszczególne instancje klasy. Na przykład klasa Array zawiera metodę instancji o nazwie sort() , która operuje bezpośrednio na instancjach klasy Array.

Zarówno zmienne statyczne, jak i zmienne instancji znajdują się w zasięgu treści metody instancji, co oznacza, że do zmiennych zdefiniowanych w tej samej klasie można odwoływać się za pomocą prostych identyfikatorów. Na przykład poniższa klasa, CustomArray, rozszerza klasę Array. Klasa CustomArray definiuje zmienną statyczną o nazwie arrayCountTotal , która rejestruje łączną liczbę instancji klasy, zmienną instancji o nazwie arrayNumber , która rejestruje kolejność tworzenia instancji, oraz metodę instancji o nazwie getPosition() , która zwraca wartości tych zmiennych.

public class CustomArray extends Array 
{ 
    public static var arrayCountTotal:int = 0; 
    public var arrayNumber:int; 
 
    public function CustomArray() 
    { 
        arrayNumber = ++arrayCountTotal; 
    } 
     
    public function getArrayPosition():String 
    { 
         return ("Array " + arrayNumber + " of " + arrayCountTotal); 
    } 
}

Mimo że kod zewnętrzny względem klasy musi mieć dostęp do zmiennej statycznej arrayCountTotal za pośrednictwem obiektu klasy, w formie CustomArray.arrayCountTotal , kod rezydujący w treści metody getPosition() może odwoływać się bezpośrednio do zmiennej statycznej arrayCountTotal . Zasada ta obowiązuje nawet dla zmiennych statycznych w nadklasach. Chociaż w języku ActionScript 3.0 właściwości statyczne nie są dziedziczone, właściwości statyczne z nadklas należą do aktualnego zasięgu. Na przykład klasa Array zawiera kilka zmiennych statycznych, z których jedna jest stałą o nazwie DESCENDING . Kod rezydujący w podklasie Array może mieć dostęp do statycznej stałej DESCENDING za pomocą prostego identyfikatora:

public class CustomArray extends Array 
{ 
    public function testStatic():void 
    { 
        trace(DESCENDING); // output: 2 
    } 
}

Wartość odwołania this w treści metody instancji jest odwołaniem do instancji, z którą ta metoda jest powiązana. Poniższy kod demonstruje, że odwołanie this wskazuje na instancję zawierającą metodę:

class ThisTest 
{ 
    function thisValue():ThisTest 
    { 
        return this; 
    } 
} 
 
var myTest:ThisTest = new ThisTest(); 
trace(myTest.thisValue() == myTest); // output: true

Dziedziczeniem metody instancji można sterować za pomocą słów kluczowych override i final . Atrybut override umożliwia przedefiniowanie metody odziedziczonej, a atrybut final zapobiega przesłanianiu metody przez podklasy.

Funkcje-akcesory pobierające i ustawiające, nazywane także metodami pobierającymi i metodami ustawiającymi , umożliwiają realizację koncepcji ukrywania i enkapsulacji informacji, a jednocześnie stworzenie wygodnego interfejsu programistycznego dla samodzielnie tworzonych klas. Funkcje pobierające i ustawiające pozwalają na zachowanie prywatności właściwości klasy, ale jednocześnie umożliwiają użytkownikom klasy dostęp do tych właściwości w taki sposób, jak do zmiennych, a nie w formie wywołania metody klasy.

Zaletą takiej strategii jest możliwość uniknięcia tradycyjnych akcesorów o „nieprzyjaznych” nazwach, takich jak getPropertyName() i setPropertyName() . Inną zaletą funkcje pobierających i ustawiających jest możliwość obycia się bez pary funkcji publicznych przypadającej na każdą właściwość, która ma być dostępna i do odczytu, i do zapisu.

Poniższa klasa przykładowa o nazwie GetSet zawiera funkcje pobierającą i ustawiającą o nazwie publicAccess() , która umożliwia dostęp do zmiennej prywatnej o nazwie privateProperty :

class GetSet 
{ 
    private var privateProperty:String; 
     
    public function get publicAccess():String 
    { 
        return privateProperty; 
    } 
     
    public function set publicAccess(setValue:String):void 
    { 
        privateProperty = setValue; 
    } 
}

Próba bezpośredniego dostępu do właściwości privateProperty powoduje zgłoszenie błędu:

var myGetSet:GetSet = new GetSet(); 
trace(myGetSet.privateProperty); // error occurs

Użytkownik klasy GetSet ma natomiast do dyspozycji mechanizm, który z pozoru przypomina właściwość o nazwie publicAccess , ale faktycznie jest parą akcesorów — złożoną z funkcji pobierającej i ustawiającej — operujących na właściwości prywatnej privateProperty . W poniższym przykładzie tworzona jest instancja klasy GetSet, a następnie wartość właściwości privateProperty ustawiana jest za pomocą publicznego akcesora o nazwie publicAccess :

var myGetSet:GetSet = new GetSet(); 
trace(myGetSet.publicAccess); // output: null 
myGetSet.publicAccess = "hello"; 
trace(myGetSet.publicAccess); // output: hello

Funkcje pobierające i ustawiające umożliwiają także przesłanianie właściwości dziedziczonych z nadklasy, co nie jest możliwe w przypadku zwykłych zmiennych należących do klasy. Zmienne należące do klasy zadeklarowane za pomocą słowa kluczowego var nie mogą być przesłaniane w podklasach. Jednak ograniczenie to nie obowiązuje w przypadku właściwości tworzonych za pomocą funkcji pobierających i ustawiających. W odniesieniu do funkcji pobierających i ustawiających odziedziczonych z nadklasy można używać atrybutu override .

Metoda powiązana, nazywana czasem zamknięciem metody , to po prostu metoda wyodrębniona z jej instancji. Przykładami metod powiązanych są metody przekazywane jako argumenty do funkcji lub zwracane jako wartości z funkcji. Metody powiązane, będące nowym elementem języka ActionScript 3.0, są podobne do zamknięć funkcji w tym, że zachowują swoje środowisko leksykalne nawet po wyodrębnieniu z instancji. Zasadnicza różnica między metodą powiązaną a zamknięciem funkcji polega na tym, że odwołanie this w metodzie powiązanej pozostaje powiązane z instancją implementującą tą metodę. Innymi słowy, odwołanie this w metodzie powiązanej zawsze wskazuje na oryginalny obiekt, który zaimplementował metodę. W przypadku zamknięć funkcji odwołanie this ma charakter ogólny, czyli wskazuje na obiekt lub funkcję, z którym jest skojarzone w momencie wywołania.

Zrozumienie koncepcji metod powiązanych jest ważne w przypadku posługiwania się słowem kluczowym this . Jak pamiętamy, słowo kluczowe this jest odwołaniem do obiektu nadrzędnego metody. Większość programistów używających języka ActionScript oczekuje, że słowo kluczowe this przedstawia obiekt lub klasę zawierającą definicję metody. Jednak bez mechanizm wiązania metod warunek ten nie zawsze byłby spełniony. Na przykład we wcześniejszych wersjach języka ActionScript odwołanie this nie zawsze wskazywało na instancję, która implementowała metodę. W języku ActionScript 2.0 w metodach wyodrębnionych z instancji nie tylko słowo kluczowe this nie było powiązane z oryginalną instancją, lecz również nie były dostępne zmienne i metody należące do klasy instancji. Nie stanowi to problemu w języku ActionScript 3.0, w którym metody powiązane są tworzone automatycznie podczas przekazywania metod jako parametrów. Metody powiązane gwarantują, że słowo kluczowe this zawsze odwołuje się do obiektu lub klasy, w którym metoda jest zdefiniowana.

Poniższy kod definiuje klasę o nazwie ThisTest, która zawiera metodę o nazwie foo() definiującą metodę powiązaną, a także metodę o nazwie bar() , która zwraca metodę powiązaną. Kod zewnętrzny względem klasy tworzy instancję klasy ThisTest, wywołuje metodę bar() i zapisuje zwróconą wartość w zmiennej o nazwie myFunc .

class ThisTest 
{ 
    private var num:Number = 3; 
    function foo():void // bound method defined 
    { 
        trace("foo's this: " + this); 
        trace("num: " + num); 
    } 
    function bar():Function 
    { 
        return foo; // bound method returned 
    } 
} 
 
var myTest:ThisTest = new ThisTest(); 
var myFunc:Function = myTest.bar(); 
trace(this); // output: [object global] 
myFunc(); 
/* output:  
foo's this: [object ThisTest] 
output: num: 3 */

Ostatnie dwa wiersze kodu demonstrują fakt, że odwołanie this w metodzie powiązanej foo() nadal wskazuje na klasę ThisTest, mimo że odwołanie this w wierszy bezpośrednio poprzedzającym wskazuje na obiekt globalny. Co więcej, metoda powiązana przechowywana w zmiennej myFunc wciąż ma dostęp do zmiennych klasy ThisTest. Gdyby ten sam kod został uruchomiony w języku ActionScript 2.0, odwołania this byłyby identyczne, a zmienna num miałaby wartość undefined .

Jednym z obszarów, w których nowa koncepcja metod powiązanych jest najbardziej zauważalna, są podprogramy obsługi zdarzeń, ponieważ metoda addEventListener() wymaga, aby jako argument przekazać do niej funkcję lub metodę.

Aby osadzić zasób, należy najpierw umieścić go w bibliotece pliku FLA. Następnie, korzystając z właściwości połączenia zasobu, należy podać nazwę klasy zasobu osadzonego. Jeśli klasy o tej nazwie nie ma w ścieżce klas, to zostanie automatycznie wygenerowana. Następnie tworzymy instancję klasy zasobu osadzonego i korzystamy z właściwości i metod zdefiniowanych lub odziedziczonych przez tę klasę. Poniższy przykładowy kod umożliwia odtworzenie osadzonego dźwięku połączonego z klasą zasobu osadzonego o nazwie PianoMusic:

var piano:PianoMusic = new PianoMusic(); 
var sndChannel:SoundChannel = piano.play();

Można również wykorzystać znacznik metadanych [Embed] w celu osadzenia zasobów w projekcie Flash Professional, co zostało opisane w dalszej części niniejszego podręcznika. Jeśli w kodzie używany jest znacznik [Embed] , program Flash Professional wykorzystuje kompilator Flex w celu skompilowania projektu, nie korzysta natomiast z kompilatora Flash Professional.

W przypadku kompilowania kodu za pomocą kompilatora Flex w celu osadzenia zasobu w kodzie ActionScript należy użyć znacznika metadanych [Embed] . Zasób należy umieścić w głównym folderze źródłowym lub innym folderze w ścieżce budowania projektu. Gdy tylko kompilator Flex napotyka znacznik Embed, tworzy klasę zasobu osadzonego. Dostęp do tej klasy jest możliwy za pośrednictwem zmiennej o typie danych Class, którą deklaruje się bezpośrednio po znaczniku metadanych [Embed] . W poniższym przykładowym kodzie osadzony jest dźwięk o nazwie sound1.mp3, a odwołanie do klasy zasobu osadzonego powiązanej z tym dźwiękiem jest przechowywane w zmiennej o nazwie soundCls . Następnie przykładowy kod tworzy instancję klasy obiektu osadzonego i wywołuje metodę play() tej instancji:

package 
{ 
    import flash.display.Sprite; 
    import flash.media.SoundChannel; 
    import mx.core.SoundAsset; 
 
    public class SoundAssetExample extends Sprite 
    { 
        [Embed(source="sound1.mp3")] 
        public var soundCls:Class; 
         
        public function SoundAssetExample() 
        { 
            var mySound:SoundAsset = new soundCls() as SoundAsset; 
            var sndChannel:SoundChannel = mySound.play(); 
        } 
    } 
}