Tablice asocjacyjne

Istnieją dwa sposoby tworzenia tablic asocjacyjnych w języku ActionScript 3.0. Pierwszy z nich to użycie instancji Object. Za pomocą instancji klasy Object można zainicjować tablicę z literałem obiektu. Wystąpienie klasy Object, określane również jako obiekt ogólny, jest funkcjonalnie identyczne z tablicą asocjacyjną. Każda nazwa właściwości obiektu generycznego działa jak klucz zapewniający dostęp do zapisanych wartości.

Poniższy przykład ilustruje tworzenie tablicy asocjacyjnej o nazwie monitorInfo za pomocą literału obiektu w celu zainicjowania tablicy za pośrednictwem dwóch par kluczy i wartości.

var monitorInfo:Object = {type:"Flat Panel", resolution:"1600 x 1200"}; 
trace(monitorInfo["type"], monitorInfo["resolution"]);  
// output: Flat Panel 1600 x 1200

Jeśli nie trzeba inicjować tablicy w chwili deklaracji, można użyć konstruktora Object w celu utworzenia tablicy, zgodnie z poniższym przykładem.

var monitorInfo:Object = new Object();

Gdy tablica zostanie utworzona za pomocą literału obiektu lub konstruktora klasy Object, można dodać nowe wartości do tablicy, korzystając z operatora dostępu do klasy ([]) lub operatora kropki (.). Poniższy przykład ilustruje dodawanie dwóch nowych wartości do zmiennej monitorArray.

monitorInfo["aspect ratio"] = "16:10"; // bad form, do not use spaces 
monitorInfo.colors = "16.7 million"; 
trace(monitorInfo["aspect ratio"], monitorInfo.colors); 
// output: 16:10 16.7 million

Należy pamiętać, że klucz o nazwie aspect ratio zawiera znak spacji. Jest to dopuszczalne w przypadku operatora dostępu do klasy ([]), spowoduje jednak wygenerowanie błędu w przypadku próby skorzystania z operatora kropki. Używanie spacji w nazwach kluczy jest w związku z tym niezalecane.

Drugim sposobem na utworzenie tablicy asocjacyjnej jest użycie konstruktora Array (lub konstruktora dowolnej klasy dynamicznej), a następnie użycie operatora dostępu do tablicy ([]) albo operatora kropki (.) w celu dodania pary klucz plus wartość do tablicy. W przypadku zdeklarowania tablicy asocjacyjnej, która ma być tablicą typu Array, nie można użyć literału obiektowego do inicjalizacji tablicy. Poniższy przykład ilustruje tworzenie tablicy asocjacyjnej o nazwie monitorInfo za pomocą konstruktora klasy Array oraz dodawanie klucza o nazwie type oraz klucza o nazwie resolution, wraz z ich wartościami.

var monitorInfo:Array = new Array(); 
monitorInfo["type"] = "Flat Panel"; 
monitorInfo["resolution"] = "1600 x 1200"; 
trace(monitorInfo["type"], monitorInfo["resolution"]);  
// output: Flat Panel 1600 x 1200

Wykorzystanie do utworzenia tablicy asocjacyjnej konstruktora Array nie przynosi żadnej korzyści. W przypadku tablic asocjacyjnych nie można używać właściwości Array.length ani żadnej z metod klasy Array, nawet jeśli zostanie użyty konstruktor Array lub typ danych Array. Użycie konstruktora Array najlepiej jest pozostawić do czasu utworzenia tablic indeksowanych.

Możliwe jest użycie klasy Dictionary do utworzenia tablicy asocjacyjnej korzystającej z kluczy, nie zaś z łańcuchów. Takie tablice są niekiedy zwane słownikami, tablicami mieszającymi lub mapującymi. Należy na przykład rozważyć aplikację determinującą lokalizację obiektu Sprite opartego na jej powiązaniu z określonym kontenerem. Możliwe jest użycie obiektu Dictionary w celu zmapowania każdego obiektu Sprite do kontenera.

Poniższy kod umożliwia utworzenie trzech instancji klasy Sprite, działających jako klucze dla obiektu Dictionary. Każdemu z kluczy przypisywana jest wartość GroupA lub GroupB. Wartości te mogą być wartościami dowolnego typu danych, lecz w tym przykładzie obie wartości — GroupA i GroupB — są wystąpieniami klasy Object. Następnie można również uzyskać dostęp do wartości skojarzonej z każdym z kluczy za pomocą operatora dostępu do tablicy ([]), zgodnie z poniższym przykładowym kodem.

import flash.display.Sprite; 
import flash.utils.Dictionary; 
 
var groupMap:Dictionary = new Dictionary(); 
 
// objects to use as keys 
var spr1:Sprite = new Sprite(); 
var spr2:Sprite = new Sprite(); 
var spr3:Sprite = new Sprite(); 
 
// objects to use as values 
var groupA:Object = new Object(); 
var groupB:Object = new Object(); 
 
// Create new key-value pairs in dictionary. 
groupMap[spr1] = groupA; 
groupMap[spr2] = groupB; 
groupMap[spr3] = groupB; 
 
if (groupMap[spr1] == groupA) 
{ 
    trace("spr1 is in groupA");  
} 
if (groupMap[spr2] == groupB) 
{ 
    trace("spr2 is in groupB");  
} 
if (groupMap[spr3] == groupB) 
{ 
    trace("spr3 is in groupB");  
}

for (var key:Object in groupMap) 
{ 
    trace(key, groupMap[key]); 
} 
/* output: 
[object Sprite] [object Object] 
[object Sprite] [object Object] 
[object Sprite] [object Object] 
*/

for each (var item:Object in groupMap) 
{ 
    trace(item); 
} 
/* output: 
[object Object] 
[object Object] 
[object Object] 
*/

var myObject:Object = new Object();

import flash.utils.Dictionary; 
 
var myObject:Object = new Object(); 
var myMap:Dictionary = new Dictionary(); 
myMap[myObject] = "foo";

myObject = null; 
delete myMap[myObject];

import flash.utils.Dictionary; 
 
var myObject:Object = new Object(); 
var myMap:Dictionary = new Dictionary(true); 
myMap[myObject] = "foo"; 
myObject = null; // Make object eligible for garbage collection.