Tablice indeksowane

Istnieje kilka technik tworzenia instancji klasy Array lub klasy Vector. Jednak techniki służące do tworzenia poszczególnych typów tablic są różne.

Najprostszym sposobem dodania elementu do tablicy indeksowanej jest użycie operatora dostępu do tablicy ( [] ). Aby ustawić wartość elementu tablicy indeksowanej, należy użyć nazwy obiektu Array lub Vector oraz numeru indeksu po lewej stronie instrukcji przypisania:

songTitles[5] = "Happy Birthday";

Jeśli obiekt Array lub Vector nie zawiera jeszcze elementu w pozycji tego indeksu, indeks zostanie utworzony, a wartość zostanie w nim zapisana. Jeśli w pozycji tego indeksu istnieje wartość, nowa wartość zastąpi istniejącą.

Obiekt Array umożliwia utworzenie elementu w pozycji dowolnego indeksu. Jednak w przypadku obiektu Vector można tylko przypisać wartość do istniejącego indeksu lub do następnego dostępnego indeksu. Następny dostępny indeks odpowiada właściwości length obiektu Vector. Najbezpieczniejszym sposobem dodania nowego elementu do obiektu Vector jest użycie następującego fragmentu kodu:

myVector[myVector.length] = valueToAdd;

Trzy z metod klas Array i Vector — push() , unshift() i splice() — umożliwiają wstawianie elementów do tablicy indeksowanej. Metoda push() powoduje dołączenie co najmniej jednego elementu na końcu tablicy. Ostatni element wstawiony do tablicy za pomocą metody push() otrzymuje najwyższy numer indeksu. Metoda unshift() powoduje wstawienie co najmniej jednego elementu na początku tablicy — pod indeksem 0. Metoda splice() powoduje wstawienie dowolnej liczby pozycji pod określonym indeksem tablicy.

Poniższy przykład zawiera wszystkie trzy metody. Tworzona jest dowolna tablica o nazwie planets . Ma ona przechowywać nazwy planet w kolejności określonej ich odległością od Słońca. Przede wszystkim wywoływana jest więc metoda push() w celu dodania do tablicy pierwszego elementu: Mars . Następnie wywoływana jest metoda unshift() wstawiająca element przypadający na sam początek tablicy: Mercury . Na koniec wywoływana jest metoda splice() wstawiająca kolejno elementy Venus i Earth za pozycją Mercury , lecz przed pozycją Mars . Pierwszy argument wysłany do metody splice() , liczba całkowita 1, powoduje rozpoczęcie wstawiania od indeksu 1. Drugi argument wysyłany do metody splice() , liczba całkowita 0, wskazuje, że żadna z pozycji nie może zostać usunięta. Trzeci i czwarty argument wysyłane do metody splice() , Venus i Earth , to elementy, które mają zostać wstawione.

var planets:Array = new Array(); 
planets.push("Mars"); // array contents: Mars 
planets.unshift("Mercury"); // array contents: Mercury,Mars 
planets.splice(1, 0, "Venus", "Earth"); 
trace(planets); // array contents: Mercury,Venus,Earth,Mars

Metody push() i unshift() zwracają nieoznaczoną liczbę całkowitą reprezentującą długość zmodyfikowanej tablicy. Metoda splice() , użyta do wstawienia elementów, zwraca pustą tablicę co może wydawać się dziwne, jest jednak logiczne w kontekście uniwersalności działania metody splice() . Metody splice() można użyć nie tylko do wstawienia elementów do tablicy, lecz również do usunięcia z niej elementów. W przypadku korzystania z metody splice() do usuwania elementów zwraca ona tablicę zawierającą te usunięte elementy.

Najprostszym sposobem na pobranie wartości elementu z tablicy indeksowanej jest użycie operatora dostępu do tablicy ( [] ). Aby pobrać wartość elementu tablicy indeksowanej, należy użyć nazwy obiektu Array lub Vector oraz numeru indeksu po prawej stronie instrukcji przypisania:

var myFavoriteSong:String = songTitles[3];

Możliwa jest próba pobrania wartości z obiektu Array lub Vector przy użyciu indeksu, który nie zawiera żadnego elementu. W takim przypadku obiekt Array zwróci wartość undefined, a obiekt Vector zgłosi wyjątek RangeError.

Trzy metody klas Array i Vector — pop() , shift() i splice() — umożliwiają usuwanie elementów. Metoda pop() umożliwia usunięcie elementu z końca tablicy. Innymi słowy, usuwa ona element o najwyższym indeksie. Metoda shift() usuwa element z początku tablicy, co oznacza, że zawsze usuwa element o indeksie równym 0. Metoda splice() , która może być również używana do wstawiana elementów, usuwa podaną liczbę elementów, rozpoczynając od indeksu o numerze podanym w pierwszym argumencie wysłanym do metody.

W poniższym przykładzie użyto wszystkich trzech metod w celu usunięcia elementów z wystąpienia klasy Array. Utworzona została tablica o nazwie oceans , która ma zawierać nazwy dużych zbiorników wodnych. Niektóre z nazw w tablicy to raczej jeziora niż oceany, dlatego potrzebne jest ich usunięcie.

Najpierw metoda splice() jest używana do usunięcia pozycji Aral i Superior oraz wstawiania pozycji Atlantic i Indian . Pierwszy argument wysyłany do metody splice() , liczba całkowita 2, wskazuje, że operacja powinna zostać rozpoczęta od trzeciej pozycji na liście — indeksu o numerze 2. Drugi argument — 2 — oznacza, że należy usunąć dwa elementy. Pozostałe argumenty, Atlantic i Indian , są wartościami, które należy wstawić pod indeksem 2.

Następnie metoda pop() usuwa ostatni element tablicy, Huron . W kolejnym kroku metoda shift() usuwa pierwszy element tablicy, Victoria .

var oceans:Array = ["Victoria", "Pacific", "Aral", "Superior", "Indian", "Huron"]; 
oceans.splice(2, 2, "Arctic", "Atlantic"); // replaces Aral and Superior 
oceans.pop(); // removes Huron 
oceans.shift(); // removes Victoria 
trace(oceans);// output: Pacific,Arctic,Atlantic,Indian

Metody pop() i shift() zwracają usunięte elementy. W przypadku instancji klasy typ danych wartości zwracanej to Object, ponieważ tablice mogą zawierać dane dowolnego typu. W przypadku instancji klasy Vector typ danych wartości zwracanej jest typem bazowym klasy Vector. Metoda splice() zwraca obiekt Array lub Vector zawierający usunięte wartości. Przykład oparty na tablicy oceans można zmienić w taki sposób, aby wywołanie metody splice() powodowało przypisanie zwróconej tablicy do nowej zmiennej tablicy, zgodnie z poniższym przykładem.

var lakes:Array = oceans.splice(2, 2, "Arctic", "Atlantic"); 
trace(lakes); // output: Aral,Superior

Użytkownik może również spotkać się z kodem, który korzysta z operatora delete dla elementu obiektu Array. Operator delete ustawia dla elementu obiektu Array wartość undefined , lecz nie usuwa elementu z tablicy. Na przykład poniższy kod korzysta z operatora delete dla trzeciego elementu w tablicy oceans , lecz długość tablicy pozostaje równa 5.

var oceans:Array = ["Arctic", "Pacific", "Victoria", "Indian", "Atlantic"]; 
delete oceans[2]; 
trace(oceans);// output: Arctic,Pacific,,Indian,Atlantic 
trace(oceans[2]); // output: undefined 
trace(oceans.length); // output: 5

Obiekt Array lub Vector można skrócić za pomocą właściwości length . Po ustawieniu właściwości length tablicy indeksowanej na wartość mniejszą od aktualnej długości tablicy jest ona skracana, co powoduje usunięcie elementów zapisanych pod numerem indeksu wyższym niż nowa wartość właściwości length pomniejszona o 1. Jeśli na przykład tablica oceans została posortowana tak, że wszystkie poprawne elementy znajdują się w jej górnej części, można za pomocą właściwości length usunąć elementy z końca tablicy, zgodnie z poniższym kodem.

var oceans:Array = ["Arctic", "Pacific", "Victoria", "Aral", "Superior"]; 
oceans.length = 2; 
trace(oceans); // output: Arctic,Pacific

Dostępne są trzy metody — reverse() , sort() oraz sortOn() — umożliwiające zmienianie kolejności elementów tablicy indeksowanej przez sortowanie albo odwracanie kolejności. Wszystkie te metody modyfikują istniejącą tablicę. W poniższej tabeli przedstawiono podsumowanie tych metod oraz ich zachowanie dla obiektów Array i Vector:

var oceans:Array = ["Arctic", "Atlantic", "Indian", "Pacific"]; 
oceans.reverse(); 
trace(oceans); // output: Pacific,Indian,Atlantic,Arctic

var poets:Array = ["Blake", "cummings", "Angelou", "Dante"]; 
poets.sort(); // default sort 
trace(poets); // output: Angelou,Blake,Dante,cummings 
 
poets.sort(Array.CASEINSENSITIVE); 
trace(poets); // output: Angelou,Blake,cummings,Dante 
 
poets.sort(Array.DESCENDING); 
trace(poets); // output: cummings,Dante,Blake,Angelou 
 
poets.sort(Array.DESCENDING | Array.CASEINSENSITIVE); // use two options 
trace(poets); // output: Dante,cummings,Blake,Angelou

var names:Array = new Array("John Q. Smith", "Jane Doe", "Mike Jones"); 
function orderLastName(a, b):int 
{ 
    var lastName:RegExp = /\b\S+$/; 
    var name1 = a.match(lastName); 
    var name2 = b.match(lastName); 
    if (name1 < name2) 
    { 
        return -1; 
    } 
    else if (name1 > name2) 
    { 
        return 1; 
    } 
    else 
    { 
        return 0; 
    } 
} 
trace(names); // output: John Q. Smith,Jane Doe,Mike Jones 
names.sort(orderLastName); 
trace(names); // output: Jane Doe,Mike Jones,John Q. Smith

var poets:Array = new Array(); 
poets.push({name:"Angelou", born:"1928"}); 
poets.push({name:"Blake", born:"1757"}); 
poets.push({name:"cummings", born:"1894"}); 
poets.push({name:"Dante", born:"1265"}); 
poets.push({name:"Wang", born:"701"});

poets.sortOn("born", Array.NUMERIC); 
for (var i:int = 0; i < poets.length; ++i) 
{ 
    trace(poets[i].name, poets[i].born); 
} 
/* output: 
Wang 701 
Dante 1265 
Blake 1757 
cummings 1894 
Angelou 1928 
*/

var indices:Array; 
indices = poets.sortOn("born", Array.NUMERIC | Array.RETURNINDEXEDARRAY); 
for (var i:int = 0; i < indices.length; ++i) 
{ 
    var index:int = indices[i]; 
    trace(poets[index].name, poets[index].born); 
} 
/* output: 
Wang 701 
Dante 1265 
Blake 1757 
cummings 1894 
Angelou 1928 
*/

Cztery metody klas Array i Vector — concat() , join() , slice() i toString() — wyszukują w tablicy informacje, ale nie modyfikują tablicy. Metody concat() i slice() zwracają nowe tablice. Metody join() i toString() zwracają ciągi. Metoda concat() pobiera nową tablicę lub listę elementów w postaci argumentów i łączy ją z istniejącą tablicą w celu utworzenia nowej tablicy. Metoda slice() ma dwa parametry o nazwach startIndex oraz endIndex . Zwraca nową tablicę zawierającą kopie elementów powycinanych z istniejącej tablicy. Warstwa ta zaczyna się od elementu startIndex , a kończy elementem poprzedzającym endIndex . Należy pamiętać, że element na pozycji endIndex nie jest uwzględniany w wartości zwracanej.

Poniższy przykład ilustruje używanie metod concat() oraz slice() do tworzenia nowych tablic przy użyciu elementów innych tablic.

var array1:Array = ["alpha", "beta"]; 
var array2:Array = array1.concat("gamma", "delta"); 
trace(array2); // output: alpha,beta,gamma,delta 
 
var array3:Array = array1.concat(array2); 
trace(array3); // output: alpha,beta,alpha,beta,gamma,delta 
 
var array4:Array = array3.slice(2,5); 
trace(array4); // output: alpha,beta,gamma

Korzystając z metod join() oraz toString() , można zwracać zawartość tablic w postaci ciągów. Jeśli dla metody join() nie są używane żadne parametry, te dwie metody zachowują się identycznie, zwracając ciąg zawierający listę rozdzielaną przecinkami, składającą się ze wszystkich elementów w tablicy. Metoda join() w przeciwieństwie do metody toString() przyjmuje parametr o nazwie delimiter , pozwalający wybrać symbol, który będzie rozdzielał poszczególne elementy w zwracanym ciągu.

W poniższym przykładzie tworzony jest obiekt Array o nazwie rivers oraz wywoływane są metody join() i toString() zwracające wartości z obiektu Array w postaci ciągu. Metoda toString() służy do zwracania wartości rozdzielanych przecinkami ( riverCSV ), podczas gdy metoda join() służy do zwracania wartości rozdzielanych znakiem + .

var rivers:Array = ["Nile", "Amazon", "Yangtze", "Mississippi"]; 
var riverCSV:String = rivers.toString(); 
trace(riverCSV); // output: Nile,Amazon,Yangtze,Mississippi 
var riverPSV:String = rivers.join("+"); 
trace(riverPSV); // output: Nile+Amazon+Yangtze+Mississippi

Jedną z kwestii, jakie należy mieć na uwadze w przypadku posługiwania się metodą join() , jest to, że wszelkie zagnieżdżone wystąpienia klas Array lub Vector są zawsze zwracane w postaci rozdzielanej przecinkami, niezależnie od tego, jaki separator wybrano dla elementów tablicy głównej. Ilustruje to poniższy przykład.

var nested:Array = ["b","c","d"]; 
var letters:Array = ["a",nested,"e"];  
var joined:String = letters.join("+"); 
trace(joined); // output: a+b,c,d+e